[求助]：知道弧长，弦长，怎样画圆弧？

胡子8913

如题，弦长230，弧长235。谢谢！

walken

这个好象不是经常用到吧，不过我也不知道怎么画。
还想近来看看呢。

rush1177

计算一下再画。。。

民工

有程序可以画的，以前讨论过的，也就是输入两端点和弧长后生成圆弧

(defun c:aaa (/ p1 p2 s a l x xx fx flx r c c1 c2 mspace myobj)
  (defun N ()
    (setq c (- (+ a (* 0.5 pi)) (* x 0.5)))
    (setq cen (polar p1 c r))
    (setq c1 (+ c pi))
    (setq c2 (+ c1 x))
    (setq myobj (vla-addarc mspace (vlax-3d-point cen) r c1 c2))
    (princ)
  )
  (setq p1 (getpoint "\n请输入圆弧第一点:"))
  (setq p2 (getpoint p1 "\n请输入圆弧第二点:"))
  (setq s (getdist p1 "\n请输入弧长："))
  (setq a (angle p1 p2))
  (setq l (distance p1 p2))
  (vl-load-com)
  (setq    mspace (vla-get-modelspace
         (vla-get-activedocument (vlax-get-acad-object))
           )
  )
  (if (<= s l)
    (progn
      (prompt "您所要画的圆弧并不存在！")
      (princ)
    )
    (progn
      (setq x 2)
      (setq fx (- (/ (sin (/ x 2)) x) (/ (* 0.5 l) s)))
      (setq
    flx (/ (- (* 0.5 x (cos (* 0.5 x))) (sin (* 0.5 x))) (* x x))
      )
      (setq xx (- x (/ fx flx)))
      (while (> (abs (- x xx)) 0.0000000001)
    (setq x xx)
    (setq fx (- (/ (sin (/ x 2)) x) (/ (* 0.5 l) s)))
    (setq flx
           (/ (- (* 0.5 x (cos (* 0.5 x))) (sin (* 0.5 x))) (* x x))
    )
    (setq xx (- x (/ fx flx)))
      )
      (setq r (/ s xx))

      (initget "N S")
      (setq aa (getkword "\n 请输入圆弧方向[逆时针(N)/顺时针(S)]<N>:"))
      (if (= aa nil)
    (setq aa "N")
      )
      (if (= aa "N")
    (N)
    (if (= aa "S")
      (progn
        (setq c (- (+ a (/ x 2)) (* 0.5 pi)))
        (setq cen (polar p1 c r))
        (setq c1 (- (+ c pi) x))
        (setq c2 (+ c pi))
        (setq myobj (vla-addarc mspace (vlax-3d-point cen) r c1 c2))
        (princ)
      )
    )
      )
    )
  )
)

开拓进取

如何把这个程序导入到cad中?

lxch

将上面的程序保存为 aaa.lsp ，工具菜单——加载应用程序，加载 aaa.lsp 。
画直线230；命令行键入 aaa 。按提示选择直线的两个端点，输入弧长235 。

忆枫2001

6楼的，听说你很厉害啊。可不可以教教我画图呢？不胜感激哦

782150yhm

在CAD工具下拉菜单里面有个加载应用程序，点它找到需要加载的LSP然后点加载，就加载进来了。

胡子8913

谢谢各位，这样的确实应用较少，但碰到一个却耗了我不少时间，LIS程序又不会编，谢谢你的劳动成果。真的好用！

gengxiaowu

看到这个程序自己直接就呆了,看不懂是什么意思啊~~~

lanzhi125

我也看不懂.试着来用用!

zhoujh1982

比较少用的哦,先收下了,以备不时之需,谢谢了

xieqingx

好厉害啊，我还没有学过CAD二次开发，真想研究研究！