[原创]：轻轻松松统计块！

highflybird

针对目前有很多人还在用R14,而且没有装express tools工具，对过滤器的用法又不熟悉，编写了一个lisp程序，
能用来统计块的数量。
(本想发到 lisp开发版块的，但觉得这里更合适,因而贴到此处了)
用法：加载程序，运行BC ，先选择要统计的块,然后选择要统计的区域,结束后按F2显示出统计数量。
[php]
(prompt "\n命令为: BC ,用法如下: ")
(prompt "\n先选择要统计的块,然后选择要统计的区域,结束后按F2显示出统计数量.")
;;;*****************************
;;;highflybird  2007-2-8 kunming
;;;主程序-----------------------
;;;*****************************
(defun C:BC (/ ss1 ss2 NamLst BList str1 str2)
  (graphscr)
  (prompt "\n请选择要统计的块:")
  (if (setq ss1 (ssget '((0 . "INSERT"))))
    (progn
      (prompt "\n请选择要统计的区域:")
      (if (setq ss2 (ssget '((0 . "INSERT"))))
        (progn
          (setq NamLst (Name-list ss1))
          (setq BList (Name-count ss2 NamLst))
          (princ "\n块名")
          (princ (setq str1 "..............................."))
          (princ "数量")
          (princ "\n--------------------------------------")
          (foreach n BList
            (princ "\n")
            (princ (setq str2 (car n)))
            (princ (substr str1 (1+ (strlen str2)) (strlen str1)))
            (princ "....")
            (princ (cdr n))
          )
        )
        (princ "\n所选区域没有要统计的块!")
      )
    )
    (princ "\n你没有选择要统计的块!")
  )
  (princ)
)
;;;图块名列表函数
(defun Name-list (ss1 / i l EName EList BName NList)
  (setq l (sslength ss1))            
  (setq i 0 NList nil)
  (while (< i l)
    (setq EName (ssname ss1 i))       ;取得图元名
    (setq EList (entget EName))       ;取得图元表
    (setq BName (cdr (assoc 2 EList)));取得图块名
    (if (not (member BName NList))    ;如果表中没有图块名
      (setq NList (cons BName NList)) ;添加到表中
    )
    (setq i (1+ i))                   ;计数器加1
  )
  NList
)
;;;计数函数
(defun Name-count (ss2 NamLst / blist i l ename elist bname oldcount newcount)
  (setq Blist (mapcar '(lambda (x) (cons x 0)) NamLst))       ;计数器归零
  (setq i 0 l (sslength ss2))
  (while (< i l)                                              ;对选择区域循环
    (setq ename (ssname ss2 i))                               ;取得图元名
    (setq elist (entget ename))                               ;取得图元表
    (setq bname (cdr (assoc 2 elist)))                        ;取得图块名
    (if (member bname NamLst)                                 ;如果是要统计的块
      (setq OldCount (assoc bname Blist)                      ;取得块数量
            NewCount (1+ (cdr OldCount))                      ;计数器加1
            Blist (subst (cons bname NewCount) OldCount Blist);替代原数量
      )      
    )
    (setq i (1+ i))
  )
  BList
)
[/php]

附件中包含了lisp程序和演示文件

smxsmx

下来后是0字节,
重传吧

highflybird

现在可以下载了，用IE或者傲游老上传不上去！---哎，这个该死的熬油。

如果不能下载，请到下面网址：
http://www.mjtd.com/BBS/dispbbs. ... ID=58012&page=1
重新上传一个lisp程序！
是因为针对很多人用天正，所以改了一下，能适合天正图块。

liubingxia

用FILTER命令就可以，用不着这么麻烦吧！

highflybird

最初由 liubingxia 发布
[B]用FILTER命令就可以，用不着这么麻烦吧！ [/B]

用filter固然可以，但是麻烦，而且不能统计多个，而且过滤器对天正的某些实体不起作用（大家不妨试验一下）。
编这个程序的目的就是为了：
１。对于不知道过滤器用法的一些人也能够适用。
２。对天正的实体也能够适用。
３。有选择性的对所选区域进行统计。

woudy

不错,用ACAD自己的"属性提取"功能也能够实现.

zhangq_cai1

改成输出到表格就更好了~~~~~~~~~~~~~~~~~~~~~~·

chleiwu

看不见附件哦

清风明月10

谢谢楼主代码分享！

wyq20110208

新手学习，感谢分享

renyonghua2014

学习了，学习提供啊

7895927

这个历害，搞设计的统计就方便了。