[编程申请]：lsp如何调用自己的pgp文件

yinzhun22

想把自己添加的一些程序快捷命令，写在一个自己的pgp文件中如：DQ.pgp，不知道如何用lsp来调用，不希望手动复制到acad.pgp里，希望高手帮忙……

AyungerStudio

(defun C:ayCMD(/ PGPFile fp i xString aList shortCMD GlobalCMD)
        (vl-load-com)
        (setq PGPFile "Ayunger.pgp");F:\\Ayungerstudio\\VLisp\\Ayunger.pgp
        (if (setq PGPFile (findfile PGPFile))
                (progn;then
                        (setq fp (open PGPFile "r"))
                        (setq i 1)
                        (while (setq xString (read-line fp))
                                (if (= (type xString) 'SYM) (setq xString (vl-symbol-name xString)));转换数据文件中无引号的字符串.
                          (while (vl-string-search " " xstring);去掉所有的空格.
                                        (setq xString(vl-string-subst "" " " xstring));空格.
                                        (setq xString(vl-string-subst "" "        " xstring));tab符.
                                );end_while
                                (if (and (/= (substr xString 1 1) ";") (vl-string-search "," xstring) (vl-string-search "*" xstring))
                                        (progn
                                                (setq aList (read (strcat "(" (vl-string-subst " . C:" ",*" xString) ")")))
                                                (setq shortCMD (vl-string-trim " " (vl-symbol-name (car aList))))
                                                (setq GlobalCMD (cdr aList))
                                                ;(vlax-remove-cmd shortCMD);删除已定义的命令.
                                                (vlax-add-cmd shortCMD GlobalCMD)
                                        );end_progn
                                );end_if
                                (setq i (+ i 1))
                        );end_while read-line
                        (close fp)
                );end_progn then
                (princ "\nAY工具简化命令定义文件 Ayunger.pgp 没找到或不存在!")
        );end_if
        (princ)
);end_defun

;;Ayunger.PGP
;;
;;     AY工具命令简化设置文件
;;
;; Copyright Ayunger Studio 2001-2008
;;   E-mail: AyungerStudio@163.com
;;
;; 格式:  <简化命令>,  *<完全命令>
;;
ARW,        *ayArw         
TL,         *ayRailway      
SPX,        *aySpx         
ZPX,        *ayZpx         
PDX,        *ayPdx         
PDXC,       *ayPdxC         
CX,         *ayPerCurve     
QX,         *ayTanCurve     
LL,         *ayLL

yinzhun22

命令: aycmd
Error：参数类型错误: symbolp 22

AyungerStudio

调试呀，这个就是本人的《一个非常好用的AutoCAD工具集》中的函数，当然ayunger.pgp文件要放置到autoCAD的搜索路径下，否则需要加入长路径。
请检查pgp文件格式对不对？

yinzhun22

试了下确实是我的pgp文件有点问题，不过还有一个问题，就是我要按aycmd才能调用ayunger.pgp，不知道能不能让他在加载lsp文件时就自动运行……

AyungerStudio

;;把这个至于程序文件的最后或适当位置即可！
;;;┏━━━━━━━━━━━━━━━━━━━━━┓  
;;;┃    AY工具快捷命令自动加载调用            ┃  
;;;┃ 需放在该函数的被调用函数后方可自动执行   ┃  
;;;┗━━━━━━━━━━━━━━━━━━━━━┛  
(C:ayCMD);AY工具快捷命令自动加载调用               
(princ "\nAutoCAD AYunger Tools Copyright (C)2001-2008 AYunger Studio")
(prin1)

yinzhun22

谢谢，可以了
再请教下，如果是把cad本来的命令改成自定义的快捷键，可以写在自己的pgp文件里，一起调用吗