[求助]：如何得出连续直线的端点

xyzjint_cn

如何用程序实现如下功能：
只选取直线中的第一条起始直线LN1，得到所有点的列表list，列表形式为（pt1  pt2 pt3 pt4 pt5 pt6)
直线如下图

狂刀

1、提取直线2端点
2、分别 (ssget "c" pt pt '((0 . "LINE")))

cy956

(DEFUN cy_lines_pb (start_line filt / CLINE EDATA END_PLINE K-REV NLINE PT PT1
                         PT2 SS1 VERTEXSET _EXIT)
  ;;;由任意一线搜所有头尾相连的直线
  (setq        k-rev        nil
        end_pline nil
        edata (entget start_line)
        pt1 (dxf 10 edata)
        pt2 (dxf 11 edata)
        cline start_line
        _exit nil
        vertexset (list pt2 pt1))
  (while (not _exit)
;;;    (setq ss1 (ssget "c" pt1 pt1 '((0 . "line") (8 . "2d墙面"))))
    (setq ss1 (ssget "c" pt1 pt1 filt))
    (if        (and ss1 (ssmemb cline ss1))
      (setq ss1 (ssdel cline ss1))
    )
    (if        (and ss1 (> (sslength ss1) 0))
      (setq nline (ssname ss1 0))
      (setq nline nil)
    )
    (if        nline
      (if (equal nline start_line)
        (setq _exit t)
        (progn (setq edata (entget nline))
               (if (< (distance (dxf 10 edata) pt1)
                      (distance (dxf 11 edata) pt1)
                   )
                 (setq pt (dxf 11 edata))
                 (setq pt (dxf 10 edata))
               )
               (if k-rev
                 (setq vertexset (cons pt vertexset))
                 (setq vertexset (append vertexset (list pt)))
               )
               (setq cline nline)
               (setq pt1 pt)
               (if (< (distance pt2 pt) 0.1)
                 (setq _exit t)
               )
        )
      )
      (progn
         (if (not end_pline)
               (progn (setq end_pline t
                            k-rev t
                      )
                      (setq pt        pt2
                            pt2        pt1
                            pt1        pt
                      )
                      (setq start_line cline)
               )
               (setq _exit t)
             )
      )
    )
  )
  vertexset
)