多选直线按指定打断距离打断直线

xtdwynij

高手真多！学习啦！慢慢学。谢谢各位前辈师兄们出手相助！谢谢晓东大神！！

xtdwynij

zxq0220 发表于 2013-4-14 08:10

                               
登录/注册后可看大图

(defun c:tt ()
  (setvar "osmode" 0)
  (setvar "cmdecho" 0)

[pcode=lisp,true]
(defun c:tt ()
  (setvar "osmode" 0)
  (setvar "cmdecho" 0)
   (setq ss (ssget '((0 . "LINE"))))
   (setq i 0)
   (repeat (sslength ss)
     (setq name (ssname ss i))
     (setq ent (entget name))
     (setq pt10 (cdr (assoc 10 ent)))
     (setq pt11 (cdr (assoc 11 ent)))
     (setq dist (distance pt10 pt11))
     (setq ang (angle pt10 pt11))
     (cond
       ((>= dist 20) (if (=(rem(/ dist 100))0) (setq gs (/ dist 100)) (setq gs (1+ (fix (/ dist 100))))))   
       ((< dist 20) (setq gs 1))
       (t (alert "桥位出了问题了"))
     )                      ; 桥位的个数
     
     (setq b (if (>= dist 20) 2 0.75)) ;此处为打断的一半距离
     (setq abc 1)
     (setq dist1 (/ dist (1+ gs)))
     (repeat gs  
       (setq pt1 (polar pt10 ang dist1)) ; 距离  
       (setq pt2 (polar pt1 ang b)
             pt3 (polar pt1 ang (- b))
       )
       (command "_.break" "f" pt2  pt3) ;此处遇到了问题,打断的话这样类似于修剪,产生新的图元也是这样么?求出手~~
       (setq dist1 (+ dist1 dist1))
       (setq abc (1+ abc))
     )
     (setq i (1+ i))
   )
   (setvar "osmode" 3)
   (setvar "osmode" 1)
)
[/pcode]

Free-Lancer 师兄.我根据你的代码做了以下修改.但一样也是不行.拿了你的代码运行也达不到我要的郊果!晓东大神曾指点打断后得出最后的图元,可实在是搞不懂这些!还请出手完善代码!

xtdwynij

xtdwynij 发表于 2013-4-14 16:44

                               
登录/注册后可看大图

(defun c:tt ()
  (setvar "osmode" 0)
  (setvar "cmdecho" 0)

如何始终选 择原实体呢?如果是纯LISP的话.VL开头的函数菜鸟我还没有开始学!

Free-Lancer

用 Dwg 说明，30 楼代码可以打断，不过大于 100 的是按等分数断开（均分）

xtdwynij

Free-Lancer 发表于 2013-4-14 16:52

                               
登录/注册后可看大图

用 Dwg 说明，30 楼代码可以打断，不过大于 100 的是按等分数断开

DWG说明是什么意思?嗯.30楼师兄的代码是有一段线是打成很多段的!F白ree-Lancer师兄能完善一下我的代码么?纯LISP的!VL的回头我再看一下各自的作用!

Free-Lancer

没搞明白你的 105 打断两次，200的也打断两侧是什么意思？多长距离打断？在 100 的地方？

xtdwynij

我的意思是这样!假如是长度大于20少于或等于100的打断距离为4MM 打断一次 长度小于20的打断距离为1.5MM 也是打断一次 长度超过一百的除以100 有余数的等于结果整数+1 没有余数的直接等于结果整数 比如:105\100 余数为5 有余数就加1 那么就等于整数+1 打断二次 200\100 没有余数那么就等于2 不加 打断距离都是4MM

xtdwynij

xtdwynij 发表于 2013-4-14 17:16

                               
登录/注册后可看大图

我的意思是这样!假如是长度大于20少于或等于100的打断距离为4MM 打断一次 长度小于20的打断距离为1.5MM 也是 ...

平均打断~!

Free-Lancer

30 楼的代码就是这样的啊，如果是2004开始加一句 (vl-load-com)

xtdwynij

xtdwynij 发表于 2013-4-14 17:17

                               
登录/注册后可看大图

平均打断~!

打断后线的长度是相同的!

Free-Lancer

知道了，现在大于200的首尾段和中间段不同

Free-Lancer

这样就对了
[pcode=lisp,true];;(vl-load-com)
(defun c:tt (/ mkline getpts ss i sl e el sp ep pl)
  ;;divide n
  (defun getpts        (sp ep n dw / d d1 d2 an p1 p2)
    (setq d  (distance sp ep)
          d1 (- d (* (1- n) 2. dw))
          an (angle sp ep)
          d2 (/ d1 n)
          tf t
    )
    (repeat (1- n)
      (setq p1 (polar sp an d2)
            p2 (polar p1 an (* dw 2))
            pl (cons (list p2 p1) pl)
            sp p2
      )
    )
    (apply 'append pl)
  ) ;_生成逆序点，用来Break
  ;;Main
  (while (setq ss (ssget '((0 . "line"))))
    (setq sl (sslength ss)
          i  -1
    )
    (repeat sl
      (setq e  (ssname ss (setq i (1+ i)))
            el (entget e)
            sp (cdr (assoc 10 el)) ;_dxf
            ep (cdr (assoc 11 el)) ;_dxf
            d  (distance sp ep) ;_line length
               ;;sp (vlax-curve-getstartpoint e);_比assoc + cdr 简单高效
               ;;ep (vlax-curve-getendpoint e)
               ;;d  (vlax-curve-getEndParam e);_对Line而言省了distance,如果是spline,arc,pline 要改改
      )
      (cond
        ((< 0 d 20.)
         (setq pl (getpts sp ep 2 0.75))
        )
        ((<= 20 d 100)
         (setq pl (getpts sp ep 2 2.))
        )
        ((< 100 d)
         (setq pl (getpts sp ep (1+ (fix (/ d 100.))) 2.))
        )
      )
      (while pl
        (vl-cmdf ".break"
                 (list e sp)
                 "_f"
                 "_none"
                 (car pl)
                 "_none"
                 (cadr pl)
        ) ;_始终选择的是原实体
        (setq pl (cddr pl))
      )
    )
  )
  (princ)
)[/pcode]

xtdwynij

Free-Lancer 发表于 2013-4-14 18:25

                               
登录/注册后可看大图

这样就对了
;;(vl-load-com)
(defun c:tt (/ mkline getpts ss i sl e el sp ep pl)

是这样的郊果!8谢Free-Lancer 师兄出手相助.也怪我没有表达清楚!下次发贴前一定要表达清楚!麻烦了很多人.感到蛮不好意思的!

ayue52122

额 看不明白 看不明白啊

ysq101

这里高手如云