(多重表)递归操作

炫翔

;分别在元素末尾加上 晓东 两字

执行前:
(SETQ LST '(123 ("A" "B" "C" (123 456 789))))

执行后:
(SETQ LST2 ("123晓东" ("A晓东" "B晓东" "C晓东" ("123晓东" "456晓东 " "789晓东"))))

炫翔

弄一个实例，引导大家，

[pcode=lisp,true];去除表中相同图元, BY顾版
;(gxl-delsame '(5 2 2 3 3 3 4 5));返回(5 2 3 4)
(defun gxl-delsame (l)
  (if L
    (cons (car L) (gxl-delsame (vl-remove (car L) (cdr L))));从(cdr L)删除(car L)元素
  )
)[/pcode]

炫翔

[pcode=lisp,true];;;小函数测试时间,ti为使用次数,funname为函数名,funarglist为函数funname的参数列表
;;;如(powerset (list 1 2 3))测试100000次运行时间使用代码为
;;;    (times 100000 'powerset (list (list 1 2 3)))
(defun times (ti funname funarglist / t1 t2)
  (setq t1 (getvar "date"))
  (repeat ti
    (vl-catch-all-apply
      funname
      funarglist
    )
  )
  (setq t2 (getvar "date"))
  (princ "函数:")
  (princ funname)
  (princ (strcat "运行" (rtos ti 2 0) "次" ))
  (princ "测试结果")
  (princ (menucmd (strcat "M=$(edtime,"
     (rtos (- t2 t1) 2 16)
     ",HH:MM:SS:MSEC)"
    )
  )
  )
)[/pcode]

Lispboy

相应版主号召，贴个看看。

[pcode=lisp,true]
(defun c:ttt ( / l lst1 lst2 tf x)
  (defun _tt (l / tf x)
    (setq tf (type l))
    (cond
      ((= tf 'list)
        (mapcar
          '(lambda (x)
             (_tt x)
           )
          l
        )
      )
      ((= tf 'str)
        (strcat l "晓东")
      )
      ((= tf 'int)
        (strcat (rtos l) "晓东")
      )
    )
  )
  (setq lst1 '(123 ("A" "B"
                    "C"
                    (123 456 789)
                   )
              )
  )                                       
  (setq lst2 (mapcar
               '(lambda (x)
                  (_tt x)
                )
               lst1
             )
  )
  (princ "\n***LST1=")
  (prin1 lst1)
  (princ "***")
  (princ "\n***LST2=")
  (prin1 lst2)
  (princ "***")
)
[/pcode]

Lispboy

上面的函数只考虑了题目的整数和字符串的情况，其他未判断~~

Lispboy

炫翔 发表于 2013-4-26 16:54

                               
登录/注册后可看大图

弄一个实例，引导大家，

;去除表中相同图元, BY顾版

这函数能删除嵌套表里面相同的吗？

Lispboy

炫翔 发表于 2013-4-26 16:54

                               
登录/注册后可看大图

弄一个实例，引导大家，

;去除表中相同图元, BY顾版

那版主给修改下啊，所有嵌套表里面重复的也都删除掉~

Lispboy

修改了下上面贴的代码，主程序里面有点逻辑问题~

[pcode=lisp,true]
(defun c:ttt ( / l lst1 lst2 tf x)
  (defun _tt (l / tf x)
    (setq tf (type l))
    (cond
      ((= tf 'list)
        (mapcar
          '(lambda (x)
             (_tt x)
           )
          l
        )
      )
      ((= tf 'str)
        (strcat l "晓东")
      )
      ((= tf 'int)
        (strcat (rtos l) "晓东")
      )
    )
  )
  (setq lst1 '(123 ("A" "B"
                    "C"
                    (123 456 789)
                   )
              )
  )                                       ;  (setq a '(1 2 4 (1 3)))
  (setq lst2 (_tt lst1))
  (princ "\n***LST1=")
  (prin1 lst1)
  (princ "***")
  (princ "\n***LST2=")
  (prin1 lst2)
  (princ "***")
)
[/pcode]

ll_j

[pcode=lisp,true](defun tt(ss)
  (mapcar
     '(lambda(x)
       (if (= (type x) 'INT)
         (strcat (itoa x) "晓东")
         (if (= (type x) 'STR)
           (strcat x "晓东")
           (tt x)
        )
      )
    )
    ss
  )
)[/pcode]

处处问题鸟

[pcode=lisp,true](defun f (l)
  (if l
    (cond
      ((atom (car l))
       (cons (strcat (VL-PRINC-TO-STRING (car l)) "晓东")
             (f (cdr l))
       )
      )
      ((= 'list (type (car l)))
       (cons (f (car l)) (f (cdr l)))
      )
    )
  )
)[/pcode]

cuyongping

支持！呵呵

77077

我也来凑个热闹

2. (defun addstr(lst);表中每项都添加字符
   
3. (mapcar
   
4.    '(lambda(X)
   
5.      (if (= (type x) 'list)
   
6.        (addstr x)
   
7.        (strcat (vl-princ-to-string x) "炫翔")
   
8.      )
   
9.    )
   
10. lst
    
11. )
    
12. )

(defun addstr(lst);表中每项都添加字符<br /> (mapcar <br />    '(lambda(X)<br />      (if (= (type x) 'list)<br />        (addstr x)<br />        (strcat (vl-princ-to-string x) "炫翔")<br />      )<br />    )<br /> lst<br /> )<br /> )

命令: (addstr '(123 ("A" "B" "C" (123 456 789))))
("123炫翔" ("A炫翔" "B炫翔" "C炫翔" ("123炫翔" "456炫翔" "789炫翔")))

不知道算不算成功!

czx663

2. (defun ttt (lst)
   
3.   (mapcar '(lambda (x) (strcat# x "晓东")) lst)
   
4. )
   
5. (defun strcat# (element str / Type1)
   
6.   (setq Type1 (type element))
   
7.   (cond
   
8.     ((= Type1 'list) (ttt element));1#
   
9.     ((= Type1 'Str) (setq element (strcat element str))) ;2#
   
10.     ((= Type1 'int)
    
11.      (setq element (strcat (itoa element) str))
    
12.     );3#
    
13.   );cond
    
14. );defun

(defun ttt (lst)<br />   (mapcar '(lambda (x) (strcat# x "晓东")) lst)<br /> )<br /> (defun strcat# (element str / Type1)<br />   (setq Type1 (type element))<br />   (cond<br />     ((= Type1 'list) (ttt element));1#<br />     ((= Type1 'Str) (setq element (strcat element str))) ;2#<br />     ((= Type1 'int)<br />      (setq element (strcat (itoa element) str))<br />     );3#<br />   );cond<br /> );defun