能不能把XREF文件的一部分给拷贝出来？

lisphk

我工作中会用到很多的XREF文件，能不能用LISP程序把其中的一部分给拷贝出来？我刚学LISP很多东西还摸不到头脑。

Lispboy

给你提供的命令，copyn 类似express的ncopy 。但比ncopy强。可以生成XREF里面的选定的实体的拷贝。

[pcode=lisp,true]
(defun c:copyn (/ blk blks e i lst obj tm ss)
  (setq    blks (vla-get-blocks
               (vla-get-activedocument (vlax-get-acad-object))
             )
        ss   (ssadd)
  )
  (while (and (setq e (nentselp "Select nested object to copy: "))
              (setq tm (caddr e))
              (setq blk (car (cadddr e)))
              (setq blk (vlax-ename->vla-object blk))
              (setq i (vla-item blks (vla-get-name blk)))
         )
    (if        (= (vla-get-isxref i) :vlax-false)
      (vlax-for        be i
        (if (and (setq e (entget (vlax-vla-object->ename be)))
                 (not (cdr (assoc 102 e)))
                 (setq obj (entmakex e))
                 (setq obj (vlax-ename->vla-object obj))
            )
          (progn
            (vla-transformby obj (vlax-tmatrix tm))
            (setq lst (cons (list obj (vla-get-color obj)) lst))
            (vla-put-color obj 1)
            (vla-update obj)
          )
          (princ (strcat "\nComplex entity not created [ "
                         (cdr (assoc 0 e))
                         " ]"
                 )
          )
        )
      )
      (progn
        (setq obj (vlax-ename->vla-object (entmakex (entget (car e)))))
        (vla-transformby obj (vlax-tmatrix tm))
        (setq lst (cons (list obj (vla-get-color obj)) lst))
        (vla-put-color obj 1)
        (vla-update obj)
      )
    )
  )
  (if lst
    (progn (foreach o lst
             ;;(vla-put-color (car o) (cadr o))
             (setq ss (ssadd (vlax-vla-object->ename (car o)) ss))
             (command ".draworder"
                      (vlax-vla-object->ename (car o))
                      ""
                      "front"
             )
           )
           (sssetfirst nil ss)
    )
  )
  (princ)
)

[/pcode]

lisphk

Lispboy 发表于 2013-4-30 01:25

                               
登录/注册后可看大图

给你提供的命令，copyn 类似express的ncopy 。但比ncopy强。可以生成XREF里面的选定的实体的拷贝。

谢谢，测试了，可以实现，这个程序还需要一次点一个，能不能像平时用窗口选需要的拷贝出来呢？

flowerson

很不错！Lispboy。能叫这个名字的估计是高手来的。

flowerson

Lispboy，高手您好！您的代码在模型空间我测试过，没有问题，但是再布局空间就不行了，请大侠相助！

flowerson

Lispboy,你好。发给你的压缩包一起解压再打开“helplispboy.dwg”，“平面图参照.dwg”和 “图框A3.dwg” 是参照来的，布局当中提出就有问题，请大侠试试。另外属性块也不行，参照中的块也不理想。

Lispboy

flowerson 发表于 2013-7-1 17:08
Lispboy,你好。发给你的压缩包一起解压再打开“helplispboy.dwg”，“平面图参照.dwg”和 “图框A3.dwg”  ...

你好，你试了刚发布的插件吗

http://bbs.xdcad.net/thread-669138-1-1.html

试验下，然后告诉我结果，另外，你单独开一个帖子吧，放这里容易发现不了。

bobbyzhoucj

Lispboy 发表于 2013-4-30 01:25
给你提供的命令，copyn 类似express的ncopy 。但比ncopy强。可以生成XREF里面的选定的实体的拷贝。

你好大神，我试了这个代码。发现如果是天正图元，就会死机，不知道能否优化一下？