关于LISP表处理的测试练习，看看谁的代码高效的前提下更简洁

GTJ116600 · 发表于 2013-5-26 16:59:31

呵呵，这种方式很好，对初学者学习非常有益呀

wowan1314 · 发表于 2013-5-26 17:16:11

本帖最后由 wowan1314 于 2013-5-26 20:01 编辑

;;WHILE方法
(DEFUN T1 (LST / LST1)
(SETQ LST1 NIL)
(WHILE (SETQ LST1 (CONS (LIST (CAR LST) (CADR LST)) LST1)
LST (CDR LST)
)
)
(reverse (CDR LST1))
)
;;foreach方法
(DEFUN T2 (A / LST)
(SETQ LST NIL)
(foreach b a (setq lst (cons (list b (cadr a)) lst) a (cdr a)))
(reverse (CDR LST))
)
;;mapcar方法1
(DEFUN T3 (LST)
(mapcar '(lambda (a b) (list a b)) lst (cdr lst))
);;mapcar方法2
(DEFUN T4 (a)
(apply 'mapcar (cons 'list (list a (cdr a))))
)
;;mapcar方法3
(DEFUN T5 (LST)
(mapcar 'LIST lst (cdr lst))
)

while、repeat、递归、foreach、mapcar 都可以实现。mapcar代码最简洁（估计也最高效）。

楼主来测效率吧。也算对此贴做个了结。
递归的话表长超过10000好像会出错.repeat方法速度肯定是慢点的。下面主要是对其他三种方法进行测试。有事先走了。还是楼主来测吧。

newer · 发表于 2013-5-26 19:05:57

(while (cdr lst)
(setq l (cons (list (car lst)(cadr lst)) l))
(setq lst (cdr lst))
)
(reverse l)

yxpxa · 发表于 2013-5-26 19:32:30

都是高人啊
应当放到一个固定的循环里运行10万次，看谁的速度快，最短的代码效率不一定最好哦。
楼主帮着测试一下，大家才有比较。

夜来风语声 · 发表于 2013-5-26 19:34:39

(defun split (l)
(if (cdr l)
(cons (list (car l) (cadr l)) (split (cdr l)))
)
)

Lispboy · 发表于 2013-5-26 20:12:14

wowan1314 发表于 2013-5-26 17:16
while、repeat、递归、foreach、mapcar 都可以实现。mapcar代码最简洁（估计也最高效）。

楼主来测效率 ...

好的，还有朋友贴代码吗？

大家先下个赌注吧，凭直觉赌下哪层楼的代码速度最快？

newer · 发表于 2013-5-26 20:25:03

Lispboy 发表于 2013-5-26 20:12
好的，还有朋友贴代码吗？

大家先下个赌注吧，凭直觉赌下哪层楼的代码速度最快？

要测试了？我宣布，我再加个代码，我的2个都要求测。:$ 少了reverse 换成append，一直想弄清哪个更快，以前懒，没做过，楼主代劳了。

(while (cdr lst)
(setq l (append l (list (list (car lst)(cadr lst)))))
(setq lst (cdr lst))
)

newer · 发表于 2013-5-26 20:27:10

我凭直觉当然是我的快{:soso_e113:}， 18楼和22楼，我赌 18 楼的快。

GTJ116600 · 发表于 2013-5-26 20:52:34

本帖最后由 GTJ116600 于 2013-5-26 21:25 编辑

初学者，凑个热闹，也来一个。

(defun tt(lst / i newlst )
(setq i 0 newlst nil)
(while (> (- (length lst) 1) i)
(setq newlst (cons (list (nth i lst)(nth (1+ i) lst)) newlst))
(setq i (1+ i))
)
(setq newlst (reverse newlst))
)

Love-Lisp · 发表于 2013-5-26 20:57:59

newer 发表于 2013-5-26 20:27
我凭直觉当然是我的快， 18楼和22楼，我赌 18 楼的快。

肯定11楼Underway的效率最高！代码最简短，而且用的都是最基本的函数！

处处问题鸟 · 发表于 2013-5-26 21:05:25

newer 发表于 2013-5-26 20:25
要测试了？我宣布，我再加个代码，我的2个都要求测。少了reverse 换成append，一直想弄清哪个更快， ...

append函数肯定要慢，而且慢多了，表越长越显得慢！在这个贴子里勿在浮沙筑高台--由LISP公理推导函数的几个练习 G版在4楼讨论过的！

cy956 · 发表于 2013-5-26 21:15:02

处处问题鸟发表于 2013-5-26 19:05
append函数肯定要慢，而且慢多了，表越长越显得慢！在这个贴子里勿在浮沙筑高台--由LISP公理推导函数 ...

append函数肯定要慢，一直在cdr大表的感觉也不快，所以mapcar那个极简但不一定快。

Lisper · 发表于 2013-5-26 21:24:51

cy956 发表于 2013-5-26 21:15
append函数肯定要慢，一直在cdr大表的感觉也不快，所以mapcar那个极简但不一定快。

我测试了一下部分代码，结果如下：
命令: tt
  4楼炫翔用时  21.716  秒
  7#楼Lisphk用时  90.153  秒
  9#楼wowan1314用时  21.59  秒
  11#楼Underway用时  2.761  秒
  14#楼wowan1314用时  19.188  秒
  18#楼newer用时  17.816  秒
  20#楼楼夜来风语声用时  18.049  秒
命令:

结果显示11楼的代码最快！
测试代码如下：

(defun c:tt ()
(repeat (setq i 1000)
(setq l (cons (setq i (1- i)) l))
)
;;4楼炫翔
(defun t11 (lst / lst1)
(setq lst1 nil)
(while (and (car lst) (cadr lst))
(setq lst1 (cons (list (car lst) (cadr lst)) lst1)
lst (cdr lst)
)
)
(reverse lst1)
)
(setq *StartTime* (car (_VL-TIMES)))
(repeat 10000
(t11 l)
)
(princ (strcat "\n 4楼炫翔用时 " (rtos (* 0.001 (- (car (_VL-TIMES)) *StartTime*)) 2 4) " 秒 "))
;;7#楼Lisphk
(defun t2 (a / l)
(setq i 0
l nil
)
(repeat (- (length a) 1)
(setq b (nth i a)
i (1+ i)
c (nth i a)
l (cons (list b c) l)
)
)
(reverse l)
)
(setq *StartTime* (car (_VL-TIMES)))
(repeat 10000
(t2 l)
)
(princ (strcat "\n 7#楼Lisphk用时 " (rtos (* 0.001 (- (car (_VL-TIMES)) *StartTime*)) 2 4) " 秒 "))
;;9#楼wowan1314
(DEFUN T12 (LST / LST1 T11)
(DEFUN T11 (LST)
(AND (cadr lst)
(setq lst1 (cons (list (car lst) (cadr lst)) lst1)
lst (cdr lst)
)
(T11 LST)
)
)
(SETQ LST1 NIL)
(T11 LST)
(reverse lst1)
)
(setq *StartTime* (car (_VL-TIMES)))
(repeat 10000
(t12 l)
)
(princ (strcat "\n 9#楼wowan1314用时 " (rtos (* 0.001 (- (car (_VL-TIMES)) *StartTime*)) 2 4) " 秒 "))
;;11#楼Underway
(defun t13 (a)
(apply 'mapcar (cons 'list (list a (cdr a))))
)
(setq *StartTime* (car (_VL-TIMES)))
(repeat 10000
(t13 l)
)
(princ (strcat "\n 11#楼Underway用时 " (rtos (* 0.001 (- (car (_VL-TIMES)) *StartTime*)) 2 4) " 秒 "))
;;14#楼wowan1314
(DEFUN T14 (A / LST)
(SETQ LST NIL)
(foreach b a
(setq lst (cons (list b (cadr a)) lst)
a (cdr a)
)
)
(reverse (CDR LST))
)
(setq *StartTime* (car (_VL-TIMES)))
(repeat 10000
(t14 l)
)
(princ (strcat "\n 14#楼wowan1314用时 " (rtos (* 0.001 (- (car (_VL-TIMES)) *StartTime*)) 2 4) " 秒 "))
;;18#楼 newer
(defun t15 (lst / l)
(while (cdr lst) (setq l (cons (list (car lst)(cadr lst)) l)) (setq lst (cdr lst)))(reverse l)
)
(setq *StartTime* (car (_VL-TIMES)))
(repeat 10000
(t15 l)
)
(princ (strcat "\n 18#楼newer用时 " (rtos (* 0.001 (- (car (_VL-TIMES)) *StartTime*)) 2 4) " 秒 "))
;;20#楼夜来风语声
(defun split (l) (if (cdr l) (cons (list (car l) (cadr l)) (split (cdr l))) ))
(setq *StartTime* (car (_VL-TIMES)))
(repeat 10000
(split l)
)
(princ (strcat "\n 20#楼楼夜来风语声用时 " (rtos (* 0.001 (- (car (_VL-TIMES)) *StartTime*)) 2 4) " 秒 "))
(princ)
)

(defun c:tt () 
    
  (repeat (setq i 1000) 
    (setq l (cons (setq i (1- i)) l)) 
    ) 
  ;;4楼炫翔 
  (defun t11 (lst / lst1) 
    (setq lst1 nil) 
    (while (and (car lst) (cadr lst)) 
      (setq lst1 (cons (list (car lst) (cadr lst)) lst1) 
      lst   (cdr lst) 
      ) 
    ) 
    (reverse lst1) 
  ) 
 (setq *StartTime* (car (_VL-TIMES))) 
  (repeat 10000 
    (t11 l) 
    ) 
  (princ (strcat "\n  4楼炫翔用时  " (rtos (* 0.001 (- (car (_VL-TIMES)) *StartTime*)) 2 4) "  秒 ")) 
  ;;7#楼Lisphk 
  (defun t2 (a / l) 
    (setq i 0 
    l nil 
    ) 
    (repeat (- (length a) 1) 
      (setq b (nth i a) 
      i (1+ i) 
      c (nth i a) 
      l (cons (list b c) l) 
      ) 
    ) 
    (reverse l) 
  ) 
 (setq *StartTime* (car (_VL-TIMES))) 
  (repeat 10000 
    (t2 l) 
    ) 
  (princ (strcat "\n  7#楼Lisphk用时  " (rtos (* 0.001 (- (car (_VL-TIMES)) *StartTime*)) 2 4) "  秒 ")) 
;;9#楼wowan1314 
  (DEFUN T12 (LST / LST1 T11) 
    (DEFUN T11 (LST) 
      (AND (cadr lst) 
     (setq lst1 (cons (list (car lst) (cadr lst)) lst1) 
     lst  (cdr lst) 
     ) 
     (T11 LST) 
      ) 
    ) 
    (SETQ LST1 NIL) 
    (T11 LST) 
    (reverse lst1) 
  ) 
 (setq *StartTime* (car (_VL-TIMES))) 
  (repeat 10000 
    (t12 l) 
    ) 
  (princ (strcat "\n  9#楼wowan1314用时  " (rtos (* 0.001 (- (car (_VL-TIMES)) *StartTime*)) 2 4) "  秒 ")) 
;;11#楼Underway 
  (defun t13 (a) 
    (apply 'mapcar (cons 'list (list a (cdr a)))) 
    ) 
  (setq *StartTime* (car (_VL-TIMES))) 
  (repeat 10000 
    (t13 l) 
    ) 
  (princ (strcat "\n  11#楼Underway用时  " (rtos (* 0.001 (- (car (_VL-TIMES)) *StartTime*)) 2 4) "  秒 ")) 
 
  ;;14#楼wowan1314 
  (DEFUN T14 (A / LST) 
    (SETQ LST NIL) 
    (foreach b a 
      (setq lst  (cons (list b (cadr a)) lst) 
      a  (cdr a) 
      ) 
    ) 
    (reverse (CDR LST)) 
  ) 
   (setq *StartTime* (car (_VL-TIMES))) 
  (repeat 10000 
    (t14 l) 
    ) 
  (princ (strcat "\n  14#楼wowan1314用时  " (rtos (* 0.001 (- (car (_VL-TIMES)) *StartTime*)) 2 4) "  秒 ")) 
;;18#楼 newer 
  (defun t15 (lst / l) 
  (while (cdr lst)   (setq l (cons (list (car lst)(cadr lst)) l))   (setq lst (cdr lst)))(reverse l) 
    ) 
     (setq *StartTime* (car (_VL-TIMES))) 
  (repeat 10000 
    (t15 l) 
    ) 
  (princ (strcat "\n  18#楼newer用时  " (rtos (* 0.001 (- (car (_VL-TIMES)) *StartTime*)) 2 4) "  秒 ")) 
;;20#楼夜来风语声 
  (defun split (l)  (if (cdr l)    (cons (list (car l) (cadr l)) (split (cdr l)))  )) 
     (setq *StartTime* (car (_VL-TIMES))) 
  (repeat 10000 
    (split l) 
    ) 
  (princ (strcat "\n  20#楼楼夜来风语声用时  " (rtos (* 0.001 (- (car (_VL-TIMES)) *StartTime*)) 2 4) "  秒 ")) 
  (princ) 
  )

cy956 · 发表于 2013-5-26 21:26:48

试试这样：
(setq b2(cdr b1)
b(mapcar 'list b1 b2))

cy956 · 发表于 2013-5-26 21:29:45

Lisper 发表于 2013-5-26 19:24
我测试了一下部分代码，结果如下：
命令: tt
4楼炫翔用时 21.716 秒

试试这样：
(setq b2(cdr b1)
b(mapcar 'list b1 b2))

账号		自动登录	找回密码
密码			立即注册

[研讨] 关于LISP表处理的测试练习，看看谁的代码高效的前提下更简洁

评分

评分

评分

评分