关于表格合并单元格的问题，大家探讨下。

XDSoft · 发表于 2013-7-4 16:11:28

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

如图，这是一个5X5的表格，用LINE画的，+其中有几个合并的单元格，问题是，如何判断单元格是否是合并的了，并且确定四条边框线在表格的确定位置？

QQ截图20130704160054.jpg

请点击此处下载

查看状态：需购买或无权限

您的用户组是：游客

文件名称:Drawing1.rar
下载次数:2 文件大小:54.67 KB
下载权限: 不限以上 [免费赚D豆]

eachy · 发表于 2013-7-4 16:15:47

针对这个图，用交点点数判断(不通用方法)

zml84 · 发表于 2013-7-4 16:16:33

牢固 · 发表于 2013-7-4 16:28:43

本帖最后由牢固于 2013-7-4 16:36 编辑

我的方法还是先生成个单元格的格子，然后再根据格子坐标生成单元格表！以下是取自我的XD_C2X程序中的子程序，可能需要最新的XDRX_API支持：

(defun SS2Lst (SS FUZZ / PL E TMP XL N COL YL ROW
I K X X1 X0 Y Y1 Y0 PTS GRIDLST
C1 R1 ang mat invmat
)
(if xdrx_document_ucsoff
(xdrx_document_ucsoff)
(xdrx_ucsoff)
)
(setq ang (angle (setq cen (cdr (assoc 10 (setq e (entget (ssname ss 0))))))
(cdr (assoc 11 e))
)
)
(if (equal ang pi 1e-8)
(setq ang 0)
(if (> ang pi)
(setq ang (- ang pi))
)
)
(if (equal ang (* pi 0.5) 1e-8)
(setq ang 0)
(if (> ang (* pi 0.5))
(setq ang (- ang (* pi 0.5)))
)
)
;;转换到平行于表格的矩阵
(setq mat (GXL-MAT:MXM
(Gxl-MAT:Rotation '(0 0 0) (- ang))
(GXL-MAT:TRANSLATION (mapcar '- cen))
)
invmat (gxl-mat-inverse mat) ;_ 逆矩阵
)
(setq tmp (XDRX_CURVE_INTERSECTBREAK ss 0))
(if tmp (setq ss tmp))
(setq pl (xdrx_geom_searchregions ss))
;(setq a1 pl m mat invm invmat)
(setq pl
(cdr
(vl-sort
pl
'(lambda (a b) (> (abs (apply 'xdrx_parea a)) (abs (apply 'xdrx_parea b))))
)
)
pl
(mapcar
'(lambda (x / l)
(apply 'XDRX_POINTSBOX (mapcar '(lambda (b) (GXL-MAT:MXP mat (append b '(0)))) x)) ;_ 左下、右下、右上、左上
;(list (cadddr l) (cadr l)) ;_ 左上、右下
)
pl
)
)
;(setq a2 pl)
;;点转换到平行于表格
;(setq pl (mapcar '(lambda (a) (mapcar '(lambda (b) (GXL-MAT:MXP mat b)) a)) pl))
;; 计算列数的X坐标，从小到大
(setq tmp (vl-sort (mapcar 'car (apply 'append pl)) '(lambda (a b) (< a b))))
(while tmp
(setq xl (cons (setq n (car tmp)) xl)
tmp (cdr tmp)
)
(while (and tmp (equal n (car tmp) fuzz))
(setq tmp (cdr tmp))
)
)
(setq xl (reverse xl) ;_ 列数的X坐标，从小到大
col (1- (length xl)) ;_ 列数
)
;;j计算行数的y坐标,从大到小
(setq tmp (vl-sort (mapcar 'cadr (apply 'append pl)) '(lambda (a b) (> a b))))
(while tmp
(setq yl (cons (setq n (car tmp)) yl)
tmp (cdr tmp)
)
(while (and tmp (equal n (car tmp) fuzz))
(setq tmp (cdr tmp))
)
)
(setq yl (reverse yl) ;_ 行数的y坐标,从大到小
row (1- (length yl)) ;_ 列数
)
(foreach pts pl
(setq GridLst
(cons
(list
(strcat
(vlxls-rangeid
(list
(progn
(setq c1 0)
(vl-some '(lambda (x)
(setq c1 (1+ c1))
(equal x (car (cadddr pts)) fuzz)
)
xl
)
c1
)
(progn
(setq r1 0)
(vl-some '(lambda (x)
(setq r1 (1+ r1))
(equal x (cadr (cadddr pts)) fuzz)
)
yl
)
r1
)
)
)
":"
(vlxls-rangeid
(list
(progn
(setq c1 -1)
(vl-some '(lambda (x)
(setq c1 (1+ c1))
(equal x (caadr pts) fuzz)
)
xl
)
c1
)
(progn
(setq r1 -1)
(vl-some '(lambda (x)
(setq r1 (1+ r1))
(equal x (cadadr pts) fuzz)
)
yl
)
r1
)
)
)
) ;_ 单元格名称
(mapcar (function (lambda (x) (GXL-MAT:MXP invmat (append x '(0))))) pts) ;_ 左下、右下、右上、左上
)
GridLst
)
)
)
;;单元格列表 '((单元格 (左下、右下、右上、左上)) ...)
(setq GridLst
(vl-sort GridLst '(lambda (a b) (< (car a) (car b))))
)
(list GridLst
(mapcar '(lambda (x) (car (GXL-MAT:MXP invmat (list x (apply 'max yl) 0)))) xl)
col
(mapcar '(lambda (y) (cadr (GXL-MAT:MXP invmat (list (apply 'min xl) y 0)))) yl)
row
(mapcar '- (cdr xl) xl) ;_ 各列宽度
(mapcar '- yl (cdr yl) ) ;_ 各行高度
)
)

(defun SS2Lst  (SS FUZZ /    PL   E  TMP  XL    N    COL  YL   ROW 
        I   K    X     X1  X0   Y    Y1   Y0   PTS   GRIDLST 
        C1   R1 ang mat invmat 
       ) 
    (if xdrx_document_ucsoff 
    (xdrx_document_ucsoff) 
    (xdrx_ucsoff) 
      ) 
   (setq ang (angle (setq cen (cdr (assoc 10 (setq e (entget (ssname ss 0)))))) 
         (cdr (assoc 11 e)) 
        ) 
    ) 
    (if (equal ang pi 1e-8) 
      (setq ang 0) 
      (if (> ang pi) 
  (setq ang (- ang pi)) 
  ) 
      ) 
    (if (equal ang (* pi 0.5) 1e-8) 
      (setq ang 0) 
      (if (> ang (* pi 0.5)) 
  (setq ang (- ang (* pi 0.5))) 
  ) 
      ) 
    ;;转换到平行于表格的矩阵 
    (setq mat (GXL-MAT:MXM 
    (Gxl-MAT:Rotation '(0 0 0) (- ang)) 
    (GXL-MAT:TRANSLATION (mapcar '- cen)) 
        ) 
    invmat (gxl-mat-inverse mat) ;_ 逆矩阵 
    ) 
    (setq tmp (XDRX_CURVE_INTERSECTBREAK ss 0)) 
    (if tmp (setq ss tmp)) 
    (setq pl (xdrx_geom_searchregions ss)) 
    ;(setq a1 pl m mat invm invmat) 
    (setq pl 
       (cdr 
         (vl-sort 
     pl 
     '(lambda (a b) (> (abs (apply 'xdrx_parea a)) (abs (apply 'xdrx_parea b)))) 
         ) 
       ) 
    pl 
       (mapcar 
         '(lambda  (x / l) 
      (apply 'XDRX_POINTSBOX (mapcar '(lambda (b) (GXL-MAT:MXP mat (append b '(0)))) x)) ;_ 左下 、右下、右上、左上 
      ;(list (cadddr l) (cadr l)) ;_ 左上 、右下 
    ) 
         pl 
       ) 
    ) 
    ;(setq a2 pl) 
    ;;点转换到平行于表格 
    ;(setq pl (mapcar '(lambda (a) (mapcar '(lambda (b) (GXL-MAT:MXP mat b)) a)) pl)) 
     ;; 计算列数的X坐标，从小到大 
    (setq tmp (vl-sort (mapcar 'car (apply 'append pl)) '(lambda (a b) (< a b)))) 
    (while tmp 
      (setq xl  (cons (setq n (car tmp)) xl) 
            tmp (cdr tmp) 
            ) 
      (while (and tmp (equal n (car tmp) fuzz)) 
        (setq tmp (cdr tmp)) 
        ) 
      ) 
    (setq xl  (reverse xl) ;_ 列数的X坐标，从小到大 
       col (1- (length xl)) ;_ 列数 
       ) 
   ;;j计算行数的y坐标,从大到小 
    (setq tmp (vl-sort (mapcar 'cadr (apply 'append pl)) '(lambda (a b) (> a b)))) 
    (while tmp 
      (setq yl  (cons (setq n (car tmp)) yl) 
            tmp (cdr tmp) 
            ) 
      (while (and tmp (equal n (car tmp) fuzz)) 
        (setq tmp (cdr tmp)) 
        ) 
      ) 
    (setq yl  (reverse yl) ;_ 行数的y坐标,从大到小 
          row (1- (length yl)) ;_ 列数 
          ) 
    (foreach pts pl 
      (setq GridLst 
       (cons 
         (list 
           (strcat 
       (vlxls-rangeid 
         (list 
           (progn 
             (setq c1 0) 
             (vl-some  '(lambda (x) 
             (setq c1 (1+ c1)) 
             (equal x (car (cadddr pts)) fuzz) 
           ) 
          xl 
             ) 
             c1 
           ) 
           (progn 
             (setq r1 0) 
             (vl-some  '(lambda (x) 
             (setq r1 (1+ r1)) 
             (equal x (cadr (cadddr pts)) fuzz) 
           ) 
          yl 
             ) 
             r1 
           ) 
         ) 
       ) 
       ":" 
       (vlxls-rangeid 
         (list 
           (progn 
             (setq c1 -1) 
             (vl-some  '(lambda (x) 
             (setq c1 (1+ c1)) 
             (equal x (caadr pts) fuzz) 
           ) 
          xl 
             ) 
             c1 
           ) 
           (progn 
             (setq r1 -1) 
             (vl-some  '(lambda (x) 
             (setq r1 (1+ r1)) 
             (equal x (cadadr pts) fuzz) 
           ) 
          yl 
             ) 
             r1 
           ) 
         ) 
       ) 
           ) ;_ 单元格名称 
           (mapcar (function (lambda (x) (GXL-MAT:MXP invmat (append x '(0))))) pts) ;_ 左下 、右下、右上、左上 
         )   
         GridLst 
       ) 
      ) 
      ) 
 
    ;;单元格列表 '((单元格 (左下 、右下、右上、左上)) ...) 
    (setq GridLst 
     (vl-sort GridLst '(lambda (a b) (< (car a) (car b)))) 
    ) 
    (list GridLst 
    (mapcar '(lambda (x) (car (GXL-MAT:MXP invmat (list x (apply 'max yl) 0)))) xl) 
    col 
    (mapcar '(lambda (y) (cadr (GXL-MAT:MXP invmat (list (apply 'min xl) y 0)))) yl) 
    row 
    (mapcar '- (cdr xl) xl) ;_ 各列宽度 
    (mapcar '- yl (cdr yl) ) ;_ 各行高度 
 
    ) 
  )

例如:(setq l (SS2Lst (ssget '((0 . "line"))) 0.01))

返回：

((("A1:B2" ((3339.11 911.139 0.0) (3378.81 911.139 0.0) (3378.81 953.107 0.0) (3339.11 953.107 0.0))) ("A3:A3" ((3339.11 890.154 0.0) (3358.96 890.154 0.0) (3358.96 911.139 0.0) (3339.11 911.139 0.0))) ("B3:B3" ((3358.96 890.154 0.0) (3378.81 890.154 0.0) (3378.81 911.139 0.0) (3358.96 911.139 0.0))) ("C1:C1" ((3378.81 932.123 0.0) (3398.66 932.123 0.0) (3398.66 953.107 0.0) (3378.81 953.107 0.0))) ("C2:C2" ((3378.81 911.139 0.0) (3398.66 911.139 0.0) (3398.66 932.123 0.0) (3378.81 932.123 0.0))) ("C3:D3" ((3378.81 890.154 0.0) (3418.51 890.154 0.0) (3418.51 911.139 0.0) (3378.81 911.139 0.0))) ("D1:D2" ((3398.66 911.139 0.0) (3418.51 911.139 0.0) (3418.51 953.107 0.0) (3398.66 953.107 0.0)))) (3339.11 3358.96 3378.81 3398.66 3418.51) 4 (953.107 932.123 911.139 890.154) 3 (19.8491 19.8491 19.8491 19.8491) (20.9844 20.9844 20.9844))

ayl1004 · 发表于 2013-7-4 17:09:04

曾经在固版的帖子里发过我的思路，整理下重新发：

;;;--------------- AYL-GetBoxAddrs 函数 ---------------;;;
;;;(AYL-GetBoxAddrs DPntLst HHLst VWLst) ;;;
;;;获取Acad表格中每个方框的地址。 ;;;
;;;DPntLst Acad表格所有的点对表，第一项是右上方的方框，;;;
;;; 最后一项是左下的方框。 ;;;
;;;HHLst Acad表格每一行的行高 ;;;
;;;VWLst Acad表格每一列的列宽 ;;;
;;;----------------------------------------------------;;;
(defun AYL-GetBoxAddrs (DPntLst HHLst VWLst / RetLst AYL-SearchHV
MaxPnt AYL-itoa AYL-GetBoxAddress AYL-EvaMList)
;;搜索实数表前 n项和和指定值相等，并返回移除这 n项后，余下的元素个数；
;;如果所有表里元素和小于指定值，那么返回 0。
(defun AYL-SearchHV (value Lst fuzz / s)
(setq s 0.0)
(length
(cdr (vl-member-if
(function
(lambda (x) (equal (setq s (+ s x)) value fuzz))
)
Lst
)
)
)
)
;;将整数转换成大写字母
(defun AYL-itoa (a)
(cond
((< a 0) "")
((>= a 0)
(strcat (AYL-itoa (1- (fix (/ a 26))))
(chr (+ 65 (rem a 26)))
)
)
(t nil)
)
)
(defun AYL-EvaMList (Func Lst)
(apply 'mapcar (cons Func Lst))
)
;;-------------------- AYL-GetBoxAddress 函数 --------------------;;
;;(AYL-GetBoxAddress DPnt ruPnt HHs VWs fuzz) ;;
;;获取指定方框在Acad表格中的地址。 ;;
;; ;;
;;DPnt 指定方框的对角点点对表 ;;
;;ruPnt Acad表格的右上点 ;;
;;HHs Acad表格所有行行高的表，按行从高往底排列 ;;
;;VWs Acad表格所有列列宽的表，按列从右往左排列 ;;
;;fuss 容差 ;;
;;返回值：方框地址和方框对角点组成的表. ;;
;; ;;
;;注意：若给定的方框不是指定表格的方框，造成的错误未知。 ;;
;;----------------------------------------------------------------;;
(defun AYL-GetBoxAddress (DPnt ruPnt HHs VWs fuzz / xi yi xa ya)
(setq xi (- (car ruPnt) (caar DPnt))
xi (AYL-SearchHV xi VWs fuzz)
yi (- (cadr ruPnt) (cadar DPnt))
yi (- (length HHs) (AYL-SearchHV yi HHs fuzz))
xa (- (car ruPnt) (caadr DPnt))
ya (- (cadr ruPnt) (cadadr DPnt))
)
(cond
((equal xa 0.0 fuzz) (setq xa (1- (length VWs))))
(t (setq xa (1- (AYL-SearchHV xa VWs fuzz))))
)
(cond
((equal ya 0.0 fuzz) (setq ya 1))
(t (setq ya (1+ (- (length HHs) (AYL-SearchHV ya HHs fuzz)))))
)
(cond
((and (= xi xa) (= yi ya)) (cons (strcat (AYL-itoa xi) (itoa yi)) DPnt))
(t (cons (strcat (AYL-itoa xi) (itoa ya) ":" (AYL-itoa xa) (itoa yi)) DPnt))
)
)
(setq MaxPnt (AYL-EvaMList 'max (mapcar 'cadr DPntLst))
RetLst nil
)
(foreach Item DPntLst
(setq RetLst (cons (AYL-GetBoxAddress Item MaxPnt HHLst VWLst 0.00001) RetLst))
)
)

;;;--------------- AYL-GetBoxAddrs 函数 ---------------;;; 
;;;(AYL-GetBoxAddrs DPntLst HHLst VWLst)               ;;; 
;;;获取Acad表格中每个方框的地址。                      ;;; 
;;;DPntLst Acad表格所有的点对表，第一项是右上方的方框，;;; 
;;;    最后一项是左下的方框。                          ;;; 
;;;HHLst   Acad表格每一行的行高                        ;;; 
;;;VWLst   Acad表格每一列的列宽                        ;;; 
;;;----------------------------------------------------;;; 
(defun AYL-GetBoxAddrs (DPntLst HHLst    VWLst /  RetLst AYL-SearchHV 
                        MaxPnt  AYL-itoa AYL-GetBoxAddress AYL-EvaMList) 
  ;;搜索实数表前 n项和和指定值相等，并返回移除这 n项后，余下的元素个数； 
  ;;如果所有表里元素和小于指定值，那么返回 0。 
  (defun AYL-SearchHV (value Lst fuzz / s) 
    (setq s 0.0) 
    (length 
      (cdr (vl-member-if 
             (function 
               (lambda (x) (equal (setq s (+ s x)) value fuzz)) 
             ) 
             Lst 
           ) 
      ) 
    ) 
  ) 
  ;;将整数转换成大写字母 
  (defun AYL-itoa (a) 
    (cond 
      ((< a 0) "") 
      ((>= a 0) 
       (strcat (AYL-itoa (1- (fix (/ a 26)))) 
               (chr (+ 65 (rem a 26))) 
       ) 
      ) 
      (t nil) 
    ) 
  ) 
  (defun AYL-EvaMList (Func Lst) 
    (apply 'mapcar (cons Func Lst)) 
  ) 
  ;;-------------------- AYL-GetBoxAddress 函数 --------------------;; 
  ;;(AYL-GetBoxAddress DPnt ruPnt HHs VWs fuzz)                     ;; 
  ;;获取指定方框在Acad表格中的地址。                                ;; 
  ;;                                                                ;; 
  ;;DPnt  指定方框的对角点点对表                                    ;; 
  ;;ruPnt Acad表格的右上点                                          ;; 
  ;;HHs   Acad表格所有行行高的表，按行从高往底排列                  ;; 
  ;;VWs   Acad表格所有列列宽的表，按列从右往左排列                  ;; 
  ;;fuss  容差                                                      ;; 
  ;;返回值：方框地址和方框对角点组成的表.                           ;; 
  ;;                                                                ;; 
  ;;注意：若给定的方框不是指定表格的方框，造成的错误未知。          ;; 
  ;;----------------------------------------------------------------;; 
  (defun AYL-GetBoxAddress (DPnt ruPnt HHs VWs fuzz / xi yi xa ya) 
    (setq xi (- (car ruPnt) (caar DPnt)) 
          xi (AYL-SearchHV xi VWs fuzz) 
          yi (- (cadr ruPnt) (cadar DPnt)) 
          yi (- (length HHs) (AYL-SearchHV yi HHs fuzz)) 
          xa (- (car ruPnt) (caadr DPnt)) 
          ya (- (cadr ruPnt) (cadadr DPnt)) 
    ) 
    (cond 
      ((equal xa 0.0 fuzz) (setq xa (1- (length VWs)))) 
      (t (setq xa (1- (AYL-SearchHV xa VWs fuzz)))) 
    ) 
    (cond 
      ((equal ya 0.0 fuzz) (setq ya 1)) 
      (t (setq ya (1+ (- (length HHs) (AYL-SearchHV ya HHs fuzz))))) 
    ) 
    (cond 
      ((and (= xi xa) (= yi ya)) (cons (strcat (AYL-itoa xi) (itoa yi)) DPnt)) 
      (t (cons (strcat (AYL-itoa xi) (itoa ya) ":" (AYL-itoa xa) (itoa yi)) DPnt)) 
    ) 
  ) 
  (setq MaxPnt (AYL-EvaMList 'max (mapcar 'cadr DPntLst)) 
        RetLst nil 
  ) 
  (foreach Item        DPntLst 
    (setq RetLst (cons (AYL-GetBoxAddress Item MaxPnt HHLst VWLst 0.00001) RetLst)) 
  ) 
)

XDSoft · 发表于 2013-7-4 17:09:40

zml84 发表于 2013-7-4 16:16

是对LINE操作的吗，可否贴下算法和代码。

XDSoft · 发表于 2013-7-4 17:10:35

1楼，附件图贴上来了，大家用附件的图讨论吧。

XDSoft · 发表于 2013-7-4 17:14:17

ayl1004 发表于 2013-7-4 17:09
曾经在固版的帖子里发过我的思路，整理下重新发：

可否整理，说下思路，算法要点。

ayl1004 · 发表于 2013-7-4 17:23:54

XDSoft 发表于 2013-7-4 17:14
可否整理，说下思路，算法要点。

分别计算方框的左下点和右上点到表格右上点的水平距离和垂直距离，来确定方框在表格中的位置，以及是否是合并单元格。

XDSoft · 发表于 2013-7-4 17:28:27

ayl1004 发表于 2013-7-4 17:23
分别计算方框的左下点和右上点到表格右上点的水平距离和垂直距离，来确定方框在表格中的位置，以及是否是 ...

1、首先要确定方框，这个如何确定？

2、如果根据坐标，判断是一个合并的单元格，及这个单元格的编号？

ayl1004 · 发表于 2013-7-4 17:39:55

XDSoft 发表于 2013-7-4 17:28
1、首先要确定方框，这个如何确定？

2、如果根据坐标，判断是一个合并的单元格，及这个单元格的编 ...

1 根据选择的直线得到所有方框的对角点，这应该不难吧
2 水平距离和垂直距离不刚好说明两个点相隔多少行和多少列吗

XDSoft · 发表于 2013-7-4 17:45:55

ayl1004 发表于 2013-7-4 17:39
1 根据选择的直线得到所有方框的对角点，这应该不难吧
2 水平距离和垂直距离不刚好说明两个点相隔多少 ...

水平距离和垂直距离不刚好说明两个点相隔多少 ..

如果对于所有列宽都相等，行高都相等的情况，容易求，如果列宽、行高都不固定，随机，有什么算法求是否是合并的单元格呢？

ayl1004 · 发表于 2013-7-4 17:55:53

XDSoft 发表于 2013-7-4 17:45
如果对于所有列宽都相等，行高都相等的情况，容易求，如果列宽、行高都不固定，随机，有什么算法求 ...

我上面的函数里有两个变量，HHLst 保存所有行行高，从高往低按顺序排列 VWLst 保存所有列列宽，从右往左排列，表的个数就是多少行多少列，表里前几个元素的和就是后几行和后几列的总高和总宽。
还有四个变量xi yi xa ya就是方框的左下点和右上点，如果(list xi yi) 和 (list xa ya)指向同一个单元格，那就是非合并的，否则就是合并的。

XDSoft · 发表于 2013-7-4 18:30:04

(list xi yi) 和 (list xa ya)指向同一个单元格

如何判断是否指向同一个单元格？

守仁格竹GM · 发表于 2013-7-4 18:32:54

假如出现不完全重复的线呢，一个长一个短重复

账号		自动登录	找回密码
密码			立即注册

[研讨] 关于表格合并单元格的问题，大家探讨下。

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

点评

点评

点评

点评

评分

点评

点评

点评

评分

点评

点评