Creating a gradient hatch using VLisp

st788796

Creating a gradient hatch using VLispBy Balaji Ramamoorthy
Here is a Visual Lisp example that adds a circle to model space and fill it with a gradient hatch.

(defun c:addGHat (/       acadObject  acaddocument
      mspace      mycircle   myloop      myhatch
      col1       col2
      )
    (vl-load-com)

    (setq acver (substr (getvar "acadver")1 2))

    (SetQ acadobject   (VLAX-Get-ACAD-Object)
   acaddocument (VLA-Get-ActiveDocument acadobject)
   mspace      (VLA-Get-ModelSpace acaddocument)
   )
    (SetQ mycircle (VLA-AddCircle
       mspace
       (VLAX-3D-Point '(50.0 50.0 0.0))
       150.0
       )
   )
    (SetQ myloop (VLAX-Make-SafeArray vlax-vbObject '(0 . 0)))
    (VLAX-SafeArray-Put-Element
      myloop
      0
      mycircle
      )
  
   (SetQ myhatch (VLA-AddHatch
      mspace
      acPreDefinedGradient
      "LINEAR"  
      :vlax-true
      acGradientObject
      )
   )
  
   (setq col1 (vla-GetInterfaceObject
          (vlax-get-acad-object)
          (strcat "AutoCAD.AcCmColor." acver)
          )
   )
  
   (setq col2 (vla-GetInterfaceObject
          (vlax-get-acad-object)
          (strcat "AutoCAD.AcCmColor." acver)
          )
   )
  
   (vla-SetRGB col1 255 0 0)
   (vla-setrgb col2 0 0 255)
  
   (vla-put-gradientcolor1 myhatch col1)
   (vla-put-gradientcolor2 myhatch col2)
  
   (VLA-AppendOuterLoop myhatch myloop)
   (VLA-Evaluate myhatch)
)

Update : Thanks to Oleg for suggesting the use of acadVer instead of using "AutoCAD.AcCmColor.19" to get the color object.

GTJ116600

太给力了，好，赞一个