(XD::Geom:NumDiv)给定参数值，起始值，等分数，返回等分后的参数表

Lispboy · 发表于 2013-8-18 01:49:01

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

;|
等分数
参数：
num --- 数
start --起始数
div ---等分数
|;
(defun XD::Geom:NumDiv (num start div / i numl num1)
(setq i 1 div (fix div) num1 (float (- num start)))
(repeat (- div 1)
(setq numl (cons (+ start (* i (/ num1 div))) numl)
i (1+ i)
)
)
(cons start (reverse (cons num numl)))
)

ll_j · 发表于 2013-8-18 09:07:25

想来想去这个函数有点什么问题，终于想明白了，输入参数应该是start、end、div，对于共用函数，num是无意义的，只要在某个范围内均分就可以了。
更实际的应用应该是在两点间均分和沿曲线均分。
两点间均分也不难，只是修改一下就可以了，沿曲线均分就不同了，涉及到ent、start、end和div。

Lispboy · 发表于 2013-8-18 09:28:07

ll_j 发表于 2013-8-18 09:07
想来想去这个函数有点什么问题，终于想明白了，输入参数应该是start、end、div，对于共用函数，num是无意义 ...

num 就是 end 啊

st788796 · 发表于 2013-8-18 09:30:44

一说参数就想到曲线，仔细一看LZ这个仅是"数"间均分，和曲线没关系！来自: Android客户端

ll_j · 发表于 2013-8-18 10:07:30

Lispboy 发表于 2013-8-18 09:28
num 就是 end 啊

不好意思，是我自己把自己绕糊涂了，有start、end的先入为主的次序，再加上曲线有“头”的顽固理念，num在头脑里就怎么也理不清了。{:soso_e110:}

Lispboy · 发表于 2013-8-18 10:11:06

ll_j 发表于 2013-8-18 10:07
不好意思，是我自己把自己绕糊涂了，有start、end的先入为主的次序，再加上曲线有“头”的顽固理念，num ...

{:soso_e112:}

其实我把NUM写前面可能不太符合习惯吧，我的意思是等分”数",所以先给的END，如果start是0，就是等分这个给的“数”了。

Lispboy · 发表于 2013-8-18 10:14:04

st788796 发表于 2013-8-18 09:30
一说参数就想到曲线，仔细一看LZ这个仅是"数"间均分，和曲线没关系！

写这个就是为了和“曲线”发生关系啊{:soso_e112:}

如果是线性曲线的，等分的数就是等分(距离)曲线的参数值

如果非线性的，等分的数可以给起始的距离和终止的距离，那么等分的就是距离了，把这个等分的数送给 xdrx_getParamAtDist,xdrx_getPointAtDist就得到“等分点”了啊。

Free-Lancer · 发表于 2013-8-26 17:40:34

库函数不是这个! 改下用法

(defun XD::Geom:DivNumBy (lst / num start end spa v1 v ll len _len)
(setq num (car lst)
start (cadr lst)
end (caddr lst)
spa (cadddr lst)
len (- end start)
)
(if spa
(progn
(setq _len (/ (- len (* (1- num) spa)) num))
(if (> _len 0.)
(progn
(setq v1 (+ _len spa)
v (list v1 v1)
)
(repeat (1- (fix num))
(if ll
(setq ll (cons (mapcar
'-
(car ll)
v
) ll
)
)
(setq ll (list (list (- end _len) end)))
)
)
(setq ll (cons (list start (+ start _len)) ll))
)
)
)
(progn
(setq _len (/ len num))
(repeat (1+ (fix num))
(if ll
(setq ll (cons (- (car ll) _len) ll))
(setq ll (list end))
)
)
)
)
ll
)

(defun XD::Geom:DivNumBy (lst / num start end spa v1 v ll len _len) 
  (setq num (car lst) 
        start (cadr lst) 
        end (caddr lst) 
        spa (cadddr lst) 
        len (- end start) 
  ) 
  (if spa 
    (progn 
      (setq _len (/ (- len (* (1- num) spa)) num)) 
      (if (> _len 0.) 
        (progn 
          (setq v1 (+ _len spa) 
                v (list v1 v1) 
          ) 
          (repeat (1- (fix num)) 
            (if ll 
              (setq ll (cons (mapcar 
                               '- 
                               (car ll) 
                               v 
                             ) ll 
                       ) 
              ) 
              (setq ll (list (list (- end _len) end))) 
            ) 
          ) 
          (setq ll (cons (list start (+ start _len)) ll)) 
        ) 
      ) 
    ) 
    (progn 
      (setq _len (/ len num)) 
      (repeat (1+ (fix num)) 
        (if ll 
          (setq ll (cons (- (car ll) _len) ll)) 
          (setq ll (list end)) 
        ) 
      ) 
    ) 
  ) 
  ll 
)

Free-Lancer · 发表于 2014-9-12 19:46:23

本帖最后由 Free-Lancer 于 2014-9-12 19:48 编辑

保持原函数，增加一个功能，尾参数可以为表，适合在周期数内计算

(defun XD::Geom:NumDiv (num start div / NumDiv tol lst)
(defun NumDiv (num start div / i numl dis n m)
(setq i 0)
(if (eq (type div) 'REAL)
(setq n (/ (float (- num start)) div)
m (if (>= n (fix n))
(1+ (fix n))
(fix n)
)
dis div
)
(setq m (1+ div)
dis (/ (float (- num start)) div)
)
)
(repeat (fix m)
(setq numl (cons (+ start (* i dis)) numl)
i (1+ i)
)
)
(reverse numl)
)
(if (eq (type div) 'LIST)
(progn
(setq tol (car div)
lst (mapcar '(lambda (x)
(if (>= x tol)
(- x tol)
x
)
)
(NumDiv (+ tol (min num start))
(max num start)
(cadr div)
)
)
)
(if (< num start)
(reverse lst)
lst
)
)
(NumDiv num start div)
)
)

(defun XD::Geom:NumDiv (num start div / NumDiv tol lst) 
  (defun NumDiv        (num start div / i numl dis n m) 
    (setq i 0) 
    (if        (eq (type div) 'REAL) 
      (setq n        (/ (float (- num start)) div) 
            m        (if (>= n (fix n)) 
                  (1+ (fix n)) 
                  (fix n) 
                ) 
            dis        div 
      ) 
      (setq m        (1+ div) 
            dis        (/ (float (- num start)) div) 
      ) 
    ) 
    (repeat (fix m) 
      (setq numl (cons (+ start (* i dis)) numl) 
            i         (1+ i) 
      ) 
    ) 
    (reverse numl) 
  ) 
  (if (eq (type div) 'LIST) 
    (progn 
      (setq tol        (car div) 
            lst        (mapcar        '(lambda (x) 
                           (if (>= x tol) 
                             (- x tol) 
                             x 
                           ) 
                         ) 
                        (NumDiv        (+ tol (min num start)) 
                                (max num start) 
                                (cadr div) 
                        ) 
                ) 
      ) 
      (if (< num start) 
        (reverse lst) 
        lst 
      ) 
    ) 
    (NumDiv num start div) 
  ) 
)

原函数功能
_$ (XD::GEOM:NUMDIV 12 3 4)
(3.0 5.25 7.5 9.75 12.0)
_$ (XD::GEOM:NUMDIV 3 12 4)
(12.0 9.75 7.5 5.25 3.0)

新增功能
周期
_$ (XD::GEOM:NUMDIV 3 12 '(15 4))
(3.0 1.5 0.0 13.5 12.0)
_$ (XD::GEOM:NUMDIV 12 3 '(15 4))
(12.0 13.5 0.0 1.5 3.0)

实数步距
_$ (XD::GEOM:NUMDIV 12 3 0.5)
(3.0 3.5 4.0 4.5 5.0 5.5 6.0 6.5 7.0 7.5 8.0 8.5 9.0 9.5 10.0 10.5 11.0 11.5 12.0)

周期时步距
_$ (XD::GEOM:NUMDIV 3 12 '(15 0.5))
(3.0 2.5 2.0 1.5 1.0 0.5 0.0 14.5 14.0 13.5 13.0 12.5 12.0)
_$ (XD::GEOM:NUMDIV 12 3 '(15 0.5))
(12.0 12.5 13.0 13.5 14.0 14.5 0.0 0.5 1.0 1.5 2.0 2.5 3.0)

Free-Lancer · 发表于 2014-9-13 08:43:30

漏了个情况，当 div 为 REAL num < start 时 n 为负，m 需要 abs 且 dis 为负

账号		自动登录	找回密码
密码			立即注册

[几何] (XD::Geom:NumDiv)给定参数值，起始值，等分数，返回等分后的参数表

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

相关帖子

点评

点评

点评