对称拉伸

st788796 · 发表于 2014-3-1 16:52:33

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

本帖最后由 st788796 于 2014-3-1 16:57 编辑

(defun c:tt (/ Pnts:Mirror _pi2 p1 p2 p pts ptl p3 p4 p33 p44 _stretch)
(defun Pnt:Mirror (pt p1 p2 / p an)
(setq an (angle p1 p2)
p (inters p1 p2 pt (polar pt (+ an _pi2) 1.) nil)
)
(polar pt (angle pt p) (* (distance pt p) 2.))
)
(defun _stretch (pts p1 p2 / tf)
(vl-cmdf ".stretch" "CP")
(while (and pts (/= (getvar "cmdactive") 0))
(vl-cmdf (car pts))
(setq pts (cdr pts))
)
(vl-cmdf "")
(vl-cmdf "")
(vl-cmdf p1)
(vl-cmdf p2)
)
(setq _pi2 (* pi 0.5))
(if (and (setq p1 (getpoint "\nFirst Point of Mirror line: "))
(setq p2 (getpoint p1 "\nSecond Point of Mirror Line: "))
(progn
(grdraw p1 p2 6 1)
(while (setq p (if pts
(getpoint (car pts) "\nNext Point: ")
(getpoint "\nFirst Point: ")
)
)
(if pts
(progn
(grdraw p (car pts) 1 1)
(grdraw (pnt:mirror p p1 p2)
(car ptl)
1
1
)
)
)
(setq pts (cons p pts)
ptl (cons (pnt:mirror p p1 p2) ptl)
)
)
(grdraw (car pts) (last pts) 1 1)
(grdraw (car ptl) (last ptl) 1 1)
pts
)
(> (length pts) 2)
(setq p3 (getpoint "\nBase Point: "))
(setq p4 (getpoint p3 "\nTarget Point: "))
)
(progn
(setq p33 (pnt:mirror p3 p1 p2)
p44 (pnt:mirror p4 p1 p2)
)
(_stretch pts p3 p4)
(_stretch ptl p33 p44)
)
)
(princ)
)

(defun c:tt (/ Pnts:Mirror _pi2 p1 p2 p pts ptl p3 p4 p33 p44 _stretch) 
  (defun Pnt:Mirror (pt p1 p2 / p an) 
    (setq an (angle p1 p2) 
          p  (inters p1 p2 pt (polar pt (+ an _pi2) 1.) nil) 
    ) 
    (polar pt (angle pt p) (* (distance pt p) 2.)) 
  ) 
  (defun _stretch (pts p1 p2 / tf) 
    (vl-cmdf ".stretch" "CP") 
    (while (and pts (/= (getvar "cmdactive") 0)) 
      (vl-cmdf (car pts)) 
      (setq pts (cdr pts)) 
    ) 
    (vl-cmdf "") 
    (vl-cmdf "") 
    (vl-cmdf p1) 
    (vl-cmdf p2) 
  ) 
  (setq _pi2 (* pi 0.5)) 
  (if (and (setq p1 (getpoint "\nFirst Point of Mirror line: ")) 
           (setq p2 (getpoint p1 "\nSecond Point of Mirror Line: ")) 
           (progn 
             (grdraw p1 p2 6 1) 
             (while (setq p (if        pts 
                              (getpoint (car pts) "\nNext Point: ") 
                              (getpoint "\nFirst Point: ") 
                            ) 
                    ) 
               (if pts 
                 (progn 
                   (grdraw p (car pts) 1 1) 
                   (grdraw (pnt:mirror p p1 p2) 
                           (car ptl) 
                           1 
                           1 
                   ) 
                 ) 
               ) 
               (setq pts (cons p pts) 
                     ptl (cons (pnt:mirror p p1 p2) ptl) 
               ) 
             ) 
             (grdraw (car pts) (last pts) 1 1) 
             (grdraw (car ptl) (last ptl) 1 1) 
             pts 
           ) 
           (> (length pts) 2) 
           (setq p3 (getpoint "\nBase Point: ")) 
           (setq p4 (getpoint p3 "\nTarget Point: ")) 
      ) 
    (progn 
      (setq p33        (pnt:mirror p3 p1 p2) 
            p44        (pnt:mirror p4 p1 p2) 
      ) 
      (_stretch pts p3 p4) 
      (_stretch ptl p33 p44) 
    ) 
  ) 
  (princ) 
)

ysq101 · 发表于 2014-3-1 17:56:41

提点小意见~~~~~
确定对称轴后
拉伸操作改为直接框选是不是更方便？？
要画线选对象还不如直接来两次S（拉伸）快啊

（或许这不好实现）

st788796 · 发表于 2014-3-1 18:16:07

本帖最后由 st788796 于 2014-3-1 18:52 编辑

ysq101 发表于 2014-3-1 17:56
提点小意见~~~~~
确定对称轴后
拉伸操作改为直接框选是不是更方便？？

框选简单啊，GetCorner

(defun c:tt (/ Pnts:Mirror _pi2 p1 p2 p3 p4 p00 p01 p000 p001 _stretch)
(defun Pnt:Mirror (pt p1 p2 / p an)
(setq an (angle p1 p2)
p (inters p1 p2 pt (polar pt (+ an _pi2) 1.) nil)
)
(polar pt (angle pt p) (* (distance pt p) 2.))
)
(setq _pi2 (* pi 0.5))
(if (and (setq p1 (getpoint "\nFirst Point of Mirror line: "))
(setq p2 (getpoint p1 "\nSecond Point of Mirror Line: "))
(progn
(grdraw p1 p2 6 1)
t
)
(setq p00 (getpoint "\nFirst Corner: "))
(setq p01 (getcorner p00 "\nSecond Corner: "))
(progn
(grvecs (list '1
p00
(list (car p01) (cadr p00) 0.)
'1
(list (car p01) (cadr p00) 0.)
p01
'1
p01
(list (car p00) (cadr p01) 0.)
'1
(list (car p00) (cadr p01) 0.)
p00
)
)
(setq p000 (pnt:mirror p00 p1 p2)
p001 (pnt:mirror p01 p1 p2)
)
(grvecs (list '1
p000
(list (car p001) (cadr p000) 0.)
'1
(list (car p001) (cadr p000) 0.)
p001
'1
p001
(list (car p000) (cadr p001) 0.)
'1
(list (car p000) (cadr p001) 0.)
p000
)
)
t
)
(setq p3 (getpoint "\nBase Point: "))
(setq p4 (getpoint p3 "\nTarget Point: "))
)
(progn
(vl-cmdf "._stretch" "C" "_none" p00 "_none" p01 "" "_none" p3
"_none" p4)
(vl-cmdf "._stretch"
"C"
"_none"
p000
"_none"
p001
""
"_none"
(pnt:mirror p3 p1 p2)
"_none"
(pnt:mirror p4 p1 p2)
)
)
)
(princ)
)

(defun c:tt (/ Pnts:Mirror _pi2 p1 p2 p3 p4 p00 p01 p000 p001 _stretch) 
  (defun Pnt:Mirror (pt p1 p2 / p an) 
    (setq an (angle p1 p2) 
          p  (inters p1 p2 pt (polar pt (+ an _pi2) 1.) nil) 
    ) 
    (polar pt (angle pt p) (* (distance pt p) 2.)) 
  ) 
  (setq _pi2 (* pi 0.5)) 
  (if (and (setq p1 (getpoint "\nFirst Point of Mirror line: ")) 
           (setq p2 (getpoint p1 "\nSecond Point of Mirror Line: ")) 
           (progn 
             (grdraw p1 p2 6 1) 
             t 
           ) 
           (setq p00 (getpoint "\nFirst Corner: ")) 
           (setq p01 (getcorner p00 "\nSecond Corner: ")) 
           (progn 
             (grvecs (list '1 
                           p00 
                           (list (car p01) (cadr p00) 0.) 
                           '1 
                           (list (car p01) (cadr p00) 0.) 
                           p01 
                           '1 
                           p01 
                           (list (car p00) (cadr p01) 0.) 
                           '1 
                           (list (car p00) (cadr p01) 0.) 
                           p00 
                     ) 
             ) 
             (setq p000        (pnt:mirror p00 p1 p2) 
                   p001        (pnt:mirror p01 p1 p2) 
             ) 
             (grvecs (list '1 
                           p000 
                           (list (car p001) (cadr p000) 0.) 
                           '1 
                           (list (car p001) (cadr p000) 0.) 
                           p001 
                           '1 
                           p001 
                           (list (car p000) (cadr p001) 0.) 
                           '1 
                           (list (car p000) (cadr p001) 0.) 
                           p000 
                     ) 
             ) 
             t 
           ) 
           (setq p3 (getpoint "\nBase Point: ")) 
           (setq p4 (getpoint p3 "\nTarget Point: ")) 
      ) 
    (progn 
      (vl-cmdf "._stretch" "C" "_none" p00 "_none" p01 "" "_none" p3 
               "_none" p4) 
 
      (vl-cmdf "._stretch" 
               "C" 
               "_none" 
               p000 
               "_none" 
               p001 
               "" 
               "_none" 
               (pnt:mirror p3 p1 p2) 
               "_none" 
               (pnt:mirror p4 p1 p2) 
      ) 
    ) 
  ) 
  (princ) 
)

434939575 · 发表于 2014-3-1 19:19:02

一箭双雕。喜欢100%lisp.学习了！

ysq101 · 发表于 2014-3-1 19:55:27

st788796 发表于 2014-3-1 18:16
框选简单啊，GetCorner

感谢你采纳我的建议~~~~这个功能真心不错啊。。。。很多行业都通用
再次谢谢你

kwok · 发表于 2014-3-1 19:56:20

这个牛，顶一下，画工件方便多了.

maxone · 发表于 2014-3-1 20:51:25

本帖最后由 maxone 于 2014-3-1 20:52 编辑

载入之后出现这个，错误: 读入的 (八进制) 字符不正确: 0:L

ysq101 · 发表于 2014-3-1 21:34:11

st788796 发表于 2014-3-1 18:16
框选简单啊，GetCorner

突然来点灵感
指定对称轴的时候可以直接点选中心线啊~~~~

这样就免去点两下了哈。。。。

实在不行我自己改改吧。。。反正是源码，，就当是学习一下好了

st788796 · 发表于 2014-3-1 21:50:15

ysq101 发表于 2014-3-1 21:34
突然来点灵感
指定对称轴的时候可以直接点选中心线啊~~~~

有线时当然可以, 没有时还得描点

ysq101 · 发表于 2014-3-1 21:53:26

st788796 发表于 2014-3-1 21:50
有线时当然可以, 没有时还得描点

对于这种对称图。。。一般作图者都会作出中心线不过你说得也是有道理。。。。。。。个人习惯不一样。。。

还是我自己动手改改吧。。。

谢谢你

429014673 · 发表于 2014-3-3 21:43:30

机械佬专用

yoyoho · 发表于 2014-3-4 17:31:22

st788796 发表于 2014-3-1 18:16
框选简单啊，GetCorner

感谢分享学习!{:soso_e179:}

XDnpu349 · 发表于 2014-3-9 16:22:41

这样还是省事不少:)

qianyi0710 · 发表于 2015-7-26 21:52:21

这个实用，不知道怎么用？

qianyi0710 · 发表于 2015-7-26 21:53:57

这个实用，不知道怎么用？

账号		自动登录	找回密码
密码			立即注册

[教学] 对称拉伸

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

点评

点评

点评