如何判断点是否在两个平行线中间

marting · 发表于 2016-5-4 12:19:34

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

如图，有什么好的方法判断测试点是否在 P1 P2连线垂线组成的两个平行线之间呢？

搜狗截图20160504120747.png

iLisp · 发表于 2016-5-4 12:34:56

trans出car来判断

iLisp · 发表于 2016-5-4 12:47:23

还可以转换为判断点在矩形内部

/db_自贡黄明儒_ · 发表于 2016-5-4 12:59:54

两平行距离D,点P到两条平行线的距离是否都小于D

marting · 发表于 2016-5-4 13:16:45

iLisp 发表于 2016-5-4 12:47
还可以转换为判断点在矩形内部

不一定有框，点在两条平行线中间都算。

marting · 发表于 2016-5-4 13:20:32

iLisp 发表于 2016-5-4 12:34
trans出car来判断

如何TRANS 判断？

st788796 · 发表于 2016-5-4 13:37:11

marting 发表于 2016-5-4 13:20
如何TRANS 判断？

(defun f (p p1 p2 p3 p4 / l1 l2)
(if (inters p1 p3 p2 p4)
(mapcar 'set '(p3 p4) (list p4 p3))
)
(setq l1 (trans (mapcar '- p p1) 0 (mapcar '- p2 p1))
l2 (trans (mapcar '- p p3) 0 (mapcar '- p4 p3))
)
(if (or (minusp (last l1))
(minusp (last l2))
(> (last l1) (distance p1 p2))
(> (last l2) (distance p3 p4))
(> (* (car l1) (car l2)) 0)
)
nil
t
)
)

newer · 发表于 2016-5-4 14:59:36

其实从数学上，向量的点集是判断点和直线位置关系的最简明的方法

点在两直线中间，测试点和P1，P2的两个点积的乘积必小于0.

下面是测试函数, 纯LISP的点积函数本论坛有。下面的点积函数用的XDRX API里面的。

(defun XD::Pnt:IsBetween (pnt p1 p2)
(setq vx (mapcar '- p2 p1)
v1 (mapcar '- pnt p1)
v2 (mapcar '- pnt p2)
)
(< (* (xdrx_vector_dotproduct v1 vx)
(xdrx_vector_dotproduct v2 vx)
) 0
)
)

newer · 发表于 2016-5-4 15:12:30

找到个老黄的纯LISP代码的点积函数帖子，http://bbs.xdcad.net/thread-677302-1-1.html

csharp · 发表于 2016-5-4 15:19:18

试过 AcGe 库中的 OrthoProject Project，还有 acedTrans , 都没有包装的 autolisp 这个 trans 函数丰富好用

牢固 · 发表于 2016-5-9 20:46:54

本帖最后由牢固于 2016-5-9 21:02 编辑

(defun c:tt ()
(if (and
(setq p1 (getpoint "\n第一点:"))
(setq p2 (getpoint p1 "\n第二点:"))
(setq p3 (getpoint p1 "\n平行线上点:"))
)
(while (setq p0 (getpoint "\n测试点:"))
(if (< (* (car (trans (mapcar '- p0 p1) 1 (mapcar '- p2 p1)))
(car (trans (mapcar '- p0 p3) 1 (mapcar '- p2 p1)))
)
0
)
(princ "\n点位于平行线之间")
(princ "\n点位于平行线之外")
)
)
)
(princ)
)

Highflybird · 发表于 2016-5-9 22:23:05

我提出一个判别方法：
如果这个点在两平行线AB,CD中间，那么它在平行方向的线应该与AD或者BC相交。否则交于AD或者BC的延长线上。以后补写一段代码。

Highflybird · 发表于 2016-5-9 22:33:14

(defun c:tt ()
(if (and
(setq p1 (getpoint "\n第一点:"))
(setq p2 (getpoint p1 "\n第二点:"))
(setq p3 (getpoint p1 "\n平行线上点:"))
)
(progn
(setq an (angle p1 p3))
(while (setq p0 (getpoint "\n测试点:"))
(if (or (inters p1 p2 p0 (polar p0 an -1e20))
(inters p1 p2 p0 (polar p0 an 1e20))
)
(princ "\n点位于平行线之间")
(princ "\n点位于平行线之外")
)
)
)
)
(princ)
)

牢固 · 发表于 2016-5-10 21:17:05

Highflybird 发表于 2016-5-9 22:33

代码有点小错误，红色部分，已修改！
(defun c:tt ()
  (if (and
(setq p1 (getpoint "\n第一点:"))
(setq p2 (getpoint p1 "\n第二点:"))
(setq p3 (getpoint p1 "\n平行线上点:"))
   )
(progn
   (setq an (angle p1 p2))
   (while (setq p0 (getpoint "\n测试点:"))
(if (or (inters p1 p3 p0 (polar p0 an -1e20))
      (inters p1 p3 p0 (polar p0 an 1e20))
         )
   (princ "\n点位于平行线之间")
   (princ "\n点位于平行线之外")
)
   )
)
  )
  (princ)
)

Highflybird · 发表于 2016-5-10 23:30:45

牢固发表于 2016-5-10 21:17
代码有点小错误，红色部分，已修改！
(defun c:tt ()
(if (and

我的理解错误。
我把你的那几个点P2,P3理解反了

账号		自动登录	找回密码
密码			立即注册

[求助] 如何判断点是否在两个平行线中间

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

点评

点评

评分

点评

点评

点评