找回密码
 立即注册

QQ登录

只需一步,快速开始

扫一扫,访问微社区

查看: 2124|回复: 1

[拖动] (XD::Drag:GMove)点监视器实现的通用拖动函数

[复制链接]

已领礼包: 40个

财富等级: 招财进宝

发表于 2016-5-25 13:18:45 | 显示全部楼层 |阅读模式
函数发布
函数名称: XD::Drag:GMove
调用格式: (XD::Drag:GMove basePnt info clr vec bothsides callback)
参数说明: basepnt ----- 基点(UCS)
info ----- 提示字符串
clr ----- 拖动线的颜色和模式, 负数(实线),正数(虚线),0:不显示拖动线
vec ------ 约束方向向量(单位矢量)(UCS)
bothside2 --- T 允许向量正交两个方向,NIL 仅向量方向
callback ----- 回调函数(在该函数中写自己的拖动后的具体实现代码)
返回值: 点(UCS) or NIL
函数简介: 点监视器实现的通用拖动函数, 支持鼠标和输入距离选点拖动

允许中间使用F8键改变为两个正交方向约束
函数来源: 原创
函数作者: Newer
适用版本: XDRX API 
最后更新时间: 2016-06-02
备注: 2016年6月2日更新第三版
演示图片:

马上注册,结交更多好友,享用更多功能,让你轻松玩转社区。

您需要 登录 才可以下载或查看,没有账号?立即注册

×
前几天Lispboy写了个GETPOINT的点监视器实现代码,但只能取点。
受启发,在此基础上修改,增加了回调函数做成通用的点监视器实现的拖动函数。

  1. (defun XD::Drag:GMove (basePnt info clr vec bothsides callback / basePnt2                               basePnt3 con dis dis2 dis3 dynpt msg myerr
  2.                                olderr pt pt1 pt2 pt3 v x-dir x-project y-dir
  3.                       )
  4.   (defun myerr (msg)
  5.     (princ (strcat "\n" msg))
  6.     (xdrx_pointmonitor)
  7.     (redraw)
  8.     (setq *error* olderr)
  9.     (princ)
  10.   )
  11.   (defun _drawOrthoVec (x-dir y-dir)
  12.     (setq basePnt2 (mapcar
  13.                      '+
  14.                      basePnt
  15.                      (trans x-dir 0 1 2)
  16.                    )
  17.           basePnt3 (mapcar
  18.                      '+
  19.                      basePnt
  20.                      (trans y-dir 0 1 2)
  21.                    )
  22.           pt2 (XD::Pnts:OrthoProject (list dynpt) (trans basePnt 1 0)
  23.                                      (trans basePnt2 1 0)
  24.               )
  25.           dis2 (distance dynpt (car pt2))
  26.           pt3 (XD::Pnts:OrthoProject (list dynpt) (trans basePnt 1 0)
  27.                                      (trans basePnt3 1 0)
  28.               )
  29.           dis3 (distance dynpt (car pt3))
  30.     )
  31.     (if (< dis2 dis3)
  32.       (setq pt (car pt2)
  33.             x-project (trans x-dir 0 1 2)
  34.             basePnt2 basePnt2
  35.       )
  36.       (setq pt (car pt3)
  37.             x-project (trans y-dir 0 1 2)
  38.             basePnt2 basePnt3
  39.       )
  40.     )
  41.     pt
  42.   )
  43.   (defun _#XD::Drag:InCallback (dynpt)
  44.     (redraw)
  45.     (if vec
  46.       (progn
  47.         (if (and (= 1 (XD::SYMBOL:Get '#XD-GLOBALVAR-DRAG-FREEORTHO))
  48.                  (= (getvar "orthomode") 0)
  49.             )
  50.           (progn
  51.             (setq pt dynpt
  52.                   x-project nil
  53.             )
  54.           )
  55.           (if (not bothsides)
  56.             (progn
  57.               (setq v (xdrx_vector_normalize (mapcar
  58.                                                '-
  59.                                                dynpt
  60.                                                (trans basePnt 1 0)
  61.                                              )
  62.                       )
  63.               )
  64.               (setq x-project vec
  65.                     pt (car (XD::Pnts:OrthoProject (list dynpt)
  66.                                                    (trans basePnt 1 0)
  67.                                                    (trans basePnt2 1 0)
  68.                             )
  69.                        )
  70.               )
  71.             )
  72.             (progn
  73.               (setq x-dir vec
  74.                     y-dir (xdrx_vector_perpvector x-dir)
  75.               )
  76.               (setq pt (_drawOrthoVec x-dir y-dir))
  77.             )
  78.           )
  79.         )
  80.       )
  81.       (progn
  82.         (if (= 0 (getvar "orthomode"))
  83.           (setq pt dynpt
  84.                 x-project nil
  85.           )
  86.           (progn
  87.             (setq x-dir (getvar "ucsxdir")
  88.                   y-dir (getvar "ucsydir")
  89.             )
  90.             (setq pt (_drawOrthoVec x-dir y-dir))
  91.           )
  92.         )
  93.       )
  94.     )
  95.     (if (/= 0 clr)
  96.       (xdrx_grdraw clr con (trans basePnt 1 0) pt)
  97.     )
  98.     (if (not lastPnts)
  99.       (progn
  100.         (setq lastPnts (cons dynpt lastPnts))
  101.         (setvar "users1" (vl-prin1-to-string dynpt))
  102.       )
  103.       (progn
  104.         (setq lastPnts (list dynpt (car lastPnts)))
  105.         (setvar "users2" (vl-prin1-to-string (cadr lastpnts)))
  106.         (setvar "users1" (vl-prin1-to-string dynpt))
  107.       )
  108.     )
  109.     (if (= (type (eval (read callback))) 'SUBR)
  110.       (eval (list (read callback) (read "pt")))
  111.     )
  112.     (princ)
  113.   )
  114.   (if (minusp clr)
  115.     (setq con 0
  116.           clr (abs clr)
  117.     )
  118.     (setq con 1)
  119.   )
  120.   (setq olderr *error*)
  121.   (setq *error* myerr)
  122.   (if (not callback)
  123.     (setq callback "")
  124.   )
  125.   (xdrx_pointmonitor "_#XD::Drag:InCallback")
  126.   (setvar "lastpoint" basePnt)
  127.   (setq basePnt2 (mapcar
  128.                    '+
  129.                    basePnt
  130.                    vec
  131.                  )
  132.   )
  133.   (if (setq dis (getpoint info))
  134.     (progn
  135.       (cond
  136.         ((= (type dis) 'LIST)
  137.           (if (not (equal (car lastPnts) (cadr lastPnts) 1e-3))
  138.             (progn
  139.               (if x-project
  140.                 (progn
  141.                   (setq pt1 (XD::Pnts:OrthoProject (list (car lastPnts))
  142.                                                    (trans basePnt 1 0)
  143.                                                    (trans basePnt2 1 0)
  144.                             )
  145.                         x-project (xdrx_vector_normalize (mapcar
  146.                                                            '-
  147.                                                            (trans
  148.                                                                   (car pt1)
  149.                                                                   0 1
  150.                                                            )
  151.                                                            basePnt
  152.                                                          )
  153.                                   )
  154.                         pt1 (mapcar
  155.                               '+
  156.                               basePnt
  157.                               (xdrx_vector_product x-project
  158.                                                    (distance (car lastPnts)
  159.                                                              (trans basePnt
  160.                                                                     1 0
  161.                                                              )
  162.                                                    )
  163.                               )
  164.                             )
  165.                   )
  166.                 )
  167.                 (setq pt1 (trans pt 0 1))
  168.               )
  169.             )
  170.             (setq pt1 (trans pt 0 1))
  171.           )
  172.         )
  173.         ((= (type dis) 'STR)
  174.           (setq pt1 dis)
  175.         )
  176.       )
  177.     )
  178.     (setq pt1 nil)
  179.   )
  180.   (xdrx_pointmonitor)
  181.   (setq *error* olderr)
  182.   (redraw)
  183.   pt1
  184. )

论坛插件加载方法
发帖求助前要善用【论坛搜索】功能,那里可能会有你要找的答案;
如果你在论坛求助问题,并且已经从坛友或者管理的回复中解决了问题,请把帖子标题加上【已解决】;
如何回报帮助你解决问题的坛友,一个好办法就是给对方加【D豆】,加分不会扣除自己的积分,做一个热心并受欢迎的人!

已领礼包: 40个

财富等级: 招财进宝

 楼主| 发表于 2016-5-25 13:28:56 | 显示全部楼层
具体的应用例子见: http://bbs.xdcad.net/thread-704336-1-1.html
论坛插件加载方法
发帖求助前要善用【论坛搜索】功能,那里可能会有你要找的答案;
如果你在论坛求助问题,并且已经从坛友或者管理的回复中解决了问题,请把帖子标题加上【已解决】;
如何回报帮助你解决问题的坛友,一个好办法就是给对方加【D豆】,加分不会扣除自己的积分,做一个热心并受欢迎的人!
回复 支持 反对

使用道具 举报

您需要登录后才可以回帖 登录 | 立即注册

本版积分规则

QQ|申请友链|Archiver|手机版|小黑屋|辽公网安备|晓东CAD家园 ( 辽ICP备15016793号 )

GMT+8, 2024-3-29 15:30 , Processed in 0.306503 second(s), 34 queries , Gzip On.

Powered by Discuz! X3.5

© 2001-2024 Discuz! Team.

快速回复 返回顶部 返回列表