请问用户座系下标注飞出去的机理是怎样形成的？

行雲

效果如图。飞出去有两万多MM，为方便截图，才将二者移近。
在世界坐标系下则不会飞出去
请问，是基于什么原因飞出去的？有解决法子么？

(defun c:tt ()
(setq os (getvar "osmode"))
(setvar "osmode" 1)
(setq ucso (getpoint "\n原点:"))
(command "ucs" "o" ucso)
;(command "ucs" "w")
(command "ucsicon" "or")
(setvar "osmode" 0)
(setq xze (ssget'((0 . "circle"))))
(setq xhuan 0)
(while (< xhuan (sslength xze))
   (setq bzu (ssname xze xhuan))
   (setq yxin (cdr (assoc 10 (entget bzu))))
   (command "dimordinate" yxin "x" (polar yxin (* 1.5 pi) (* (getvar "dimtxt") 5)))
   (setq xhuan (+ xhuan 1))
)
(setvar "osmode" os)
(princ)
)

ll_j

dxf组码10是在世界坐标系下的，由此推算出来的点自然也就是世界坐标系的点，而使用command函数调用命令的输入点是当前坐标系中的，所以有转换关系，直接使用就会跑偏。
有两种方法解决，其一是使用entmake，属于哪里来哪里去，一般不会跑偏，其二是使用trans转换一下，具体可以看看trans的帮助。

marting

你要使用COMMAND， 里面的参数点要求是UCS坐标，
把你计数的点，用 (trans pt 0 1) 下

行雲

ll_j 发表于 2017-2-24 17:31

多谢指点，透彻详细，entmake没弄过，好高级，trans也无从入手，看来又有一番艰难折腾了，，好在，有了还有阁下不吝指教，略略知道了怎么回事，谢谢。
此外，还相请教一个问题：
(setq xze (ssget'((0 . "circle"))))
(setq xhuan 0)
(while (< xhuan (sslength xze))
    (setq bzu (ssname xze xhuan))
    (setq yxin (cdr (assoc 10 (entget bzu))))
二次循环时，yxin碰到同心圆，一般以什么法子忽略其一？

行雲

marting 发表于 2017-2-24 17:57

大致改个句式范本让在下临摹一下，好不，谢谢

csharp

用 command 就去掉 ucs 部分， entget 部分加 trans

ll_j

行雲 发表于 2017-2-24 17:59

(setq yxin (cdr (assoc 10 (entget bzu))))后面再增加：
(setq yxin (trans yxin 0 1))


圆心相同的情况最近在论坛有过讨论，记不清是这里还是明经通道了，你不妨找找看。这种问题其实就是把圆心坐标排序，然后按自己的要求除重，根据要求不同，代码也会不同。

marting

行雲 发表于 2017-2-24 18:02

(defun c:tt ()
  (setq os (getvar "osmode"))
  (setvar "osmode" 1)
  (setvar "osmode" 0)
  (setq xze (ssget '((0 . "circle"))))
  (setq xhuan 0)
  (while (< xhuan (sslength xze))
    (setq bzu (ssname xze xhuan))
    (setq yxin (cdr (assoc 10 (entget bzu))))
    (command "dimordinate"
             (trans yxin 0 1)
             "x"
             (trans (polar yxin (* 1.5 pi) (* (getvar "dimtxt") 5)) 0 1)
    )
    (setq xhuan (+ xhuan 1))
  )
  (setvar "osmode" os)
  (princ)
)

行雲

谢谢ll_j   谢谢marting 谢谢各位

行雲

谢谢ll_j   谢谢marting 谢谢各位