如何取得多段线顶点表

ljxkm

如何取得多段线顶点表

ljxkm

问题简单了，都不回复啊，自己写了一个源码如下：
(defun ljx-getplpoint (e / obj pname lst)
  (vl-load-com)
  (setq obj (vlax-ename->vla-object e)
        pname (cdr (assoc 0 (entget e)))
  )
  (cond
    ((= pname "SPLINE")
     (setq lst (ch-lst e (vlax-safearray->list (vlax-variant-value (vla-get-ControlPoints obj)))))
    )
    ((or (= pname "LWPOLYLINE") (= pname "POLYLINE"))
     (setq lst (ch-lst e  (vlax-safearray->list (vlax-variant-value (vla-get-Coordinates obj)))))
    )
    (T
     (setq lst (list (vlax-safearray->list (vlax-variant-value (vla-get-StartPoint obj)))
                     (vlax-safearray->list (vlax-variant-value (vla-get-EndPoint obj))))
     )
    )
  );;;;cond
  lst
);;;;defun
  (defun ch-lst (ei lsti / ind nn lstn lsti1)
    (setq ind 0
          nn (if (= (cdr (assoc 0 (entget ei))) "LWPOLYLINE") 2 3)
          lstn '()
    )
    (repeat (/ (length lsti) nn)
      (if (= (cdr (assoc 0 (entget ei))) "LWPOLYLINE")
        (setq lsti1 (list (nth ind lsti) (nth (1+ ind) lsti) (cdr (assoc 38 (entget ei)))))
        (setq lsti1 (list (nth ind lsti) (nth (1+ ind) lsti) (nth (+ 2 ind) lsti)))
      )
      (setq lstn (cons lsti1 lstn)
            ind (+ ind nn)
      )
    )
    (setq lstn (reverse lstn))
  )
;;;;使用示例：(setq lsta (ljx-getplpoint (car (entsel "\n请选择曲线"))))