这三个文字怎么了，05下和08下看到的不一样？

/db_自贡黄明儒_ · 发表于 2017-8-19 14:00:04

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

本帖最后由 /db_自贡黄明儒_ 于 2017-8-19 14:05 编辑

压缩包内只一个文件，里面有3个文字，在08下和05下看到的不一样，而且在08下旋转命令转不动？查组码是(210 0.0 0.0 1.0)也是对的呀。

/db_自贡黄明儒_ · 发表于 2017-8-19 14:38:34

本帖最后由 /db_自贡黄明儒_ 于 2017-8-19 15:32 编辑

marting 发表于 2017-8-19 14:25

就是写这个遇到的问题，下面是一个简化版

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;齐线QX 2017.8.19
(defun C:QX (/ textchange doText ANG ANGB B E EN ET FLAG GR P P0 PARAM SS p10)
(defun textchange () (if Flag
(setq ang (+ pi ang))
)
(setq en (entget et))
(if (or (/= (cdr(assoc 72 en)) 0) (/= (cdr (assoc 73 en)) 0))
(setq en (subst (cons 11 p0) (assoc 11 en) en))
(setq en (subst (cons 10 p0) (assoc 10 en) en))
)
(entmod (subst (cons 50 ang) (assoc 50 en) en))
)
(defun doText ()
(if (/= (length e) 4)
(progn
(setq p (cadr e)) ;击点
(princ "\n 按F文字反向")
(WHILE (not (member (car (setq gr (grread t 4 2)))
'(3 11 13 32 12 25)
)
)
;;按下F
(if (or (equal gr '(2 70)) (equal gr '(2 102)))
(setq Flag (not Flag))
)
(if (= (car gr) 5) ;鼠标在移动
(progn
(setq p (vlax-curve-getClosestPointTo (car e) p))
(setq Param (vlax-curve-getParamAtPoint (car e) p))
(setq
ang (mapcar '+
p
(vlax-curve-getFirstDeriv (car e) param)
)
)
(setq ang (angle p ang))
(setq p0 (cadr gr)) ;鼠标位置p0
(textchange)
(redraw)
(grdraw p0 p 3 2)
(setq p p0)
)
)
)
)
)
)
(if (findfile "actscale.arx")
(ARXLOAD "actscale.arx")
)
(if (findfile "acTscale.crx")
(ARXLOAD "acTscale.crx")
)
(command "_.undo" "begin")
(setvar "cmdecho" 0)
(if (and
(setq e (nentsel "\n 选择曲线:"))
(wcmatch (cdr (assoc 0 (entget (car e))))
"*LINE,ARC,CIRCLE,ELLIPSE"
)
)
(while (and
(setvar "nomutt" 1)
(princ "\n 选择文字:")
(setq ss (ssget ":E:S" '((0 . "*TEXT,ATTDEF"))))
(vl-cmdf "_.JUSTIFYTEXT" ss "" "MC")
(setvar "nomutt" 0)
(setq et (ssname ss 0))
)
(doText)
)
(setvar "nomutt" 0)
)
(setvar "nomutt" 0)
(redraw)
(command "_.undo" "end")
(princ)
)
(princ "\n 文字齐线:QX")
(princ)
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;齐线QX 2017.8.19

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;齐线QX 2017.8.19 
(defun C:QX (/ textchange doText ANG ANGB B E EN ET FLAG GR P P0 PARAM SS p10) 
  (defun textchange ()        (if        Flag 
      (setq ang (+ pi ang)) 
    ) 
    (setq en (entget et)) 
    (if        (or (/= (cdr(assoc 72 en)) 0) (/= (cdr (assoc 73 en)) 0))       
      (setq en (subst (cons 11 p0) (assoc 11 en) en)) 
      (setq en (subst (cons 10 p0) (assoc 10 en) en)) 
    ) 
    (entmod (subst (cons 50 ang) (assoc 50 en) en)) 
  ) 
  (defun doText        () 
    (if        (/= (length e) 4)       
      (progn 
        (setq p (cadr e))                ;击点 
        (princ "\n 按F文字反向") 
        (WHILE (not (member (car (setq gr (grread t 4 2))) 
                            '(3 11 13 32 12 25) 
                    ) 
               ) 
          ;;按下F 
          (if (or (equal gr '(2 70)) (equal gr '(2 102))) 
            (setq Flag (not Flag)) 
          ) 
          (if (= (car gr) 5)                ;鼠标在移动 
            (progn 
               (setq p (vlax-curve-getClosestPointTo (car e) p)) 
              (setq Param (vlax-curve-getParamAtPoint (car e) p)) 
              (setq 
                ang (mapcar '+ 
                            p 
                            (vlax-curve-getFirstDeriv (car e) param) 
                    ) 
              ) 
              (setq ang (angle p ang)) 
              (setq p0 (cadr gr))        ;鼠标位置p0          
              (textchange) 
              (redraw) 
              (grdraw p0 p 3 2) 
              (setq p p0) 
            ) 
          ) 
        ) 
      ) 
    ) 
  ) 
 
  (if (findfile "actscale.arx") 
    (ARXLOAD "actscale.arx") 
  ) 
  (if (findfile "acTscale.crx") 
    (ARXLOAD "acTscale.crx") 
  )   
  (command "_.undo" "begin") 
  (setvar "cmdecho" 0)   
  (if (and 
        (setq e (nentsel "\n 选择曲线:")) 
        (wcmatch (cdr (assoc 0 (entget (car e)))) 
                 "*LINE,ARC,CIRCLE,ELLIPSE" 
        ) 
      ) 
    (while (and 
             (setvar "nomutt" 1) 
             (princ "\n 选择文字:") 
             (setq ss (ssget ":E:S" '((0 . "*TEXT,ATTDEF")))) 
             (vl-cmdf "_.JUSTIFYTEXT" ss "" "MC") 
             (setvar "nomutt" 0) 
             (setq et (ssname ss 0)) 
           ) 
      (doText) 
    ) 
    (setvar "nomutt" 0) 
  ) 
  (setvar "nomutt" 0) 
  (redraw) 
  (command "_.undo" "end") 
  (princ) 
) 
(princ "\n 文字齐线:QX") 
(princ) 
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;齐线QX 2017.8.19

/db_自贡黄明儒_ · 发表于 2017-8-19 14:11:37

16下跟08看到的一样，也旋转不动。哪位大师帮看看，谢谢。

marting · 发表于 2017-8-19 14:14:05

文字对齐方式的事，设置了布满。你改下其他的就能旋转了。

/db_自贡黄明儒_ · 发表于 2017-8-19 14:18:32

marting 发表于 2017-8-19 14:14

还是你牛哈，谢谢。记得文坛中有文字齐线，遇到这情况是不是先处理了文字。

marting · 发表于 2017-8-19 14:25:22

/db_自贡黄明儒_ 发表于 2017-8-19 14:18

是的，可以改了修改完后在改回去布满，黄总，给大家写一个？

marting · 发表于 2017-8-19 14:30:55

/db_自贡黄明儒_ 发表于 2017-8-19 14:18

而且你这个文字显然被处理过了，组码10和11一样，显示为一个夹点，实际上布满就没作用了。正常的布满是两个夹点的。

应该是人为的让这个文字不能修改转角。

/db_自贡黄明儒_ · 发表于 2017-8-19 14:32:05

marting 发表于 2017-8-19 14:25

但还有一个问题，为什么在05下看不到，在08双击（准备编辑)看到是一条线？

marting · 发表于 2017-8-19 14:50:30

/db_自贡黄明儒_ 发表于 2017-8-19 14:32

组码10和组码11相同了的原因，2005那时可能还没处理这个。

下面代码试试，看画的外框线是不是一个直线？

另外在2005下，你用 ssget "x" 看看是不是能选到这几个文字。

(defun c:tt ()
(if (setq e (car (entsel)))
(progn
(setq o (vlax-ename->vla-object e))
(setq bound (vla-getboundingbox o 'bl 'ul))
(setq p1 (vlax-safearray->list bl)
p2 (vlax-safearray->list ul)
)
(entmakex (list '(0 . "LINE")'(100 . "AcDbLine")(cons 10 p1)(cons 11 p2)))
)
)
(princ)
)

/db_自贡黄明儒_ · 发表于 2017-8-19 15:07:10

本帖最后由 /db_自贡黄明儒_ 于 2017-8-19 15:10 编辑

05下画出来的线如图，有些奇怪（绿色是字，白色是画的线），然后Command: (sslength ( ssget "x"))
7这个7是因为我下面还画了一曲线。

marting · 发表于 2017-8-19 15:18:28

/db_自贡黄明儒_ 发表于 2017-8-19 15:07

用下面的，修复下文字，看看

(defun c:tt ()
(if (setq ss (ssget "x" '((0 . "TEXT") (-4 . "&=") (72 . 5))))
(progn
(setq i -1)
(while (setq e (ssname ss (setq i (1+ i))))
(setq box (textbox (setq ed (entget e)))
v (mapcar '- (cadr box) (car box))
an (cdr (assoc 50 ed))
p1 (cdr (assoc 10 ed))
p2 (polar p1 an (+ (caar box) (car v)))
)
(setq ed (subst (cons 11 p2) (assoc 11 ed) ed))
(entmod ed)
)
)
)
(princ)
)

/db_自贡黄明儒_ · 发表于 2017-8-19 15:27:43

marting 发表于 2017-8-19 15:18

不起作用。
用视图工具，从三个方向也只能看到线。用3dorbit方能看到文字。

marting · 发表于 2017-8-19 15:44:55

/db_自贡黄明儒_ 发表于 2017-8-19 15:27

试试，没2005，测试不了，你在2005下测试下

搜狗截图20170819154028.png

(defun c:tt ()
(if (setq ss (ssget "x" '((0 . "TEXT") (-4 . "&=") (72 . 5))))
(progn
(setq i -1)
(while (setq e (ssname ss (setq i (1+ i))))
(setq box (textbox (setq ed (entget e)))
v (mapcar '- (cadr box) (car box))
an (cdr (assoc 50 ed))
p1 (cdr (assoc 10 ed))
p2 (polar p1 an (+ (caar box) (car v)))
)
(setq ed (subst (cons 11 p2)(assoc 11 ed) ed)
ed (subst '(41 . 1.0) (assoc 41 ed) ed))
(entmod ed)
)
)
)
(princ)
)

sicky111 · 发表于 2017-8-20 00:08:31

学习

yoyoho · 发表于 2017-8-20 07:16:16

谢谢分享学习！！！！

账号		自动登录	找回密码
密码			立即注册

[求助] 这三个文字怎么了，05下和08下看到的不一样？

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

点评