64位cad无法打开数据库是什么问题

q3_2006

(setq dbfile "f:\\tt1.mdb")
(setq *ConnectionObject*
      (ADO_ConnectToDB
        (strcat
   "Provider=MSDASQL;Driver={Microsoft Access Driver (*.mdb)};DBQ="
   dbfile)
        "
        "")
返回空..不知道哪里没写对,2006下正常..
(defun ADO_ConnectToDB        (ConnectString UserName Password / IsUDL
                            FullUDLFileName ConnectionObject TempObject
                            ReturnValue ConnectionPropertiesObject
                            ConnectionParsingPropertyObject
                        )
  ;; Assume no error
  (setq ADOLISP_ErrorList        nil
        ADOLISP_LastSQLStatement nil
  )

  ;; If the connect string is a UDL file name ...
  (if (= ".UDL"
         (strcase
           (substr ConnectString (- (strlen ConnectString) 3))
         )
      )
    (progn
      ;; Set a flag that it's a UDL file
      (setq IsUDL T)
      ;; Try to find it
      (cond
        ((setq FullUDLFileName (findfile ConnectString)))
        ;; Didn't find it in the current directory or
        ;; the AutoCAD search path, try the AutoCAD
        ;; Data Source location
        ((setq FullUDLFileName
                (findfile (strcat (vlax-get-property
                                    (vlax-get-property
                                      (vlax-get-property
                                        (vlax-get-acad-object)
                                        "Preferences"
                                      )
                                      "Files"
                                    )
                                    "WorkspacePath"
                                  )
                                  "\\"
                                  ConnectString
                          )
                )
         )
        )
        ;; Didn't find it, store an error message
        (t
         (setq ADOLISP_ErrorList
                (list (list (cons "ADOLISP connection error"
                                  (strcat "Can't find \""
                                          ConnectString
                                          "\""
                                  )
                            )
                      )
                )
         )
        )
      )
    )
  )

  ;; If the first argument is a UDL file name... ...
  (if IsUDL
    ;; If we found it ...
    (if FullUDLFileName
      (progn
        ;; Create an ADO connection object
        (setq ConnectionObject
               (vlax-create-object
                 "ADODB.Connection"
               )
        )
        ;; Try to open the connection.  If there is an error
        ;; ...
        (if (vl-catch-all-error-p
              (setq TempObject
                     (vl-catch-all-apply
                       'vlax-invoke-method
                       (list ConnectionObject
                             "Open"
                             (strcat "File Name=" FullUDLFileName)
                             UserName
                             Password
                             ADOConstant-adConnectUnspecified
                       )
                     )
              )
            )
          (progn
            ;; Save the error information
            (setq ADOLISP_ErrorList
                   (ADO_ErrorProcessor TempObject ConnectionObject)
            )
            ;; Release the connection object
            (vlax-release-object ConnectionObject)
          )
          ;; It worked, store the connection object in our
          ;; return value
          (setq ReturnValue ConnectionObject)
        )
      )
    )
    ;; The connect string is not a UDL file name.
    (progn
      ;; Create an ADO connection object
      (setq ConnectionObject
             (vlax-create-object "ADODB.Connection")
      )
      ;; Try to open the connection.  If there is an error ...
      (if (vl-catch-all-error-p
            (setq TempObject
                   (vl-catch-all-apply
                     'vlax-invoke-method
                     (list
                       ConnectionObject "Open" ConnectString UserName
                       Password ADOConstant-adConnectUnspecified
                      )
                   )
            )
          )
        (progn
          ;; Save the error information
          (setq ADOLISP_ErrorList
                 (ADO_ErrorProcessor TempObject ConnectionObject)
          )
          ;; Release the connection object
          (vlax-release-object ConnectionObject)
        )
        ;; It worked, store the connection object in our
        ;; return value
        (setq ReturnValue ConnectionObject)
      )
    )
  )
  ;; If we made a connection ...
  (if ReturnValue
    (progn
      ;; If we want to set ODBC Parsing to true ...
      (if (not ADOLISP_DoNotForceJetODBCParsing)
        (progn
          ;; Get the properties collection
          (setq ConnectionPropertiesObject
                 (vlax-get-property
                   ReturnValue
                   "Properties"
                 )
          )
          ;; If the properties collection has a "Jet OLEDB:ODBC
          ;; Parsing" item ...
          (if (not (vl-catch-all-error-p
                     (setq ConnectionParsingPropertyObject
                            (vl-catch-all-apply
                              'vlax-get-property
                              (list
                                ConnectionPropertiesObject
                                "ITEM"
                                "Jet OLEDB:ODBC Parsing"
                              )
                            )
                     )
                   )
              )
            ;; Set the "Jet OLEDB:ODBC Parsing" item to
            ;; "true" so the Jet engine accepts double-quotes
            ;; around delimited identifiers
            (vlax-put-property
              ConnectionParsingPropertyObject
              "VALUE"
              :vlax-true
            )
          )
        )
      )
      ;; And release our objects
      (if (= 'VLA-OBJECT (type ConnectionParsingPropertyObject))
        (vlax-release-object ConnectionParsingPropertyObject)
      )
      (if (= 'VLA-OBJECT (type ConnectionPropertiesObject))
        (vlax-release-object ConnectionPropertiesObject)
      )
    )
  )
  ReturnValue
)

木易成舟好

完全没看懂

zhystar

打开什么数据库?

q3_2006

zhystar 发表于 2019-10-6 10:52
打开什么数据库?

MSACCESS sql也一样

aisong220

Lisphk

（XD::MDB:Create）创建一个空的MDB数据库


http://bbs.xdcad.net/forum.php?mod=viewthread&tid=719505&highlight=mdb


看看这个帖子能不能有帮助

nbxhy

太难了！！！！！

q3_2006

Lisphk 发表于 2019-10-7 12:12
（XD::MDB:Create）创建一个空的MDB数据库

问题解决了,是64位32位OFFICE驱动问题

caddog

请问下楼主，具体是怎样解决的呢？