怎么用entmake生成Table（表格）

zrg1

是组码太多吗？论坛找不到相关的资源

/db_自贡黄明儒_

Table从05开始才出现，是复杂对象。一般用户Vla-函数生成，估计entmake也行，恐怕没有人这么干，所以就没有回答你了。

Lisphk

为什么要纠结一定要 entmake

用 vla-addTable 去做

这是使用lisp创建TABLE实体的示例。 此示例还使用lisp创建了一些FIELDS。

该例程允许用户选择闭合的折线，它将创建一个包含两列的TABLE。 一个包含区域，另一个包含ObjectID。 最后一行总计面积。 您可以轻松地对此进行调整以显示图层，颜色或任何其他属性。

TABLE是在当前表样式上创建的，因此，根据当前表样式的设置，您可能必须在（vla-addTable ...）函数中调整大小参数，以使表看起来可以接受。 此处使用的这些尺寸在新的空工程图中与“标准”表格样式一起使用。

1. ; load (vl-load-com) first
   
2. (vl-load-com)
   
3. (defun C:POLYTABLE ( / *MS* A CNT I LST MYTABLE PT1 ROW SSET TLST)
   
4. 
   
5.   ; create an empty list, set a counter variable, and
   
6.   ; set a reference to the current model space.
   
7.   (setq lst '()
   
8. i 0
   
9. *ms* (vla-get-modelspace
   
10.              (vla-get-activedocument
    
11.              (vlax-get-acad-object)))
    
12.   )
    
13.   ; prompt the user to select closed polylines
    
14.   (princ "\n Select closed polylines ")
    
15.   (if (setq sset (ssget '((0 . "POLYLINE,LWPOLYLINE")(-4 . "&")(70 . 1))))
    
16.     ; if a valid selection set was generated, then proceed.
    
17.     (progn
    
18.    
    
19.       ; for each closed polyline selected, grab the ObjectID and Area
    
20.       ; and store these values in a list.
    
21.       (repeat (setq cnt (sslength sset))
    
22.         (setq a (vlax-ename->vla-object (ssname sset i)))
    
23.         (setq tlst (list (vla-get-Area a) (vla-get-ObjectID a)))
    
24.         (setq lst (cons tlst lst))
    
25.         (setq i (1+ i))
    
26.       )
    
27.       ; pick a point for the table
    
28.       (setq pt1 (getpoint "\nPick point for table "))
    
29.       ; add the new table
    
30.       (setq myTable (vla-AddTable
    
31.                     *ms*
    
32.                     (vlax-3d-point pt1)
    
33.                     (+ 3 cnt)
    
34.                     2
    
35.                     0.7
    
36.                     2.5))
    
37.       ; the next three lines set the header text
    
38.       (vla-setText mytable 0 0 "Polyline Table")
    
39.       (vla-setText mytable 1 0 "Area")
    
40.       (vla-setText mytable 1 1 "Object ID")
    
41.       (setq row 2)
    
42.       
    
43.       ; loop through the list of polyline properties
    
44.       ; adding a line to the table that contains the
    
45.       ; area and the ObjectID
    
46.       (foreach item lst
    
47.         (vla-setText mytable
    
48.                      row
    
49.                      0
    
50.                      (strcat "%<\\AcObjProp Object(%<\\_ObjId "
    
51.                      (itoa (last item))
    
52.                      ">%).Area \\f \"%lu2\">%"))
    
53.         (vla-setText mytable row 1 (last item))
    
54.         (setq row (1+ row))
    
55.       )      
    
56.       ; On the last row, total up the area
    
57.       (vla-setText mytable
    
58.                    row
    
59.                    0
    
60.                    (strcat "Total=\\P"
    
61.                    "%<\\AcExpr (Sum(A3:A" (itoa (+ 2 cnt)) ")) \\f \"%lu2\">%"))
    
62.       ; release "myTable" and *ms*
    
63.       (vlax-release-object myTable)      
    
64.       (vlax-release-object *ms*)      
    
65.     ); end progn
    
66. 
    
67.    ; if no closed polylines were selected,
    
68.    ; end the program with this message
    
69.     (princ "\nNo closed polylines selected. ")
    
70.   ); end if
    
71.   (princ)
    
72. ); end defun
    

; load (vl-load-com) first<br /> (vl-load-com)<br /> (defun C:POLYTABLE ( / *MS* A CNT I LST MYTABLE PT1 ROW SSET TLST)<br /> <br />   ; create an empty list, set a counter variable, and<br />   ; set a reference to the current model space.<br />   (setq lst '()<br /> i 0<br /> *ms* (vla-get-modelspace<br />              (vla-get-activedocument<br />              (vlax-get-acad-object)))<br />   )<br />   ; prompt the user to select closed polylines<br />   (princ "\n Select closed polylines ")<br />   (if (setq sset (ssget '((0 . "POLYLINE,LWPOLYLINE")(-4 . "&")(70 . 1))))<br />     ; if a valid selection set was generated, then proceed.<br />     (progn<br />     <br />       ; for each closed polyline selected, grab the ObjectID and Area<br />       ; and store these values in a list.<br />       (repeat (setq cnt (sslength sset))<br />         (setq a (vlax-ename->vla-object (ssname sset i)))<br />         (setq tlst (list (vla-get-Area a) (vla-get-ObjectID a)))<br />         (setq lst (cons tlst lst))<br />         (setq i (1+ i))<br />       )<br />       ; pick a point for the table<br />       (setq pt1 (getpoint "\nPick point for table "))<br />       ; add the new table<br />       (setq myTable (vla-AddTable <br />                     *ms* <br />                     (vlax-3d-point pt1)<br />                     (+ 3 cnt)<br />                     2 <br />                     0.7<br />                     2.5))<br />       ; the next three lines set the header text<br />       (vla-setText mytable 0 0 "Polyline Table")<br />       (vla-setText mytable 1 0 "Area")<br />       (vla-setText mytable 1 1 "Object ID")<br />       (setq row 2)<br />       <br />       ; loop through the list of polyline properties<br />       ; adding a line to the table that contains the<br />       ; area and the ObjectID<br />       (foreach item lst<br />         (vla-setText mytable<br />                      row<br />                      0 <br />                      (strcat "%<\\AcObjProp Object(%<\\_ObjId "<br />                      (itoa (last item))<br />                      ">%).Area \\f \"%lu2\">%"))<br />         (vla-setText mytable row 1 (last item))<br />         (setq row (1+ row))<br />       )      <br />       ; On the last row, total up the area<br />       (vla-setText mytable<br />                    row <br />                    0<br />                    (strcat "Total=\\P"<br />                    "%<\\AcExpr (Sum(A3:A" (itoa (+ 2 cnt)) ")) \\f \"%lu2\">%"))<br />       ; release "myTable" and *ms*<br />       (vlax-release-object myTable)      <br />       (vlax-release-object *ms*)      <br />     ); end progn<br /> <br />    ; if no closed polylines were selected, <br />    ; end the program with this message<br />     (princ "\nNo closed polylines selected. ")<br />   ); end if<br />   (princ)<br /> ); end defun<br />

Michael527

学习了，谢谢楼上的分享   

kyky1002

感谢二楼的分享

yoyoho

谢谢分享,学习了!!!!!   

zrg1

Lisphk 发表于 2020-9-2 01:06
为什么要纠结一定要 entmake

用 vla-addTable 去做

谢谢回复，请教一下该如何设置表中字体的宽度因子

Lisphk

zrg1 发表于 2020-9-3 22:36
谢谢回复，请教一下该如何设置表中字体的宽度因子

建议你去看下 acadauto.chm ， 看看里面关于TABLE对象的ACTIVEX方法

kmliro_2017

谢谢分享！！！！

pxr201419

比如要创建这样的表格

1	2	3
A	B	C

CAD2006用下面的代码来实现

(entmake (list

'(0 ."ACAD_TABLE") '(100 . "AcDbEntity") '(100 ."AcDbBlockReference")

'(10 0.0 0.00.0) '(100 . "AcDbTable")

'(91 . 2) '(92. 3) '(93 . 0) '(94 . 0) '(95 . 0) '(96 . 0)

'(141 . 0.36)'(141 . 0.36) '(142 . 1.5) '(142 . 1.5) '(142 . 1.5)

'(171 . 1) '(1 . "1")

'(171 . 1) '(1 . "2")

'(171 . 1) '(1 . "3")

'(171 . 1) '(1 . "A")

'(171 . 1) '(1 . "B")

'(171 . 1) '(1 . "C")))

CAD2010以后版本实现代码

(entmake (list

'(0 ."ACAD_TABLE")'(100 . "AcDbEntity")'(100 ."AcDbBlockReference")

'(10 -3467.73377.763 0.0) '(100 . "AcDbTable")

'(91 . 2)'(92 .3)'(93 . 0)'(94 . 0)'(95 . 0)'(96 . 0)

'(141 . 0.36)'(141 . 0.36) '(142 . 1.5) '(142 . 1.5) '(142 . 1.5)

'(171 . 1) '(301 . "CELL_VALUE") '(90 . 4)'(1 . "1") '(304 . "ACVALUE_END")

'(171 . 1) '(301 . "CELL_VALUE") '(90 . 4)'(1 . "2") '(304 . "ACVALUE_END")

'(171 . 1) '(301 . "CELL_VALUE") '(90 . 4) '(1. "3") '(304 . "ACVALUE_END")

'(171 . 1) '(301 . "CELL_VALUE") '(90 . 4)'(1 . "A") '(304 . "ACVALUE_END")

'(171 . 1) '(301 . "CELL_VALUE") '(90 . 4)'(1 . "B") '(304 . "ACVALUE_END")

'(171 . 1) '(301 . "CELL_VALUE") '(90 . 4)'(1 . "C") '(304 . "ACVALUE_END")))