关于Pline 增加节点的 UCS WCS OCS转换

st788796 · 发表于 2021-1-3 23:21:54

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

看注释

(defun c:tt (/ ss e plobj p norm pw po index)
(if (setq ss (ssget ":S:E" '((0 . "lwpolyline"))))
(progn
(setq e (ssname ss 0)
plobj (vlax-ename->vla-object e)
norm (cdr (assoc 210 (entget e))) ;_Normal
)
(while (setq p (getpoint "\npoint: ")) ;_获取的是 UCS
(setq pw (trans p 1 0) ;_转换为 WCS
po (trans pw 0 norm) ;_再转换为 OCS
index (fix
(vlax-curve-getparamatpoint
e
(vlax-curve-getclosestpointto e pw) ;_vlax-curve 参数和返回都是 WCS
)
)
)
(vla-addvertex
plobj
(1+ index)
(vlax-make-variant
(vlax-safearray-fill
(vlax-make-safearray vlax-vbdouble '(0 . 1))
(list (car po)
(cadr po)
) ;_需要 OCS
)
)
)
)
)
)
(princ)
)

(defun c:tt (/ ss e plobj p norm pw po index) 
  (if (setq ss (ssget ":S:E" '((0 . "lwpolyline")))) 
    (progn 
      (setq e          (ssname ss 0) 
            plobj (vlax-ename->vla-object e) 
            norm  (cdr (assoc 210 (entget e))) ;_Normal 
      ) 
      (while (setq p (getpoint "\npoint: ")) ;_获取的是 UCS 
        (setq pw    (trans p 1 0) ;_转换为 WCS 
              po    (trans pw 0 norm) ;_再转换为 OCS 
              index (fix 
                      (vlax-curve-getparamatpoint 
                        e 
                        (vlax-curve-getclosestpointto e pw) ;_vlax-curve 参数和返回都是 WCS 
                      ) 
                    ) 
        ) 
        (vla-addvertex 
          plobj 
          (1+ index) 
          (vlax-make-variant 
            (vlax-safearray-fill 
              (vlax-make-safearray vlax-vbdouble '(0 . 1)) 
              (list (car po) 
                    (cadr po) 
              ) ;_需要 OCS 
            ) 
          ) 
        ) 
      ) 
    ) 
  ) 
  (princ) 
)

pline 中的i节点，使用 vlax-curve-getpointatparam 返回值是 WCS

_$ (setq e (car (entsel)))
<图元名: 18f6d7f00c0>
_$ (vlax-curve-getstartpoint e)
(19.2899 3.73408 -1.05567)

DXF 存储的 10 是 OCS 坐标，
_$ (cdr (assoc 10 (entget e)))
(17.6775 -8.55707)

这个坐标转换为 WCS，还需要使用 38 组码
_$ (cdr (assoc 38 (entget e)))
1.19995

将 10 和 38 组合后进行转换
_$ (setq p (append (cdr (assoc 10 el)) (list (cdr (assoc 38 el)))))
(17.6775 -8.55707 1.19995)

转换可以使用 Normal 或者实体
_$ (setq norm (cdr (assoc 210 (entget e))))
(0.155167 -0.207148 0.965926)

转换
_$ (trans p norm 0)
(19.2899 3.73408 -1.05567)
或
_$ (trans p e 0)
(19.2899 3.73408 -1.05567)

和 vlax-curve-getstartpoint 返回值一致

Lisphk · 发表于 2021-1-3 23:36:46

因为多段线保存的是二维点(OCS），所以生成多段线时候要转换到OCS
大师，能否利用OCS的定义，不用TRANS函数，自己写个函数转换成正确的结果呢？
特别是NORMAL不是'(0 0 1)的时候

hh_lj007 · 发表于 2021-1-4 08:38:53

还没接触过，学习、收藏

st788796 · 发表于 2021-1-4 11:29:19

本帖最后由 st788796 于 2021-1-4 14:29 编辑

Lisphk 发表于 2021-1-3 23:36
因为多段线保存的是二维点(OCS），所以生成多段线时候要转换到OCS
大师，能否利用OCS的定义，不用TRANS函 ...

有 trans 就没必要使用其它函数了

_$ (setq e (car (entsel)))
<图元名: 1e7dbfc6890>

获取 Normal
_$ (setq norm (cdr (assoc 210 (entget e))))
(0.129734 -0.223956 0.965926)

获取 ECS2WCS

(defun mat:ecs2wcs (norm)
(append
(mapcar 'append
(mapcar (function (lambda (v) (trans v 0 norm T)))
'((1.0 0.0 0.0) (0.0 1.0 0.0) (0.0 0.0 1.0))
)
(mapcar 'list '(0.0 0.0 0.0))
)
'((0. 0. 0. 1.))
)
)

_$ (mat:ecs2wcs norm)
((0.865301 -0.484173 0.129734 0.0) (0.501253 0.835816 -0.223956 0.0) (0.0 0.258819 0.965926 0.0) (0.0 0.0 0.0 1.0))

使用 xdapi
_$ (xdrx_matrix_ecs2wcs e)
((0.865301 -0.484173 0.129734 0.0) (0.501253 0.835816 -0.223956 0.0) (0.0 0.258819 0.965926 0.0) (0.0 0.0 0.0 1.0))

将pline节点转为 WCS

_$ (setq sp (vlax-curve-getstartpoint e))
(7.14808 4.24048 15.0367)

取出 DXF 10 及 38
_$ (setq p0 (reverse (cons (cdr (assoc 38 (entget e))) (reverse (cdr (assoc 10 (entget e)))))))
(8.31079 3.97514 14.502)

将 p0 转换到 WCS
1 使用trans
_$ (trans p0 e 0)
(7.14808 4.24048 15.0367)

2 使用 xdapi
_$ (xdrx_point_transform p0 (xdrx_matrix_ecs2wcs e))
(7.14808 4.24048 15.0367)

3 使用 alisp

;;;-----------------------------------------------------------;;
;;; 点的矩阵(4x4 matrix) 变换 ;;
;;; 输入：矩阵m和一个三维点p ;;
;;; 输出：点变换后的位置 ;;
;;;-----------------------------------------------------------;;
(defun MAT:mxp (m p)
(reverse (cdr (reverse (MAT:mxv m (append p '(1.0))))))
)

_$ (setq pw (mat:mxp (mat:ecs2wcs norm) p0))
(7.14808 4.24048 15.0367)

将 WCS 转换到 OCS 就要使用 ECS 的逆矩阵

_$ (mat:mxp (xdrx_matrix_inverse (mat:ecs2wcs norm)) pw)
(8.31079 3.97514 14.502)
_$ (cdr (assoc 10 (entget e)))
(8.31079 3.97514)
_$

st788796 · 发表于 2021-1-4 18:59:27

本帖最后由 st788796 于 2021-1-4 19:00 编辑

齐次变换矩阵逆矩阵的快速求解方法
https://blog.csdn.net/chengde689 ... -baidujs-1.nonecase

(defun _mat:inverse (m / v mt)
(setq v (list (last (car m)) (last (cadr m)) (last (caddr m)))
mt (apply 'mapcar (cons 'list m))
)
(reverse
(cons '(0. 0. 0. 1.)
(cdr
(reverse
(mapcar
'(lambda (x y)
(reverse (cons y (cdr (reverse x))))
)
mt
(mapcar '(lambda (a) (- (apply '+ (mapcar '* v a)))) mt)
)
)
)
)
)
)

账号		自动登录	找回密码
密码			立即注册

[教学] 关于Pline 增加节点的 UCS WCS OCS转换

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。