[分享]：以端点，端点，中点方式绘制圆弧

wkai

以端点，端点，中点方式绘制圆弧
[PHP](defun c:tt (/ p1 p2 p3 e run)
  (defun p_on_line (pt pt1 pt2)
    (equal (+ (distance pt pt1) (distance pt pt2))
           (distance pt1 pt2)
           1e-4
    )
  )
  (setq run t)
  (setq p1 (getpoint))
  (setq p2 (getpoint p1))
  (while (and run (setq p3 (grread 1 3)))
    (if e(progn (entdel e) (setq e nil))
    )
    (print p3)
    (cond
      ((= 5 (car p3))
       (if (not (p_on_line (cadr p3) p1 p2))
         (progn
           (command "._arc" p1 (cadr p3) p2)
           (setq e (entlast))
         )
       )
      )
      ((= 3 (car p3))
       (if (not (p_on_line (cadr p3) p1 p2))
         (progn
           (command "._arc" p1 (cadr p3) p2)
           (setq run nil)
         )
       )
      )

    )
  )
)[/PHP]

陌生人

这样写是不是更简洁些？
不过用gr 不便捕捉，总是“心中永远的痛”。
[php]
(defun c:tt (/ p1 p2 p3 e run)
  (defun p_on_line (pt pt1 pt2)
    (equal (+ (distance pt pt1) (distance pt pt2))
       (distance pt1 pt2)
       1e-4
    )
  )
  (setq run t e nil)
  (setq p1 (getpoint "\n圆弧起点:"))
  (setq p2 (getpoint p1 "\n圆弧终点:"))
  (princ "\n圆弧控制点:")
  (while (and p1 p2 run (setq p3 (grread 1 3)))
    (if e (entdel e))
    ;(print p3)
    (if (not (p_on_line (cadr p3) p1 p2))
       (progn
         (command "._arc" p1 (cadr p3) p2)
         (setq e (entlast))
       )
    )
    (if(= 3 (car p3)) (setq run nil))
  )e
)[/php]

aeo

最初由 陌生人 发布
[B]这样写是不是更简洁些？
不过用gr 不便捕捉，总是“心中永远的痛”。
[php]
(defun c:tt (/ p1 p2 p3 e run)
  (defun p_on_line (pt pt1 pt2)
    (equal (+ (distance pt pt1) (distance pt pt2))
      ... [/B]

也可以:
  先任意画出圆弧(p1 p2 p??)
grread过程中entmod.
求圆心?!

陌生人

改圆心我也想到过，不过一般情况下不太愿意用grread（除非不得已），因此也没有继续。
再换一个思路，有没有人想到过这个？：
我更愿意这样：
利用3点画圆，这个支持捕捉：）：
加了个line，为了方便看清楚要画的圆弧起点终点
虽然先画了个圆，但是并不妨碍对要画的圆弧的理解，和失去捕捉比起来，是不是更爽呢？
[php]
(defun c:arc3(/ p1 p2)
  (setq p1 (getpoint "\n起点:"))
  (setq p2 (getpoint p1 "\n终点:"))
  (vl-cmdf ".line" p1 p2 "")
  (setq e (entlast))
  (vl-cmdf ".circle" "3p" p1 p2 pause)
  (vl-cmdf ".erase" (entlast) e "")
  (vl-cmdf ".arc" p1 (getvar "lastpoint")p2)
)
[/php]

做了个演示，可惜发不上来：（