[求助]：怎么将单行文字转换为属性文字？

xbx7920

欲将单行文字转换为属性文字，我写了个小LISP，
但是测试时却提示:
Command: zu
please select single text:AutoCAD Error: bad argument type*Cancel*
Command:
请帮助看看错在哪里？急！

(defun c:zu(/ en1 data txt tag promp default high width layer coord ang style lst)
  (setq old (getvar "cmdecho"))
  (setvar "cmdecho" 0)
  (setq en1 (entsel "\nplease select single text:"))
  (setq data (entget (car en1)))
  (setq txt (cons 0 "ATTDEF")  
        tag (cons 1 (cadr(assoc 1 data )))
        promp (cons 2 (cadr(assoc 1 data )))
        default (cons 3 (cadr(assoc 1 data )))
        high (assoc 40 data)
        width (assoc 41 data)
        layer (assoc 8 data)
        coord (assoc 10 data)
        ang (assoc 50 data)
        style (assoc 7 data))   
  (setq lst (list txt tag promp default high width layer coord ang style))
  (entmake lst)
  (setvar "cmdecho" old)
  (princ)
)

snsj

cadr换成cdr，不用那么复杂吧

2. 
   
3. 参考：
   
4. (defun zm (obj x /)
   
5.   (cdr(assoc x(entget obj)))
   
6.   )
   
7. (defun c:test (/ b)
   
8. (setq b(car(entsel)))
   
9. (command "attdef" "" (zm b 1) "" "" (zm b 10) (zm b 40) (zm b 50))
   
10. (command "erase" b "")
    
11.   )
    
12. ;;;vla方法
    
13. (defun c:test (/ a)
    
14. (setq a (vlax-ename->vla-object(car(entsel"\nSelect the object:"))))
    
15. (vla-addattribute (vla-get-modelspace(vla-get-ActiveDocument(vlax-get-acad-object)))
    
16.                     (vla-get-height a) acAttributeModePreset (vla-get-textstring a)
    
17.   (vla-get-InsertionPoint a) (vla-get-textstring a) (vla-get-textstring a)
    
18.   )(vla-erase a)
    
19. )
    

<br /> 参考：<br /> (defun zm (obj x /)<br />   (cdr(assoc x(entget obj)))<br />   )<br /> (defun c:test (/ b)<br /> (setq b(car(entsel)))<br /> (command "attdef" "" (zm b 1) "" "" (zm b 10) (zm b 40) (zm b 50))<br /> (command "erase" b "")<br />   )<br /> ;;;vla方法<br /> (defun c:test (/ a)<br /> (setq a (vlax-ename->vla-object(car(entsel"\nSelect the object:"))))<br /> (vla-addattribute (vla-get-modelspace(vla-get-ActiveDocument(vlax-get-acad-object)))<br />                     (vla-get-height a) acAttributeModePreset (vla-get-textstring a)<br />   (vla-get-InsertionPoint a) (vla-get-textstring a) (vla-get-textstring a)<br />   )(vla-erase a) <br /> )<br />

aidraft

(defun c:zu  (/ old en1 data)
  (setq old (getvar "cmdecho"))
  (setvar "cmdecho" 0)
  (setq en1 (car (entsel "\nplease select single text:")))
  (setq data (entget en1))
  (ENTMAKE (LIST
        (cons 0 "ATTDEF")
        (cons 1 (cdr (assoc 1 data)))
        (cons 2 (cdr (assoc 1 data)))
        (cons 3 (cdr (assoc 1 data)))
        (assoc 40 data)
        (assoc 41 data)
        (assoc 8 data)
        (assoc 10 data)
        (assoc 50 data)
        (assoc 7 data)
        (CONS 70 0)
       )
  )
  (entdel en1)
  (setvar "cmdecho" old)
  (princ)
  )

xbx7920

SNSJ兄，别来无恙。
谢谢SNSJ兄及AIDRAFT两位的帮助，困难已排除。只是我不明白我的LISP到底错在哪里？

aidraft

tag (cons 1 (cadr(assoc 1 data )))
promp (cons 2 (cadr(assoc 1 data )))
default (cons 3 (cadr(assoc 1 data )))
这里cadr应该为cdr
另外组码70好像是必须的

aeo

应该用取代法比较全面
(setq e(car(entsel)))
(setq en(entget e))
(setq en(vl-remove-if '(lambda(x)(member(car x) '(-1 100 0))) en) )  ;去掉不要的
(加入 (0 2 3 70) )
(73 变74)
(entmake ..)

aeo

[php]
(defun mkatt(en)
(entmake (apply 'append
  (mapcar
    '(lambda(x)(setq y(car x))
       (cond((= y 0) '((0 . "ATTDEF")(70 . 0)) )
            ((= y 100) nil)
            ((= y 1)(list x (cons 2(cdr x))(cons 3(cdr x))))
            ((= y 73)(list(cons 74(cdr x))))
            (t (list x))
       )
   )en)
))
)
[/php]

(mkatt (entget(car(entsel))))

梦断江南

最初由 aeo 发布
[B]
(defun mkatt(en)
(entmake (apply 'append
  (mapcar
    '(lambda(x)(setq y(car x))
       (cond((= y 0) '((0 . "ATTDEF")(70 . 0)) )
            ((= y 100) nil)
            ((= y 1)(list ... [/B]

这个是我前两天写的：）和aeo的挺象的，呵呵
[php]
;; (txt2def e) = 文本改为属性.
;; e = text 实体名.
(defun txt2def (e / a b)
  (entmake
    (apply
      'append
      (mapcar '(lambda (x)
                 (setq a (car x))
                 (cond
                   ((member a '(-1 5 100)) nil)
                   ((= 0 a) (list (cons 0 "ATTDEF")))
                   ((= 1 a)
                    (setq b (cdr x))
                    (list (cons 1 b) (cons 2 b) (cons 3 b) (cons 70 0)))
                   (T (list x))
                 )
               )
              (entget e)
      )
    )
  )
  (entdel e)
)[/php]