发两个小东西,选择含有相同属性值的同名块，并调用 特性面板 进行编辑

梦断江南

发两个小东西，帮同事写的.
[pcode=lisp,true]
;; 选择同名块，并调用 特性面板 进行编辑.
(defun c:propblk ()
  (setq ss (ssget "x" (list (cons 0 "INSERT")(cons 2 (cdr(assoc 2 (entget(car(entsel "\n 选择参照块：")))))))))
  (sssetfirst ss ss)
  (vl-cmdf "._properties")
)

;; 选择含有相同属性值的同名块，并调用 特性面板 进行编辑.
(defun c:proprib (/ ss2 el en de d0 ss e o)
  (setq        ss2 (ssadd)
        el  (entsel "\n 选择参照块中的属性：")
        en  (entget (car el))
        de  (nentselp (cadr el))
        den (entget (car de))
  )
  (cond
    ((= "ATTRIB" (cdr (assoc 0 den)))
     (setq d0 (cdr (assoc 1 den))
           ss (ssget "x"(list (cons 0 "INSERT")(cons 2 (cdr (assoc 2 en)))))
           i  -1)
     (while (setq e (ssname ss (setq i (1+ i))))
       (setq o (vlax-ename->vla-object e))
       (if(and
           (eq (vla-get-HasAttributes o) :vlax-true)
           (apply 'or(mapcar'(lambda (x) (eq (vla-get-TextString x) d0))(vlax-invoke o 'GetAttributes)))
         )
          (ssadd e ss2)
       )
     )
     (progn (sssetfirst ss2 ss2) (vl-cmdf "._properties"))
    )
    (T (princ "\n 没有合适的实体!"))
  )
  (princ)
)
[/pcode]

LUCAS

;;江南兄:Sorry![幫]同事寫的PROPRIB程序(點選及判斷結構寫得很差)!!  8-(

梦断江南

献丑了，临时写的，因为块中可能会有多个属性，属性值也各不相等，所以必须直接点中属性，才得到想要的选集，一时间还没想到更好的办法。
至于点选及判断结构，因为上述原因，这么写操作起来也不会“出错”。只是没有点中物体的时候，返回出错提示有点不雅观。
修改了一个
[pcode=lisp,true]
(defun c:bbb (/ dxf ss2 ae bn d0 i ss e o)
  (defun dxf (e id)(cdr(assoc id (entget e)))) ;; 取实体-实体表 的索引值.
  (setq        ss2 (ssadd)
        ae  (nentsel "\n 选择参照块中的属性<退出>：")
  )
  (cond
    ((member (getvar "errno") '(52 2)) nil)
    ((and ae (= "ATTRIB" (dxf (car ae) 0)))
     (setq bn (dxf (ssname (ssget (cadr ae) '((0 . "INSERT"))) 0) 2)
           d0 (dxf (car ae) 1))
     (setq i -1 ss (ssget "x" (list (cons 0 "INSERT")(cons 2 bn))))
     (while (setq e (ssname ss (setq i (1+ i))))
       (setq o (vlax-ename->vla-object e))
       (if (apply 'or (mapcar'(lambda (x) (eq (vla-get-TextString x) d0))(vlax-invoke o 'GetAttributes)))
         (ssadd e ss2)
       )
     )
     (sssetfirst ss2 ss2)
     (vl-cmdf "._properties")
    )
    (T (princ "\n 没有选中有效实体!")(c:bbb))
  )(princ)
)
[/pcode]

请lucas指点，支招;)

赵三多

选择同名块，这个非常好。