[讨论]：台阶为什么有时候画不对

pandoit

请教大家一个问题，我刚学lisp写了一段画台阶的程序，但是如果输入的台阶高度比较小的时候画出的是斜线而不是台阶，不知道是什么缘故，比如分别输入1，0.5这样的台阶是可以画的，而输入1，0.1这样的台阶就不能画了，成了斜线，请高手指导！
(defun c:taijie ( / x y n x0 x1 y1 z1 pt1 pt2)
  (setq x (getreal "水平距离=")
)
(setq y (getreal "垂直距离=")
)
(setq n (getint "台阶数量=")
)
(setq x0 (getpoint "请选择台阶起点：")
)
(repeat n
(setq x1 (nth 0 x0))
(setq y1 (nth 1 x0))
(setq z1 (nth 2 x0))
(setq pt1 (list (+ x1 x) y1 z1)
  )
(setq pt2 (list (+ x1 x) (+ y1 y) z1)
  )
  (command "line" x0 pt1 pt2  \n)
  (setq x0 pt2)
))

hyx_lyn

你可以先把捕捉关掉试试
[php]
(setq osm (getvar "osmode"));保存原捕捉设置
(setvar "osmode" 0);关闭捕捉
....
(setvar "osmode" osm)恢复捕捉
[/php]

pandoit

谢谢你，问题似乎已经解决，不过是为什么了，难道在执行“line”的过程中程序会自己对一些点进行捕捉吗？能否解释一下呢？

hyx_lyn

楼主说的没错，当你画图时取的点如果离设置的捕捉点近的话，会自动进行捕捉，这是一个智能的方法以确保画图的准确度，但在用程序绘图时会出现一些奇怪的现象，所以一般在程序当中会把捕捉关闭或按需要设置。

pandoit

那么我想再请教一个问题，如果我想把这些线条直接连成pl线条时该如何写这段程序？是不是会复杂很多呢

zjfcumt

可以在程序的最后用“pedit”命令，把单线变成PL

pandoit

还是不清楚，我如何用程序取得我刚才画的那些线呢?

xtjd

(defun c:7s2(/ pa pb pc ww hh dw hw pp p1 p2)
     (setq pa (getpoint "左下角點:"))
     (setq ww (getdist pa "\n寬度:"))
     (setq hh (getdist pa "\n高度:"))
     (setq nn (getint "\n梯數:"))
     (setq dw (/ ww nn))
     (setq hw (/ hh nn))
     (setq pb (polar pa 0 ww))
     (setq pc (polar pb (/ pi 2) hh))
     (setq pp pa)
     (command ".pline" pc pb pa)
     (repeat nn
            (setq p1 (polar pp (/ pi 2) hw))
            (setq p2 (polar p1 0 dw))
            (command p1 p2)
            (setq pp p2)
     )
    (command "")
)

zjfcumt

(defun c:taijie        (/ x y n x0 x1 y1 z1 pt1 pt2 ss oldosm oldcmd)
  (setq        x (getreal "水平距离="))
  (setq        y (getreal "垂直距离="))
  (setq        n (getint "台阶数量="))
  (setq        x0 (getpoint "请选择台阶起点："))
  (setq        oldosm (getvar "OSMODE")       
        oldcmd (getvar "cmdecho"))
  (setvar "osmode" 0)
  (setvar "cmdecho"0)
  (setq ss(ssadd))
  (repeat n
    (setq x1 (nth 0 x0))
    (setq y1 (nth 1 x0))
    (setq z1 (nth 2 x0))
    (setq pt1 (list (+ x1 x) y1 z1))
    (setq pt2 (list (+ x1 x) (+ y1 y) z1))
    (command "pline" x0 "w" 0 0 pt1 pt2 "")
    (setq ss (ssadd (entlast) ss))
    (setq x0 pt2)
  )
  (command "pedit" (entlast)  "j" ss "" "")
  (setvar "osmode" oldosm)
  (setvar "cmdecho" oldcmd)
)