[求助]：如何过滤文字？

gxynd

在进行autolisp进行编写程序时，我想提取文字中的数字如“K3+510”，我想提取其中的3510，而自动过滤掉"K"和"+"，如何实现这个目标呢？能不能实现这个目标呢？如果能，望兄台指点一二，举一两个例子，让小弟也学学。

aidraft

; By Bill Kramer----------------------------------------------------- Listing 4.4
; Useage: (String_To_Numbers "K3+150")
(defun String_To_Numbers (
                          inStr  ;;Input string
                          /
                          Res    ;;Result list
                          Buf    ;;String buffer
                          Inx      ;;Character location
                          CH     ;;Character
                          )
  (setq Inx 1 ;start at the beginning of the string
        Buf "" ;init buffer to empty
        )
  ;
  ; Loop until the end of the string.
  ; (I indicates where we are in the string)
  ;
  (while (<= Inx (strlen inStr))
    ;
    ; Get the character at position Inx, increment position indicator
    (setq CH (substr inStr Inx 1)
          Inx (1+ Inx)
          )
    ;
    (cond
      ; Test to see if character is a digit.
      ((wcmatch CH "[0-9.]")
        (if (= CH ".") ;is it decimal?
          (if (not (wcmatch Buf "*`.*")) ;not already in there
            (setq Buf (strcat Buf CH))
            (Flush_Buf))
          ;
          (setq Buf (strcat Buf CH)))
      )
      ((= Buf "") ;is the buffer empty?
               ;Is CH minus
        (if (= CH "-")
          (setq Buf CH) ;Yes, save in Buf
        )
      )
      ('T ;else buffer is not empty
        (Flush_Buf)
        (if (= CH "-")
          (setq Buf CH))
      )
    ); End of COND
  ); End of WHILE
  ;
  (if (and (/= Buf "")
           (not (wcmatch Buf "[+-.]"))
           )
    (Flush_Buf))
  (reverse Res)
)
;
; ------------------------------------------------------ Listing 4.5
;
(defun Flush_Buf ()
  (if (not (wcmatch Buf "[+-.]")) ;is it not just +-.?
    (progn
      ;Clean it up first
      (if (= (substr Buf 1 1) ".")
        (setq Buf (strcat "0" Buf))) ;;add zero to front if .#
      (if (= (substr Buf (strlen Buf)) ".")
        (setq Buf (substr Buf 1 (1- (strlen Buf))))) ;;remove decimal if #.
      ;Add to RES list
      (setq RES (cons Buf RES))))
  (setq Buf "") ;;reset Buf
)

panzhongw

楼上仁兄的程序真是不错，受教了，不过“1楼楼主”是学公路的，所以程序最后应把数字连接起来形成一个完整的数值。不过程序整体通用性好。

LUCAS

2. 
   
3. (vl-list->string
   
4.   (vl-remove 'NIL
   
5.              (mapcar '(lambda (X)
   
6.                         (if (member
   
7.                               X
   
8.                               '(48 49 50 51 52 53 54 55 56 57 46)
   
9.                             )
   
10.                           X
    
11.                         )
    
12.                       )
    
13.                      (vl-string->list "K3+510")
    
14.              )
    
15.   )
    
16. )
    

<br /> (vl-list->string<br />   (vl-remove 'NIL<br />              (mapcar '(lambda (X)<br />                         (if (member<br />                               X<br />                               '(48 49 50 51 52 53 54 55 56 57 46)<br />                             )<br />                           X<br />                         )<br />                       )<br />                      (vl-string->list "K3+510")<br />              )<br />   )<br /> )<br />

狂刀

这个 (vl-remove 'NIL 用的好