[求助]：如何用ActiveX方式定义一个匿名的简单块？

highflybird

找了lisp帮助和浏览了一些网页，没看到自己需要的，现请求帮助。

如何用ActiveX方式定义一个匿名的简单块(simple block)?

不用command 方式，不用entmake方式，用ActiveX方式，把选择集的东西定义为一个匿名的简单块。谁能给我一个lisp程序提示。谢谢了！

highflybird

to fsxm:
谢谢提供思路！但是用copyfrom 的方法不能创建，要用copyobjects的方法创建。
下面是用ACTIVEX方法创建匿名图块的完整例子：
可以通过取得选择集合，把选择集合定义为匿名图块，然后插入进来，最后删除选择集合。

[php]
(defun Nblock (ss insertpt / InsPt number blocklist blk index SelectionSetObjs)
  (setq InsPt (vlax-3d-point insertpt))              ;转化为ActiveX的点
  (setq number (sslength ss))
  (setq blocklist (vla-get-blocks AcadDocument))
  (setq blk (vla-add blocklist InsPt "*U"))          ;定义匿名图块
  (setq SelectionSetObjs (vlax-make-safearray vlax-vbobject (cons 0 (- number 1))))
  (defun item (ss index)
    (vlax-ename->vla-object (ssname ss index))
  )
  (setq index 0)
  (repeat number
    (vlax-safearray-put-element SelectionSetObjs index (item ss index))
    (setq index (1+ index))
  )                                                  ;把选择集的物体加入到匿名图块
  (vla-copyobjects AcadDocument SelectionSetObjs blk);采用copyobjects方式
  (vla-insertblock ModelSpace InsPt (vlax-get-property blk 'name) 1 1 1 0);插入图块
)

;;以下为测试程序:
(defun C:test()
  (vl-load-com)
  (setq        AcadObject   (vlax-get-acad-object)
        AcadDocument (vla-get-activeDocument AcadObject)
        ModelSpace   (vla-get-Modelspace AcadDocument)
  )
  (if (setq ss (ssget))                              ;取得选择集
    (if (setq insertpt (getpoint "\n请输入插入点: "));取得插入点
      (progn
        (nblock ss insertpt)                         ;做匿名图块
        (vl-cmdf ".erase" ss "")                     ;删除选择集
      )
    )
  )
  (princ)
)
[/php]

fsxm

highflybird 你自己去写一个吧~很简单的东东啦~
可以详细看看copyfrom方法在vlisp中就是:vla-copyfrom
先定义一个空的块再用copyfrom将选取的图元全拷贝进去就是了~

a117034423

还得是晓东论坛 lisp转匿名块无法实现属性块转换，研究好久没研究完，到这直接复制粘贴搞定了