[LISP函数]：有没有这样的函数？

redapple · 发表于 2003-11-2 11:17:48

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

证明圆弧与直线是否相切？有没有好的函数或者好办法？谢谢！

snsj · 发表于 2003-11-2 12:24:02

如果线与圆相切那么圆心到切点的线是和切线垂直的

lsjjm · 发表于 2003-12-24 06:45:56

最初由 snsj 发布
[B]如果线与圆相切那么圆心到切点的线是和切线垂直的 [/B]

已知条件只给出一个圆, 一条直线, 不知道切点呀?

wkai · 发表于 2003-12-24 07:55:51

圆心到直线的距离等于圆的半径。

zhynt · 发表于 2003-12-24 07:57:52

先求直线与圆的交点。没有交点和有两的交点就不谈了，只有一个交点就肯定相切。

(defun point_line (pt pt1 pt2 / ptangle ptn pt pt1 pt2 dist jptx)
(setq ptangle (angle pt1 pt2)
ptn (polar pt (+ (* 0.5 pi) ptangle) 0.01)
jptx (inters pt ptn pt1 pt2 nil)
dist (distance pt jptx)
)
dist
)
(defun c:l_c ()
(setq c (car (entsel "\n选择圆或圆弧:")))
(setq l (car (entsel "\n选择直线:")))
(setq cent (cdr (assoc 10 (entget c))))
(setq cdist (cdr (assoc 40 (entget c))))
(setq lent1 (cdr (assoc 10 (entget l)))
lent2 (cdr (assoc 11 (entget l)))
)
(if (equal (point_line cent lent1 lent2) cdist 1e-10)
(princ "\n直线与圆相切")
(princ "\n直线于圆不相切")
)
(princ)
)

lsjjm · 发表于 2003-12-24 09:43:58

判断圆弧和直线是否相切(也使用于其他曲线和直线):
(defun c:test (/ pts)
 (vl-load-com)
 (setq a (car (entsel "\nSelect Arc:")))
 (setq b (car (entsel "\nSelect Line:")))
 (setq pts (vla-IntersectWith
 (vlax-ename->vla-object a)
 (vlax-ename->vla-object b)
 acExtendnone))
 (setq m (vlax-safearray-get-u-bound (vlax-variant-value pts) 1))
 (if (or (< m 0)(> m 2))
nil
T
 )
)

aeo · 发表于 2003-12-24 23:42:57

最初由 zhynt 发布
[B]先求直线与圆的交点。没有交点和有两的交点就不谈了，只有一个交点就肯定相切。
[code]
(defun point_line (pt pt1 pt2 / ptangle ptn pt pt1 pt2 dist jptx)
(setq ptangle (angle pt1 pt2)
ptn (polar pt (... [/B]

圆心到直线的距离=半径,是必要条件.
而且这条垂线要在这条弧线的角度范围内.

lsjjm · 发表于 2003-12-25 06:18:35

更正: 6贴中acExtendnone应为acExtendBoth.

陌生人 · 发表于 2003-12-25 14:04:14

如果是求实际切点,满足:
圆弧与直线有实交点
圆心与直线最近点距离=半径

aeo · 发表于 2003-12-25 22:11:55

最初由 lsjjm 发布
[B]更正: 6贴中acExtendnone应为acExtendBoth. [/B]

还是不对的:假定本来就没相交呢，给你延伸了一下才有了交点.
acExtendnone和acExtendBoth都只有一个才是.

上楼的：既然求了交点，判断几个就行了，而不用vl方法，求交点要代数求了.

求出垂线,垂线距离=半径,垂线角度在弧线的起始角和中止角间,这样很方便的.

;;;弧线和直线相切?
(defun arc-line(a l / an an-e ang an-s is ln p10 p11 pa pb r dxf)
(defun dxf(a b)(cdr(assoc a b)))
(setq an(entget a)ln(entget l)
p10(dxf 10 ln)p11(dxf 11 ln)
pA(dxf 10 an)
r(dxf 40 an)
an-s(dxf 50 an)an-e(dxf 51 an)
is(if(> an-s an-e) t nil)
PB(inters p10 p11 pA(polar pA(+(* 0.5 pi)(angle p10 p11))100.)nil)
ang(angle pa pb)
)
(if(and(equal r(distance pA pB) 1e-5)
(if is(not(> an-s ang an-e))(>= an-e ang an-s))
)
t nil)
)
;;;试验
(defun c:test( / a b)
(setq b(car(entsel"\nLIne:")) a(car(entsel"--ARC:")))
(princ (arc-line a b))
(princ)
)

wkai · 发表于 2003-12-25 22:22:11

最初由 aeo 发布
[B]
求出垂线,垂线距离=半径,垂线角度在弧线的起始角和中止角间,这样很方便的. [/B]

同意，提供相关函数代码.

[FONT=courier new]
;___________________求点到直线的垂足的函数,输入值测试点,直线端点1,端点2.返回值垂足坐标
(defun pedal_to_line (pt pt1 pt2)
(inters
pt
(polar pt (+ (/ pi 2) (angle pt1 pt2)) 1000)
pt1
pt2
nil
)
)
;___________________测试点是否在圆弧上,输入值测试点,圆心,起始角度,终止角度.返回值T或者NIL
(defun p_on_arc (pt cn an1 an2)
(if (> an1 an2)
(setq an1 (- an1 (* 2 pi))))
(or
(and (>= (+ (angle cn pt) pi pi) an1) (<= (+ (angle cn pt) pi pi) an2))
(and (>= (angle cn pt) an1) (<= (angle cn pt) an2))
(and (>= (- (angle cn pt) pi pi) an1) (<= (- (angle cn pt) pi pi) an2))
)
)
[/FONT]

陌生人 · 发表于 2003-12-26 01:07:44

"上楼的：既然求了交点，判断几个就行了，而不用vl方法，求交点要代数求了."
说的对!提醒了我.呵呵.来个一网打尽.

看我的:

;|判断两个实体是否相切;----------------------------陌生人.2003.12
函数: (x_tan obj1 obj2 ExtendOption)
语法: 1.obj1 任意实体; obj2 全段有切线属性的实体,如arc,spline,circle,ellipse.*polyline
2.ExtendOption: 指定两个对象中是否没有(acExtendNone=0)、第一个(acExtendThisEntity=1),第二个(acExtendOtherEntity=2)
或两个对象(acExtendBoth=3)延伸来得到交点.
实例: 1.(x_tan (car(entsel)) (car(entsel)) 2)
2.(list
(setvar "osmode" 512)
(while(not (setq ss (ssget (getpoint "\n选直线:") '((0 . "line"))))))
(setq obj1 (ssname ss 0))
(while(not(setq ss (ssget (getpoint "\n选圆弧:") '((0 . "arc"))))))
(setq obj2 (ssname ss 0))
(x_tan obj1 obj2 acExtendThisEntity) ;延伸第一个.
)
|;
(defun x_tan (obj1 obj2 ExtendOption)
(setq pts1 (vla-IntersectWith (vlax-ename->vla-object obj1) (vlax-ename->vla-object obj2) ExtendOption)
pts2 (vla-IntersectWith (vlax-ename->vla-object obj1) (vlax-ename->vla-object obj2) acExtendboth)
ints1 (vlax-safearray-get-u-bound (vlax-variant-value pts1) 1)
ints2 (vlax-safearray-get-u-bound (vlax-variant-value pts2) 1))
(if (= ints1 ints2 2) T nil)
)

;|判断两个实体是否相切;----------------------------陌生人.2003.12 
  函数: (x_tan obj1 obj2 ExtendOption) 
  语法: 1.obj1 任意实体; obj2 全段有切线属性的实体,如arc,spline,circle,ellipse.*polyline 
        2.ExtendOption: 指定两个对象中是否没有(acExtendNone=0)、第一个(acExtendThisEntity=1),第二个(acExtendOtherEntity=2) 
         或两个对象(acExtendBoth=3)延伸来得到交点. 
  实例: 1.(x_tan (car(entsel)) (car(entsel)) 2) 
        2.(list 
           (setvar "osmode" 512) 
           (while(not (setq ss (ssget (getpoint "\n选直线:") '((0 . "line")))))) 
           (setq obj1 (ssname ss 0)) 
           (while(not(setq ss (ssget (getpoint "\n选圆弧:") '((0 . "arc")))))) 
           (setq obj2 (ssname ss 0)) 
           (x_tan obj1 obj2 acExtendThisEntity) ;延伸第一个. 
          ) 
|; 
 
(defun x_tan (obj1 obj2 ExtendOption) 
 (setq pts1 (vla-IntersectWith (vlax-ename->vla-object obj1) (vlax-ename->vla-object obj2) ExtendOption) 
       pts2 (vla-IntersectWith (vlax-ename->vla-object obj1) (vlax-ename->vla-object obj2) acExtendboth) 
       ints1 (vlax-safearray-get-u-bound (vlax-variant-value pts1) 1) 
       ints2 (vlax-safearray-get-u-bound (vlax-variant-value pts2) 1)) 
 (if (= ints1 ints2 2) T nil) 
)

lsjjm · 发表于 2003-12-26 04:41:42

最初由 aeo 发布
[B]...还是不对的:假定本来就没相交呢，给你延伸了一下才有了交点.acExtendnone和acExtendBoth都只有一个才是...[/B]

如果只用acExtendnone, 是不能完全判断的, 例如直线和圆弧相交一点, 你怎么说就一定相切呢?

陌生人 · 发表于 2003-12-26 13:27:20

我的12贴自己测试了几个例子,都通过了.
大家也帮忙测试下:)

on/off · 发表于 2003-12-26 18:30:11

cbx老师提供过用老lisp写的程序。

账号		自动登录	找回密码
密码			立即注册

[LISP函数]：有没有这样的函数？

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

相关帖子