[其他]：简化对话框的编制工作

mmmm · 发表于 2004-1-17 13:36:15

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

设计思路：
给每个控件定义特定的性质，再由程序去根据不同的性质来处理数据，对话框关闭后可以从总数据表中抽取数据进行进一步的运算。作为实例，现在处理edit_box toggle radio_button button四种控件。

总体数据表*DCL-DATA*格式为
（控件key值（0 。空间类型）（1 。首次进入对话的缺省值）（2 。可能的更多数据表如表内容等）（3 。控件为真时变灰的其他控件）

edit_box
("EnterValue" (0 . "edit_box")(1 . "12.0") (2 . ":REAL"))
2项: 表示输入文本框内的数据类型: ":REAL" ":INT",如果为任意文本，没有2项

toggle
("ToggleEnter" (0 . "toggle")(1 . "0") (3 . (list "accept" "help" "orthers")))
3项：表示ToggleEnter为1时需要变灰的控件列表,
2项：因为只能为1或0，所以没有定义2项

radio_button
("RadioMain" (0 . "radio_button")(1 . "Radio1") (2 . (list "Radio1" "Radio2" "Radio3"))
(3 . (list "Radio1" "Radio3") (list "accept" "help" "orthers"))\
)
对于radio_button，只需要定义其上级控件key值，所有属于一个主控件的所有radio_button的key值列表在2项
3项：共分为两部分，第一部分为radio_button的key值列表，表示选定这些key值时需要将第二部分的控件列表变灰。

button
("Button" (0 . "button")(1 . -1) (2 . "(Action_PickButton)"))
1项：表示Done_dialog ID值，如果对话框不关闭，为任意负整数
2项：表示相对应得操控函数，自己加变量（变量的传递要再设计）

LISP/DCL codes

(Defun vldcl-init (DCLFile DCLName)
(cond ((= (type DCLFile) 'STR)
(if (setq *DCLID* (findfile DCLFile))
(progn
(setq *DCLID* (load_dialog DCLFile))
(new_dialog DCLName *DCLID*)
)
)
)
((null DCLFile)
(if *DCLID*
(unload_dialog *DCLID*)
)
(setq *DCLID* nil)
)
(t (setq *DCLID* nil))
)
*DCLID*
)
(Defun vldcl-update (id val / data)
;;; update *DCL-DATA*
(if (setq data (cdr (assoc id *DCL-DATA*)))
(setq data (subst (cons 1 val) (assoc 1 data) data)
*DCL-DATA* (subst (cons id data) (assoc id *DCL-DATA*) *DCL-DATA*)
)
)
)
(Defun vldcl-update2 (key val)
;;; UPdate *DCL-DONEDIALOG*
(if (null (cdr (assoc val *DCL-DONEDIALOG*)))
(setq *DCL-DONEDIALOG* (cons (cons val key) *DCL-DONEDIALOG*))
(setq *DCL-DONEDIALOG*
(subst (cons val key)
(assoc val *DCL-DONEDIALOG*)
*DCL-DONEDIALOG*
)
)
)
(action_tile key (strcat "(done_dialog " (itoa val) ")"))
)
(Defun vldcl-getvalue (key / rtn)
(setq rtn (cdr (assoc 1 (cdr (assoc key *DCL-DATA*)))))
(if (/= (type rtn) 'STR)
(setq rtn "")
)
rtn
)
(Defun vldcl-samestrlen (str proto char / ipro ist rtn)
(setq istr (strlen str)
ipro (strlen proto)
rtn str
)
(if (> istr ipro)
(setq rtn (substr str 1 ipro))
(repeat (- ipro istr)
(setq rtn (strcat rtn char))
)
)
rtn
)
(Defun vldcl-settile (/ data key ktype kval kpval item)
(foreach data *DCL-DATA*
(setq key (car data)
data (cdr data)
ktype (cdr (assoc 0 data))
kval (cdr (assoc 1 data))
kpval (cdr (assoc 2 data))
)
(cond
((= ktype "edit_box")
(cond
((= kpval ":INT")
(vldcl-editbox-int key kval)
(action_tile key "(vldcl-editbox-int $key $value)")
)
((= kpval ":REAL")
(vldcl-editbox-real key kval)
(action_tile key "(vldcl-editbox-real $key $value)")
)
(vldcl-editbox-string key kval)
(t (action_tile key "(vldcl-editbox-string $key $value)"))
)
)
((= ktype "toggle")
(vldcl-toggle key kval)
(action_tile key "(vldcl-toggle $key $value)")
)
((= ktype "button")
(if (> kval 1)
(vldcl-update2 key kval)
)
(if (< kval 0)
(action_tile key kpval)
)
(if (> kval 1)
(progn
(setq done (list kval key kpval))
(if (null (cdr (assoc kval *DCL-DONEDIALOG*)))
(setq *DCL-DONEDIALOG*
(cons done
*DCL-DONEDIALOG*
)
)
(setq *DCL-DONEDIALOG*
(subst
done
(assoc kval *DCL-DONEDIALOG*)
*DCL-DONEDIALOG*
)
)
)
)
)
)
((= ktype "radio_button")
(vldcl-radio key kval)
(foreach item kpval
(action_tile
item
(strcat "(vldcl-radio \042" key "\042 $key)")
)
)
)
)
)
)
(Defun vldcl-list (key data index)
(start_list key)
(mapcar 'add_list data)
(end_list)
(set_tile key index)
)
(Defun vldcl-button (key / func)
(if (eval (read (setq func (strcat "action_" key))))
(eval (read (strcat "(" func ")")))
)
)
(Defun vldcl-radio (key val / gray keyx mode item func)
(set_tile key val)
(vldcl-update key val)
(if (setq gray (cdr (assoc 3 (cdr (assoc key *DCL-DATA*)))))
(progn
(setq keyx (nth 0 gray)
gray (nth 1 gray)
)
(if (member val keyx)
(setq mode 1)
(setq mode 0)
)
(foreach item gray
(mode_tile item mode)
)
)
)
(if (eval (read (setq func (strcat "action_" val))))
(eval (read (strcat "(" func ")")))
)
)
(Defun vldcl-toggle (key val / keyx func)
(set_tile key val)
(vldcl-update key val)
(foreach keyx (cdr (assoc 3 (cdr (assoc key *DCL-DATA*))))
(mode_tile keyx (abs (1- (read val))))
)
(if (eval (read (setq func (strcat "action_" key))))
(eval (read (strcat "(" func ")")))
)
)
(Defun vldcl-editbox-int (key val1 / val0 func)
(setq val0 (vldcl-getvalue key)
val1 (get_tile key)
)
(if (/= (itoa (read val1)) val1)
(set_tile key val0)
(vldcl-update key val1)
)
(if (eval (read (setq func (strcat "action_" key))))
(eval (read (strcat "(" func ")")))
)
)
(Defun vldcl-editbox-real (key val1 / val0 func)
(setq val0 (vldcl-getvalue key)
val1 (get_tile key)
)
(if (null (numberp (read val1)))
(set_tile key val0)
(vldcl-update key val1)
)
(if (eval (read (setq func (strcat "action_" key))))
(eval (read (strcat "(" func ")")))
)
)
(Defun vldcl-editbox-string (key val / func)
(vldcl-update key val)
(if (eval (read (setq func (strcat "action_" key))))
(eval (read (strcat "(" func ")")))
)
)
(Defun vldcl-graytile (keys val / key)
(foreach key keys
(mode_tile key val)
)
)
(Defun vldcl-actiontile (/ id done key)
(foreach done *DCL-DONEDIALOG*
(setq id (nth 0 done)
key (nth 1 done)
)
(action_tile key (strcat "(done_dialog " (itoa id) ")"))
)
)
(Defun vldcl-donedialog (/ key)
(if (setq key (cdr (assoc *DCLRTN* *DCL-DONEDIALOG*)))
(if (eval (read (setq key (nth 1 key))))
(eval (read key))
)
)
)
(Defun c:xx (/ *DCLID* *DCL-DATA*
*DCL-DONEDIALOG* *DCLRTN*
action_pickx action_picky
)
(defun action_pickx ()
(getstring "\n Close dialog to enter string:")
)
(defun action_picky ()
(alert "SDfsdg")
)
(setq *DCL-DATA*
(list
(cons "DistX"
(list (cons 0 "edit_box") (cons 1 "0.0") (cons 2 ":REAL"))
)
(cons "DistY"
(list (cons 0 "edit_box") (cons 1 "0.0") (cons 2 ":REAL"))
)
(cons "ToggleAttribute"
(list (cons 0 "toggle") (cons 1 "1"))
)
(cons "ToggleDefault"
(list (cons 0 "toggle")
(cons 1 "1")
(cons 3 (list "help"))
)
)
(cons "ToggleRow2Col"
(list (cons 0 "toggle")
(cons 1 "1")
(cons 3 (list "help"))
;;; Gray tiles
)
)
(cons
"RadioX"
(list (cons 0 "radio_button")
(cons 1 "AutoX")
(cons 2 (list "AutoX" "UserX" "IgnoreX" "PickX"))
(cons 3
(list (list "AutoX" "IgnoreX") (list "DistX" "PickX"))
)
;;; Gray tiles
)
)
(cons
"RadioY"
(list (cons 0 "radio_button")
(cons 1 "AutoY")
(cons 2 (list "AutoY" "UserY" "IgnoreY" "PickY"))
(cons 3
(list (list "AutoY" "IgnoreY") (list "DistY" "PickY"))
)
;;; Gray tiles
)
)
(cons "PickX"
(list (cons 0 "button")
(cons 1 2)
(cons 2 "(action_pickx)")
)
)
(cons "PickY"
(list (cons 0 "button")
(cons 1 -1)
(cons 2 "(action_picky)")
)
)
)
*DCLRTN* 10
)
(while (> *DCLRTN* 0)
(vldcl-init "g:/test.dcl" "Main")
(vldcl-settile)
(vldcl-actiontile)
(setq *DCLRTN* (start_dialog))
(vldcl-donedialog)
(alert "end")
(vldcl-init nil nil)
)
;;;(get data from *DCL-DATA* and run orther operations/functions
)
(c:xx)
;| DCL files
dcl_settings : default_dcl_settings { audit_level=0; }
Main : dialog {
label="[KozMos OASis-XLS/VTM]: 设定" ;
: boxed_row {
label="虚拟表格文本行列分隔设定" ;
: boxed_radio_column {
key="RadioX" ;
label="X方向[列]" ;
: radio_button {
key="AutoX" ;
label="自动检测" ;
}
: radio_button {
key="IgnoreX" ;
label="忽略列分隔" ;
}
: radio_button {
key="UserX" ;
label="用户指定" ;
}
: button {
key="PickX" ;
label="点取距离 <" ;
}
: edit_box {
key="DistX" ;
label="X:" ;
}
}
: boxed_radio_column {
key="RadioY" ;
label="Y方向[行]" ;
: radio_button {
key="AutoY" ;
label="自动检测" ;
}
: radio_button {
key="IgnoreY" ;
label="忽略行分隔" ;
}
: radio_button {
key="UserY" ;
label="用户指定" ;
}
: button {
key="PickY" ;
label="点取距离 <" ;
}
: edit_box {
key="DistY" ;
label="Y:" ;
}
}
}
: row {
: boxed_column {
label="虚拟表格文本高级设定" ;
: toggle {
key="ToggleAttribute" ;
label="允许编辑块内属性" ;
}
: toggle {
key="ToggleDefault" ;
label="保存当前设定为缺省" ;
}
: toggle {
key="ToggleRow2Col" ;
label="转化单行为单列" ;
}
: button {
key="SortPoint" ;
label="分隔定位点..." ;
}
}
: boxed_column {
label="操作命令";
: button {
key="help" ;
label="帮助..." ;
}
: button {
key="accept" ;
label="选择实体 <" ;
is_default=true ;
}
: button {
key="cancel" ;
label="取消" ;
is_cancel=true ;
}
}
}
errtile ;
}
Sort : dialog {
label="[KozMos OASis-XLS/VTM]: 文本定位点" ;
: image {
color=white ;
key="Image" ;
width=15 ;
height=6 ;
}
: text {
label="蓝色矩形框表示文本范围框";
}
: boxed_row {
label="计算文本分隔使用定位点" ;
: boxed_radio_column {
key="SortX" ;
label="水平方向[X]" ;
: radio_button {
key="Left" ;
label="左" ;
}
: radio_button {
key="Center" ;
label="中" ;
}
: radio_button {
key="Right" ;
label="右" ;
}
}
: boxed_radio_column {
key="SortY" ;
label="垂直方向[Y]" ;
: radio_button {
key="Upper" ;
label="上" ;
}
: radio_button {
key="Middle" ;
label="中" ;
}
: radio_button {
key="Lower" ;
label="下" ;
}
}
}
ok_cancel;
errtile;
}

(Defun vldcl-init (DCLFile DCLName) 
  (cond        ((= (type DCLFile) 'STR) 
         (if (setq *DCLID* (findfile DCLFile)) 
           (progn 
             (setq *DCLID* (load_dialog DCLFile)) 
             (new_dialog DCLName *DCLID*) 
           ) 
         ) 
        ) 
        ((null DCLFile) 
         (if *DCLID* 
           (unload_dialog *DCLID*) 
         ) 
         (setq *DCLID* nil) 
        ) 
        (t (setq *DCLID* nil)) 
  ) 
  *DCLID* 
) 
(Defun vldcl-update (id val / data) 
;;; update *DCL-DATA* 
  (if (setq data (cdr (assoc id *DCL-DATA*))) 
    (setq data             (subst (cons 1 val) (assoc 1 data) data) 
          *DCL-DATA* (subst (cons id data) (assoc id *DCL-DATA*) *DCL-DATA*) 
    ) 
  ) 
) 
(Defun vldcl-update2 (key val) 
;;; UPdate *DCL-DONEDIALOG* 
  (if (null (cdr (assoc val *DCL-DONEDIALOG*))) 
    (setq *DCL-DONEDIALOG* (cons (cons val key) *DCL-DONEDIALOG*)) 
    (setq *DCL-DONEDIALOG* 
           (subst (cons val key) 
                  (assoc val *DCL-DONEDIALOG*) 
                  *DCL-DONEDIALOG* 
           ) 
    ) 
  ) 
  (action_tile key (strcat "(done_dialog " (itoa val) ")")) 
) 
(Defun vldcl-getvalue (key / rtn) 
  (setq rtn (cdr (assoc 1 (cdr (assoc key *DCL-DATA*))))) 
  (if (/= (type rtn) 'STR) 
    (setq rtn "") 
  ) 
  rtn 
) 
(Defun vldcl-samestrlen        (str proto char / ipro ist rtn) 
  (setq        istr (strlen str) 
        ipro (strlen proto) 
        rtn  str 
  ) 
  (if (> istr ipro) 
    (setq rtn (substr str 1 ipro)) 
    (repeat (- ipro istr) 
      (setq rtn (strcat rtn char)) 
    ) 
  ) 
  rtn 
) 
(Defun vldcl-settile (/ data key ktype kval kpval item) 
  (foreach data        *DCL-DATA* 
    (setq key        (car data) 
          data        (cdr data) 
          ktype        (cdr (assoc 0 data)) 
          kval        (cdr (assoc 1 data)) 
          kpval        (cdr (assoc 2 data)) 
    ) 
    (cond 
      ((= ktype "edit_box") 
       (cond 
         ((= kpval ":INT") 
          (vldcl-editbox-int key kval) 
          (action_tile key "(vldcl-editbox-int $key $value)") 
         ) 
         ((= kpval ":REAL") 
          (vldcl-editbox-real key kval) 
          (action_tile key "(vldcl-editbox-real $key $value)") 
         ) 
         (vldcl-editbox-string key kval) 
         (t (action_tile key "(vldcl-editbox-string $key $value)")) 
       ) 
      ) 
      ((= ktype "toggle") 
       (vldcl-toggle key kval) 
       (action_tile key "(vldcl-toggle $key $value)") 
      ) 
      ((= ktype "button") 
       (if (> kval 1) 
         (vldcl-update2 key kval) 
       ) 
       (if (< kval 0) 
         (action_tile key kpval) 
       ) 
       (if (> kval 1) 
         (progn 
           (setq done (list kval key kpval)) 
           (if (null (cdr (assoc kval *DCL-DONEDIALOG*))) 
             (setq *DCL-DONEDIALOG* 
                    (cons done 
                          *DCL-DONEDIALOG* 
                    ) 
             ) 
             (setq *DCL-DONEDIALOG* 
                    (subst 
                      done 
                      (assoc kval *DCL-DONEDIALOG*) 
                      *DCL-DONEDIALOG* 
                    ) 
             ) 
           ) 
         ) 
       ) 
      ) 
      ((= ktype "radio_button") 
       (vldcl-radio key kval) 
       (foreach        item kpval 
         (action_tile 
           item 
           (strcat "(vldcl-radio \042" key "\042 $key)") 
         ) 
       ) 
      ) 
    ) 
  ) 
) 
(Defun vldcl-list (key data index) 
  (start_list key) 
  (mapcar 'add_list data) 
  (end_list) 
  (set_tile key index) 
) 
(Defun vldcl-button (key / func) 
  (if (eval (read (setq func (strcat "action_" key)))) 
    (eval (read (strcat "(" func ")"))) 
  ) 
) 
(Defun vldcl-radio (key val / gray keyx mode item func) 
  (set_tile key val) 
  (vldcl-update key val) 
  (if (setq gray (cdr (assoc 3 (cdr (assoc key *DCL-DATA*))))) 
    (progn 
      (setq keyx (nth 0 gray) 
            gray (nth 1 gray) 
      ) 
      (if (member val keyx) 
        (setq mode 1) 
        (setq mode 0) 
      ) 
      (foreach item gray 
        (mode_tile item mode) 
      ) 
    ) 
  ) 
  (if (eval (read (setq func (strcat "action_" val)))) 
    (eval (read (strcat "(" func ")"))) 
  ) 
) 
(Defun vldcl-toggle (key val / keyx func) 
  (set_tile key val) 
  (vldcl-update key val) 
  (foreach keyx        (cdr (assoc 3 (cdr (assoc key *DCL-DATA*)))) 
    (mode_tile keyx (abs (1- (read val)))) 
  ) 
  (if (eval (read (setq func (strcat "action_" key)))) 
    (eval (read (strcat "(" func ")"))) 
  ) 
) 
(Defun vldcl-editbox-int (key val1 / val0 func) 
  (setq        val0 (vldcl-getvalue key) 
        val1 (get_tile key) 
  ) 
  (if (/= (itoa (read val1)) val1) 
    (set_tile key val0) 
    (vldcl-update key val1) 
  ) 
  (if (eval (read (setq func (strcat "action_" key)))) 
    (eval (read (strcat "(" func ")"))) 
  ) 
) 
(Defun vldcl-editbox-real (key val1 / val0 func) 
  (setq        val0 (vldcl-getvalue key) 
        val1 (get_tile key) 
  ) 
  (if (null (numberp (read val1))) 
    (set_tile key val0) 
    (vldcl-update key val1) 
  ) 
  (if (eval (read (setq func (strcat "action_" key)))) 
    (eval (read (strcat "(" func ")"))) 
  ) 
) 
(Defun vldcl-editbox-string (key val / func) 
  (vldcl-update key val) 
  (if (eval (read (setq func (strcat "action_" key)))) 
    (eval (read (strcat "(" func ")"))) 
  ) 
) 
(Defun vldcl-graytile (keys val / key) 
  (foreach key keys 
    (mode_tile key val) 
  ) 
) 
(Defun vldcl-actiontile        (/ id done key) 
  (foreach done        *DCL-DONEDIALOG* 
    (setq id  (nth 0 done) 
          key (nth 1 done) 
    ) 
    (action_tile key (strcat "(done_dialog " (itoa id) ")")) 
  ) 
) 
(Defun vldcl-donedialog        (/ key) 
  (if (setq key (cdr (assoc *DCLRTN* *DCL-DONEDIALOG*))) 
    (if        (eval (read (setq key (nth 1 key)))) 
      (eval (read key)) 
    ) 
  ) 
) 
 
 
(Defun c:xx (/                     *DCLID*             *DCL-DATA* 
             *DCL-DONEDIALOG*                     *DCLRTN* 
             action_pickx    action_picky 
            ) 
  (defun action_pickx () 
    (getstring "\n Close dialog to enter string:") 
  ) 
  (defun action_picky () 
    (alert "SDfsdg") 
  ) 
 
  (setq        *DCL-DATA* 
         (list 
           (cons "DistX" 
                 (list (cons 0 "edit_box") (cons 1 "0.0") (cons 2 ":REAL")) 
           ) 
           (cons "DistY" 
                 (list (cons 0 "edit_box") (cons 1 "0.0") (cons 2 ":REAL")) 
           ) 
           (cons "ToggleAttribute" 
                 (list (cons 0 "toggle") (cons 1 "1")) 
           ) 
           (cons "ToggleDefault" 
                 (list (cons 0 "toggle") 
                       (cons 1 "1") 
                       (cons 3 (list "help")) 
                 ) 
           ) 
           (cons "ToggleRow2Col" 
                 (list (cons 0 "toggle") 
                       (cons 1 "1") 
                       (cons 3 (list "help")) 
;;; Gray tiles 
                 ) 
           ) 
           (cons 
             "RadioX" 
             (list (cons 0 "radio_button") 
                   (cons 1 "AutoX") 
                   (cons 2 (list "AutoX" "UserX" "IgnoreX" "PickX")) 
                   (cons 3 
                         (list (list "AutoX" "IgnoreX") (list "DistX" "PickX")) 
                   ) 
;;; Gray tiles 
             ) 
           ) 
           (cons 
             "RadioY" 
             (list (cons 0 "radio_button") 
                   (cons 1 "AutoY") 
                   (cons 2 (list "AutoY" "UserY" "IgnoreY" "PickY")) 
                   (cons 3 
                         (list (list "AutoY" "IgnoreY") (list "DistY" "PickY")) 
                   ) 
;;; Gray tiles 
             ) 
           ) 
           (cons "PickX" 
                 (list (cons 0 "button") 
                       (cons 1 2) 
                       (cons 2 "(action_pickx)") 
                 ) 
           ) 
           (cons "PickY" 
                 (list (cons 0 "button") 
                       (cons 1 -1) 
                       (cons 2 "(action_picky)") 
                 ) 
           ) 
 
         ) 
        *DCLRTN* 10 
  ) 
  (while (> *DCLRTN* 0) 
    (vldcl-init "g:/test.dcl" "Main") 
    (vldcl-settile) 
    (vldcl-actiontile) 
    (setq *DCLRTN* (start_dialog)) 
    (vldcl-donedialog) 
    (alert "end") 
    (vldcl-init nil nil) 
  ) 
;;;(get data from *DCL-DATA* and run orther operations/functions 
) 
(c:xx) 
 
 
;| DCL files 
dcl_settings : default_dcl_settings { audit_level=0; } 
Main : dialog { 
      label="[KozMos OASis-XLS/VTM]: 设定" ; 
      : boxed_row {         
         label="虚拟表格文本行列分隔设定" ; 
         : boxed_radio_column { 
            key="RadioX" ; 
            label="X方向[列]" ; 
            : radio_button { 
               key="AutoX" ; 
               label="自动检测" ; 
            } 
            : radio_button { 
               key="IgnoreX" ; 
               label="忽略列分隔" ; 
            } 
            : radio_button { 
               key="UserX" ; 
               label="用户指定" ; 
            } 
            : button { 
               key="PickX" ; 
               label="点取距离 <" ; 
            } 
            : edit_box { 
               key="DistX" ; 
               label="X:" ; 
            } 
         } 
         : boxed_radio_column { 
            key="RadioY" ; 
            label="Y方向[行]" ; 
            : radio_button { 
               key="AutoY" ; 
               label="自动检测" ; 
            } 
            : radio_button { 
               key="IgnoreY" ; 
               label="忽略行分隔" ; 
            } 
            : radio_button { 
               key="UserY" ; 
               label="用户指定" ; 
            } 
            : button { 
               key="PickY" ; 
               label="点取距离 <" ; 
            } 
            : edit_box { 
               key="DistY" ; 
               label="Y:" ; 
            } 
         } 
      } 
      : row { 
         : boxed_column { 
            label="虚拟表格文本高级设定" ; 
            : toggle { 
               key="ToggleAttribute" ; 
               label="允许编辑块内属性" ; 
            } 
            : toggle { 
               key="ToggleDefault" ; 
               label="保存当前设定为缺省" ; 
            } 
            : toggle { 
               key="ToggleRow2Col" ; 
               label="转化单行为单列" ; 
            } 
            : button { 
               key="SortPoint" ; 
               label="分隔定位点..." ; 
            } 
         } 
         : boxed_column { 
            label="操作命令"; 
            : button { 
               key="help" ; 
               label="帮助..." ; 
            } 
            : button { 
               key="accept" ; 
               label="选择实体 <" ; 
               is_default=true ; 
            } 
            : button { 
               key="cancel" ; 
               label="取消" ; 
               is_cancel=true ; 
            } 
         } 
      }       
      errtile ; 
   } 
Sort : dialog { 
   label="[KozMos OASis-XLS/VTM]: 文本定位点" ; 
   : image { 
      color=white ; 
      key="Image" ; 
      width=15 ; 
      height=6 ; 
   } 
   : text { 
      label="蓝色矩形框表示文本范围框"; 
   } 
   : boxed_row { 
      label="计算文本分隔使用定位点" ; 
      : boxed_radio_column { 
         key="SortX" ; 
         label="水平方向[X]" ; 
         : radio_button { 
            key="Left" ; 
            label="左" ; 
         } 
         : radio_button { 
            key="Center" ; 
            label="中" ; 
         } 
         : radio_button { 
            key="Right" ; 
            label="右" ; 
         } 
      } 
      : boxed_radio_column { 
         key="SortY" ; 
         label="垂直方向[Y]" ; 
         : radio_button { 
            key="Upper" ; 
            label="上" ; 
         } 
         : radio_button { 
            key="Middle" ; 
            label="中" ; 
         } 
         : radio_button { 
            key="Lower" ; 
            label="下" ; 
         } 
      } 
   } 
   ok_cancel; 
   errtile; 
}

陌生人 · 发表于 2004-1-18 21:02:21

好文居然没人顶？
支持一下。
以后慢慢消化，3q

cy956 · 发表于 2004-1-18 21:15:46

通用对话框？下了再看。

账号		自动登录	找回密码
密码			立即注册

[其他]：简化对话框的编制工作

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

相关帖子

浏览过的版块