[讨论]：关于无名块的疑问，请大家指点

walong · 发表于 2004-2-13 17:47:41

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

关于无名块的疑问，请大家指点
(defun mc-make-unname-block(ss / count entlist ent blk)
  (entmake '((0 . "BLOCK")
   (2 . "*U")
   (70 . 1)
   (10 0 0 0)
   ))
  (setq count 0)
  (repeat (sslength ss)
(setq entlist(entget(setq ent(ssname ss  count))))
(setq count (1+ count))
(entmake entlist)
)
  (setq count 0)
  (repeat(sslength ss)
(setq ent(ssname ss count))
(setq count (1+ count))
(entdel ent)
)
  (setq blk(entmake '((0 . "ENDBLK"))))
  (if (princ blk)
  (entmake (list (cons 0  "INSERT")
   (cons 2 blk)
   (cons 10 '(0 0 0))
   ))
)
  blk
  )

上面的代码是明经站里的一个生成无名块的函数，

我想知道无块通常在什么场合下应用，在做粗糙度时有人用到无名块，我不明白这样做有什么好处，我用点坐标来制作粗糙度又会有什么区别？

另外还请高人，帮我分析上面的代码，我有些看不明白，别笑话我！

aeo · 发表于 2004-2-14 22:32:03

无名块就是块，就是名字是*U打头的而已.

一般无名块是cad内部使用的,cad偷偷的进行，你就不要考虑他了.
比如一个标注的两头就是的,你可以炸开看一下.
而一般块是你建立才会有.

无名块和一般的块建立的方法是一样的(lisp),上面的就是.
你掌握好的，就能象一般的块一样运用了.(场合:要用块的地方就行)

walong · 发表于 2004-2-14 22:40:30

不过上面代码我是抄来的，并不理解，也不会应用，还请各位释意!

陌生人 · 发表于 2004-2-15 00:30:07

[php]
(defun mc-make-unname-block (ss / count entlist ent blk)
  ;构造实体表头.
  (entmake '((0 . "BLOCK");'"实体名".
      (2 . "*U");"无名块名称".
      (70 . 1);"无名块标志".
      (10 0 0 0);"插入点.可用(getpoint)另外定义."
      )
  )
  ;"将选集ss的实体放入块定义".
  (setq count 0);"付计数初始值."
  (repeat (sslength ss)
(setq entlist (entget (setq ent (ssname ss count))));"取单个实体的实体表."
(setq count (1+ count));"计数加1".
(entmake entlist);"按实体表生成实体.因为有(entmake ....)表头,
;这些实体将作为块内定义存在.不在图上出现.但可以用insert命
;令"复制"一份到图纸上."
  )
  ;"删除用于块定义的实体."
  (setq count 0)
  (repeat (sslength ss)
(setq ent (ssname ss count))
(setq count (1+ count))
(entdel ent);"entdel一次只能删除一个实体."
  )
  ;"块定义尾.以实体名"ENDBLK"结束."
  (setq blk (entmake '((0 . "ENDBLK"))))
  ;'"原位插入块."
  (if (princ blk);如果造块成功.
(entmake (list (cons 0 "INSERT")  ;"生成块实体(和块定义是不同的)."
   (cons 2 blk)    ;"组码2引用块定义."
   (cons 10 '(0 0 0)) ;'"块插入点."
      )
)
  )
  blk  ;"返回块名".
)[/php]

[color=blue]
;;重写造无名块－－－－－from mj 修改by 陌生人2004.2
(defun c:*blk ()
(princ "\n选择做无名块的实体:")
(make*blk (ssget)(getpoint "\n定义插入点:"))
(princ)
)
(defun make*blk (ss pt / i ent blk)
(entmake (list'(0 . "BLOCK")'(2 . "*U")'(70 . 1)(cons 10 pt)))
(setq i -1)
(repeat (sslength ss)
(setq ent (ssname ss (setq i (1+ i))))
(entmake (entget ent))
(entdel ent)
)
(setq blk (entmake '((0 . "ENDBLK"))))
(if blk
(entmake (list '(0 . "INSERT") (cons 2 blk) (cons 10 pt)))
)
(princ "\n已经做成无名块:")(princ blk)
)[/color]

walong · 发表于 2004-2-15 11:25:43

陌生人真是热情，回答很详细。
我问句，还请指教：
在做粗糙度时有人用到无名块，我不明白这样做有什么好处，我用点坐标来制作粗糙度又会有什么区别？

XDSoft · 发表于 2004-2-15 11:34:14

最初由 walong 发布
[B]陌生人真是热情，回答很详细。
我问句，还请指教：
在做粗糙度时有人用到无名块，我不明白这样做有什么好处，我用点坐标来制作粗糙度又会有什么区别？ [/B]

不管是什么，无名块的作用是：

1、是块，因此可以定义一次而多次引用（插入）。图中需要大量重复引用（插入）的时候，节省图的文件大小。具有块的所有特征。

2、制作无名块的时候，不用自己命名，系统自动命名，不会有重名的可能（普通块如果重名，那么旧的块定义就会被重新定义了），无名块定义如果图中没有引用它的“实体（INSERT）”存在，那么在清理图形的时候（PURGE），无名块定义（BLOCK）会自动清理掉。

ywx0576 · 发表于 2004-2-15 13:08:28

无名块不能用DDINSERT来插入，也不能用REFEDIT来编辑。
想把无名块转成普通块，可以用上述二个命令操作，不知各位有没有办法？

walong · 发表于 2004-2-15 13:18:51

感谢各位的指点，我对无名块有了更深的了解了！谢谢！

LUCAS · 发表于 2004-2-17 08:09:04

最初由 ywx0576 发布
[B]无名块不能用DDINSERT来插入，也不能用REFEDIT来编辑。
想把无名块转成普通块，可以用上述二个命令操作，不知各位有没有办法？ [/B]

;;BY LUCAS(龍龍仔)
;;把匿名塊改回普通圖塊
;;但程序有一重大缺點....
;;改了名的圖塊與新定義的圖塊名稱一樣,但並不是同一圖塊!!
(defun C:TT (/ BLOCKS DOC SB BNAME ENT BLK BLKREF)
(vl-load-com)
(while
(or (not
(setq BLK (car (entsel "\n選擇要改回普通圖塊的匿名塊: ")))
)
(progn
(setq BLKREF (vlax-ename->vla-object BLK))
(not (= (vla-get-objectname BLKREF) "AcDbBlockReference"))
)
(/= "*" (substr (vla-get-name BLKREF) 1 1))
)
)
(setq BLOCKS
(vla-get-blocks
(setq DOC (vla-get-activedocument (vlax-get-acad-object)))
)
)
(setq BNAME (getstring "\n圖塊名稱: "))
(if (vl-catch-all-error-p
(vl-catch-all-apply 'vla-item (list BLOCKS BNAME))
)
(progn
(setq SB (vla-item BLOCKS (vla-get-name BLKREF)))
(vla-put-name (vla-item BLOCKS (vla-get-name BLKREF)) BNAME)
(setq BLK (vla-add BLOCKS (vla-get-origin SB) BNAME))
(vlax-for ENT SB
(vla-copyobjects
DOC
(vlax-safearray-fill
(vlax-make-safearray
vlax-vbobject
'(0 . 0)
)
(list ENT)
)
BLK
)
)
(vlax-release-object SB)
(vlax-release-object BLK)
)
(alert (strcat "\n "" BNAME """ "圖塊已存在!! "))
)
(vlax-release-object BLKREF)
(vlax-release-object BLOCKS)
(vlax-release-object DOC)
(princ)
)

;;BY LUCAS(龍龍仔) 
;;把匿名塊改回普通圖塊 
;;但程序有一重大缺點.... 
;;改了名的圖塊與新定義的圖塊名稱一樣,但並不是同一圖塊!! 
(defun C:TT (/ BLOCKS DOC SB BNAME ENT BLK BLKREF) 
  (vl-load-com) 
  (while 
    (or        (not 
          (setq BLK (car (entsel "\n選擇要改回普通圖塊的匿名塊: "))) 
        ) 
        (progn 
          (setq BLKREF (vlax-ename->vla-object BLK)) 
          (not (= (vla-get-objectname BLKREF) "AcDbBlockReference")) 
        ) 
        (/= "*" (substr (vla-get-name BLKREF) 1 1)) 
    ) 
  ) 
  (setq        BLOCKS 
         (vla-get-blocks 
           (setq DOC (vla-get-activedocument (vlax-get-acad-object))) 
         ) 
  ) 
  (setq BNAME (getstring "\n圖塊名稱: ")) 
  (if (vl-catch-all-error-p 
        (vl-catch-all-apply 'vla-item (list BLOCKS BNAME)) 
      ) 
    (progn 
      (setq SB (vla-item BLOCKS (vla-get-name BLKREF))) 
      (vla-put-name (vla-item BLOCKS (vla-get-name BLKREF)) BNAME) 
      (setq BLK (vla-add BLOCKS (vla-get-origin SB) BNAME)) 
      (vlax-for        ENT SB 
        (vla-copyobjects 
          DOC 
          (vlax-safearray-fill 
            (vlax-make-safearray 
              vlax-vbobject 
              '(0 . 0) 
            ) 
            (list ENT) 
          ) 
          BLK 
        ) 
      ) 
      (vlax-release-object SB) 
      (vlax-release-object BLK) 
    ) 
    (alert (strcat "\n  "" BNAME """ "圖塊已存在!!  ")) 
  ) 
  (vlax-release-object BLKREF) 
  (vlax-release-object BLOCKS) 
  (vlax-release-object DOC) 
  (princ) 
)

aeo · 发表于 2004-2-17 23:03:32

最初由 XDSoft 发布
[B]
....在，那么在清理图形的时候（PURGE），无名块定义（BLOCK）会自动清理掉。 [/B]

purge是普通的也会
是新打开图形时,没引用的无名块自动清除.

LUCAS:[B]
"改了名的圖塊與新定義的圖塊名稱一樣,但並不是同一圖塊"[/B]

图中的insert都成了新名称，那再次打开时，原来的无名块块应该没有了(按规则应该这样，不知事实是不是?)

陌生人 · 发表于 2004-2-18 00:57:30

图中的insert都成了新名称，那再次打开时，原来的无名块块应该没有了(按规则应该这样，不知事实是不是?)

没有引用的才会被自动清除

dingweidong · 发表于 2004-2-18 11:56:07

在AUTOCAD中对于块的含义是比较广泛的，记住即便是一个插入点也是可以被定义成块的！

JOSDENNIS · 发表于 2004-2-21 14:51:09

我也對這不太了解, 我從頭看到尾還是不明白. 有一問題想向各位大俠請教一二. 還望各位多多指點才是. 如:
1. 上面有人說無名塊是自動命名的. 那麼無名塊可以由我去取名嗎? 又是如何做呢?
2 . 當做了一個無名塊后. 以后怎麼找出來用呢? 如找不出來我樣的塊對畫圖有什麼價值呀?

aeo · 发表于 2004-2-21 17:12:43

最初由 LUCAS 发布
[B]
[code]
;;BY LUCAS(龍龍仔)
... [/B]

按你的方法，改名了：
比如图上有两个(实体a b)匿名块，改名是改过来了(比如"*u23 "--> "abc")
ddinsert,插入3个块"abc",(实体d e f)

现在rename(或者vla-put-name)这个"abc"名字-->"xyz"

实体d e f名称变为了"xyz"而实体a b还是"abc"
而块的列表里已经没有"abc"这个名字了.(怪事情呀,不可想象呀
这时的abc成了没定义的块)

而且现在用entmake这个"abc"插入也不行,因为块表里没有,所以没有地方取找它的定义了.

十三楼的:
无名块自己可以定义前面的，而后面cad会自动加一个数字.(保证不重复)
无名块一般都是编程才能插入.

LUCAS · 发表于 2004-2-24 12:40:38

最初由 aeo 发布
[B]

按你的方法，改名了：
比如图上有两个(实体a b)匿名块，改名是改过来了(比如"*u23 "--> "abc")
ddinsert,插入3个块"abc"... [/B]

所以才有下面這句說明
;;改了名的圖塊與新定義的圖塊名稱一樣,但並不是同一圖塊!!

账号		自动登录	找回密码
密码			立即注册

[讨论]：关于无名块的疑问，请大家指点

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

相关帖子