[分享]：动态旋转复制程序

wkai

模仿sketchup的动态旋转复制程序，放在这里保存一份.
[PHP]
(defun zf_dynamic_rotate(/ p1 p2 p3 a1 cn cnn tmp e s)
  ;_____________________________
  (defun rc (os / ns ne)
    (setq ne (entlast)
          ns (ssadd)
    )
    (command "copy" os ""  "0,0"   "0,0")
    (while (setq ne (entnext ne))
      (setq ns (ssadd ne ns))
    )
    ns
  )
  (defun ttt (ss n / m ee ns sn )
    (setq ee e
      ns (ssadd)
    )
    (while (setq ee (entnext ee))
      (setq ns (ssadd ee ns))
    )
    (command "erase" ns "")   
    (if (member (substr n (strlen n)) '("/" "*"))      
      (progn
        (setq m 0)
        (repeat        (atoi n)
          (setq m (1+ m))
          (setq sn(rc ss))
          (cond
            ((= "/" (substr n (strlen n)))
             (command  "rotate" sn "" p1 (* m (/ a1 (atof n))))
            )
            ((= "*" (substr n (strlen n)))
             (command  "rotate" sn "" p1 (* m a1))
            )
          )
        )
      )
      (progn
        (setq sn(rc ss))
      (command  "rotate" sn "" p1 (setq a1 (atof n)))
      )
    )
  )
  ;_____________________________
  (princ "\n动态旋转程序__BY__WKAI__晓东CAD空间论坛")
  (princ "\n选择要旋转的物体:")
  (setq s (ssget))
  (setq p1 (getpoint "\n旋转基点"))
  (setq p2 (getpoint p1 "\n旋转起点"))
  (command "undo" "be" "line"  p1  p2 "")
  (setq e (entlast))
  (setq p3 (getpoint p1 "\n旋转终点"))
  (setq tmp (rc s) )
  (command  "rotate" tmp ""  p1 "r"  p1  p2  p3)
  (setq cn "1*" a1 (* 180 (/ (-(angle p1 p3)(angle p1 p2))pi)))  
  (while cn   
    (ttt s cn)
    (initget 128)
    (princ "\n输入坐标=旋转终点                         输入数值=旋转角度 ")
    (princ "\n输入数值n并以 / 结束=角度内等分n次复制    输入数值n并以 * 结束=按角度复制n次 ")
    (setq cnn (getpoint "\n请按提示输入<退出>:"))
    (if        (= 'LIST (type cnn))
      (setq p3 cnn
            a1 (* 180 (/ (-(angle p1 p3)(angle p1 p2))pi))
      )
      (setq cn cnn)
    )
  )
  (entdel e)
  (command "undo" "e")
  (princ)
)
[/PHP]

JOSDENNIS

好程序.

czad

不错，启动命令是什么啊？

heliangdong

为什么不用CAD的扣子（夹点）命令呢，不是很好用吗？

pcgprz

ＯＫ！

xdcad9819

命令: _appload 已成功加载 动态旋转复制zf_dynamic_rotate.lsp。 命令: 命令: 命令: zf_dynamic_rotate 未知命令“ZF_DYNAMIC_ROTATE”。按 F1 查看帮助