[测试]：旧话重提：利用无名块加密图纸

ll_j

以前贴过一个“加密测试”的帖子，程序中在使用中会出错，最近偶然翻出来，又修改了一下，贴出来，大家看看。
[php];;;加密测试 by LL_J v0.91 for XDCAD

(defun c:lk (/ ss i entlist ent ent1 blk)
  (command "color" "")
  (if (= (getvar "tilemode") 0)
    (setq ss (ssget "X" '((67 . 1)                            ;图纸空间
                          (-4 . "<NOT") (0 . "VIEWPORT") (-4 . "NOT>")
                         )
             )
    )
    (setq ss (ssget "X" '((-4 . "<AND") (-4 . "<NOT") (67 . 1) (-4 . "NOT>")    ;模型空间
                                        (-4 . "<NOT") (0 . "VIEWPORT") (-4 . "NOT>")
                          (-4 . "AND>")
                         )
             )
    )
  )
  (entmake
    (list '(0 . "BLOCK") '(70 . 1) '(10 0 0 0) (cons 2 "*U"))       ;无名块开始
  )
  (setq i 0)
  (repeat (sslength ss)
    (setq entlist (entget (setq ent (ssname ss i)))
          i (1+ i)
    )
    (if (entnext ent)
      (if (or (= (cdr (assoc 0 (entget (entnext ent)))) "ATTRIB")     ;属性块
              (= (cdr (assoc 0 (entget (entnext ent)))) "VERTEX")    ;Polyline
          )
        (progn
          (setq ent1 ent)
          (while (/= (cdr (assoc 0 (entget ent1))) "SEQEND")
            (entmake (entget ent1))
            (setq ent1 (entnext ent1))
          )
          (entmake (entget ent1))
        )
        (entmake entlist)
      )
      (entmake entlist)
    )
    (entdel ent)
  )
  (setq blk (entmake '((0 . "ENDBLK"))))               ;无名块结束
  (if blk
    (entmakex                                        ;加密？
      (list '(0 . "INSERT")
            (cons 2 blk)
            '(100 . "AcDbMinsertBlock")
            '(10 0.0 0.0 0.0)
            '(41 . 1.0)
            '(42 . 1.0)
            '(43 . 1.0)
            '(50 . 0.0)
            '(70 . 1)
            '(71 . 2)
            '(44 . 0.0)
            '(45 . 0.0)
      )
    )
  )
  (princ)
)[/php]
[php];;你看到的是解密程序
(defun c:unlk (/ en ent)
  (setq en (entsel "\nSelect Object to Unlock:"))
  (if en
    (if        (= (cdr (assoc 0 (setq ent (cdr (entget (setq en (car en)))))))
           "INSERT"
        )
      (progn
        (setq ent (entmakex
                    (list '(0 . "INSERT")
                          (assoc 2 ent)
                          (assoc 10 ent)
                    )
                  )
        )
        (command "_.explode" (entlast))
        (entdel en)
      )
    )
  )
  (princ)
)
[/php]

附件是加密后的图形文件。
请那位能看到附件的斑竹，将帖子编辑一下（或跟一帖），将附件贴出，论坛使用隐藏功能后，附件隐藏了，我这里无法跟贴。

6月30日取消隐藏。

netbee

应一楼，转帖他的加密测试－－－加密后的图形文件
=============
这个程序很好！对于那些只知道索取的人是很有用的！因为他们大部都没有多少心思来提高自己的业务水平的。

aeo

最初由 ll_j 发布
[B]以前贴过一个“加密测试”的帖子，程序中在使用中会出错，最近偶然翻出来，又修改了一下，贴出来，大家看看。
[php];;;加密测试 by LL_J v0.91 for XDCAD

(defun c:lk (/ ss i entlist ent ent1 blk)
  (comman... [/B]

很早就有了的.
好像mmmm的站上有.

问题1. 如果图中有"attdef" ,那插块时没那么简单

问题2. 解密的时候，如果图给转过了。
      同时上面的问题，带入这里  的问题.

ll_j

02年9月我在本板块贴过此帖，当时没有解决属性块的问题，现在将属性块、实体跟随都考虑了。但图中碰到有属性（attdef），加密时就“隐藏”了，解密时会显示出来，考虑attdef一般是以块中的defrib出现，所以没有处理，附图中就包括属性块和一个炸开的属性块（attdef）。
由于属性块现在是直接搬进无名块的，所以插入没有问题。
在解密时没有考虑太复杂，只考虑了最可能的“误”移动，考虑旋转并不复杂，另外还有不等比例问题，因为“加密”是自己，“解密”也是自己。

lhj743

我使用了！
输入lk命令，
一闪便没了！
图形被整个加密成了一块！
连自己也无法用了！
请问可以解密吗？
方法是什么？
顺便说一下，定义好的块依然存在，还可插入！

大尾巴狼

请问能解密吗？怎样解？
谢谢

ll_j

帖子“隐藏”的部分就是“解密”程序，也许适当的时候会打开，也许就不打开了，至少大家先试试。“加密”吗，大家都会解了，还有什么意义？
本程序主要唬唬初学者和一些只知索取不知付出的人，程序还在完善中，贴出来主要是看看还有什么情况需要考虑。

jiangzq

怎样解密，急急

shisj

光加密，是不是会弄得连自己也打不开？

雪山飞狐(lzh)

用MInsert加密好像没有什么意义吧

eachy

我发过一个块<->多重块互转程序，已经沉底了。

陌生人

单向的加密才算真正的加密。
给图给别人，难道还希望人家有机会破解么？

XDSoft

最初由 陌生人 发布
[B]单向的加密才算真正的加密。
给图给别人，难道还希望人家有机会破解么？ [/B]

密码学理论：只有能解密的，才能叫做“加密”，否则叫“破坏”。

理论还说，只要能加密，就能够解密。加密和解密是矛盾的统一体。

shisj

隐藏的东西怎么看不见，还有其他什么要求啊，我想知道怎么解密啊，我把自己的东西加密了，解不开了

雪山飞狐(lzh)

多重引用加密确实没什么意义，太简单了，这里有一个炸开多重引用的代码
http://www.xdcad.net/forum/showthread.php?s=&threadid=199414
有没有好一点的加密算法？