[讨论]：CAD2004打印：有没有这样的LISP

逐月飞鸿

在打印CAD2004的图形的时候，感到它比R14要繁琐，是CAD2004在打印方面退化了吗？还是我不得要领呢？请指点？
我在工具--->选项--->打印中将“\\407\hp407”打印机用作默认的打印设备，新图形的默认打印样式：使用颜色相关打印样式cad.ctb。                                                       可是我每次打开一个没有在我的电脑打印过的cad图形的时候，我都得在plot的对话框的"页面设置名"的对话框中,选择<上一次打印>.或进行一次页面设置，否则，在plot的对话框里的打印设备就是“无”，打印样式也是“无”，图纸尺寸显示“ANSI A .50x11.00英寸)，请问是为什么呢？这些默认的打印设置能否更改呢？按说应该按选项的设置来显示啊？？！
       能否写个LISP，在每个图形打开的时候自动完成页面的相同设置呢（不管原来的页面设置如何）？就是打印机：\\407\hp407，打印样式：acad.ctb呢？请高手指点，是不是还有其他的办法呢？郁闷并在等待中。

sunny_258

勾上  将修改保存到布局

逐月飞鸿

勾上 将修改保存到布局 ，不行吧？要是别人的图纸我打印的时候，不是还的修改吗？因为别人的设置不一定和我的一样啊！你说是不是？

aidraft

Just an example....
(defun CH_PRINTER  (/ layout oripoint layoutsel acadobject acaddocument)
  (setq acadobject   (vlax-get-acad-object)
        acaddocument (vla-get-activedocument acadobject)
        )
  (setq layoutsel (vla-get-layouts acaddocument))
  (if (not (setq layout (objsel layoutsel "Paper")))
    (EXIT)
    )
  (vla-refreshplotdeviceinfo layout)
  (if (/= (vla-get-configname layout)
          "\\\\ccicaudirs1\\Level 3 LaserJet LJ5000 Series PS"
          )
    (progn
      (alert
        "Current plotter configuration name is not \"Level 3 LaserJet LJ5000 Series PS\", press ENTER to change..."
        )
      (vla-put-configname
        layout
        "\\\\ccicaudirs1\\Level 3 LaserJet LJ5000 Series PS"
        )
      ) ;progn
    ) ;end-if
  (vla-put-CanonicalMediaName layout "A3")
  (vla-put-paperunits layout acMillimeters)
  (if (vl-string-search "TW" (getvar "DWGNAME"))
    (vla-put-PlotRotation layout ac0Degrees)
    (vla-put-PlotRotation layout ac90Degrees)
    ) ;endif
  (vla-put-centerplot layout :vlax-false)
  (setq Oripoint (vlax-make-safearray vlax-vbDouble '(0 . 1)))
  (vlax-safearray-fill Oripoint '(0 0))
  (vla-put-PlotOrigin layout Oripoint)
  (vla-put-plottype layout acExtents)
  (vla-put-PlotviewportBorders layout :vlax-false)
  (vla-put-PlotviewportsFirst layout :vlax-true)
  (vla-put-PlotWithLineweights layout :vlax-true)
  (vla-put-PlotWithPlotstyles layout :vlax-false)
  (vla-put-StandardScale layout 16)
  (vla-put-ScaleLineweights layout :vlax-false)
  (vla-put-StyleSheet layout "ccicplotstyle.ctb")
  (vla-put-UseStandardScale layout :vlax-true)
  (vla-put-TABOrder layout 1)
  (princ)
  )
;;;;
(defun objsel  (cltns objname / temp)
  (vlax-for obj  cltns
    (if (vlax-property-available-p obj 'Name)
      (if (= (vla-get-name obj) objname)
        (setq temp obj)
        )
      )
    )
  (eval temp)
  )

逐月飞鸿

能否解释一下怎么用啊，大虾.企盼谢谢你的回答!

ls爱好者

工具\选项\打印中将你要的样式选好后,下次就不用次次都麻烦你啦...

aidraft

最初由 逐月飞鸿 发布
[B]能否解释一下怎么用啊，大虾.企盼谢谢你的回答! [/B]

Fill your own setting into my codes, then it works for you.

逐月飞鸿

我是说这个lisp怎么加载使用啊，大虾？放在那里啊？请赐教！x
加载后：错误: no function definition: VLAX-GET-ACAD-OBJECT

aidraft

Save the file as ch_printer.lsp, load it.
Then in command line type (CH_PRINTER), enter

逐月飞鸿

加载后：
输入：(CH_PRINTER)
提示：
; 错误: no function definition: VLAX-GET-ACAD-OBJECT

是为？请赐教 。3ks

aidraft

(vl-load-com) first....
BTW, remember to fill your OWN settings into the codes to make it work...

saltxf

看看我这个
(defun c:print()
(command "plot" "y" "" "HP LaserJet 5100 PCL 6.pc3" "A3" "m" "l" "n" "e" "fit" "" "y" "全部细笔.ctb" "y" "a" "n" "y" "n")
)
其中的HP LaserJet 5100 PCL 6.pc3和全部细笔.ctb要先设置好。

aidraft

楼上的应该也可以，但不知能否preview?有时Full Preview之后感觉不对会放弃打印。

aeo

最简单的就12楼的吧。vl方法是比较烦的（我花了很多时间写，最后还是注释掉了，用了command)

把
(command "plot" "y" "" "hp407.pc3" "A3" "m" "l" "n" "e" "fit" "" "y" "cad.ctb" "y" "a" "n" "y" "n")
加入到一个自动加载的文件里.有了不能确定的就用 "" 取代(比如A3)

上面一句话只是设置而已.所以不必担心什么，但要保证要找得到那些设置.比如pc3 和ctb ,图纸尺寸等.

不管是vl方法还是command对图纸尺寸,都不能很好的识别.
(R2002下,2005就没问题,我用的机器:(  ),但从plot对话框出来的就没问题.

黑米

我也遇到这个问题,还是没懂