[分享]：vb方法生成"随机数"

aeo

lisp本身没随机数的函数，(当然可以找到用lisp写的)
但vba不是带的吗!借来用用.
[php]
(defun rnd(rMin rMax)
    (vla-eval (vlax-get-acad-object)
               "ThisDrawing.setVariable \"USERR5\" ,CDbl((Rnd))"
    )
    (+ rMin(* (getvar "userr5")(- rMax rMin)))
)
[/php]
用法: 生成100~200的数 (rnd 100 200)

我这里主要讲的是lisp调用vb的方法.
比如前面eachy写的sendkeys,就是这方法

大家挖掘一下，实现点其他功能，省的再写宏了.

aeo

vba里面不声明就是Variant
setVariable是不支持Variant的（交互信息，这个方法最直接）
搞了很长时间(没到vba里试一下:(  )后来恍然大悟.

写出来，大家不要象我一样不知道原因.

aidraft

Good! Now it's time to take those VB/VBA gurus to lunch :). We need your contribution.

wkai

aeo演示很大的拓展了vlisp的功能，vlisp较之于alisp简直就是打通了任督二脉，变得无所不能了。 呵呵  好。

雪山飞狐(lzh)

偶最近也在研究这个东东，有时候VBA搞不定的就把程序分成几部分，用Lisp串起来
关注一下，：）

oyxx_1023

厉害，能把LISP和VBA贯通起来了。学习ING。。。

aidraft

;;依样画葫芦也能在VLISP中调用vb/vba中功能强大的MsgBox函数，详细用法见VB帮助文件
[php]
;;;(setq ArgLst '("Do you want to continue ?" 50
;;;"MsgBox Demonstration" "DEMO.HLP" 1000))
;;;用法：(MsgBox Arglst)
(defun Msgbox(ArgLst / Msg Style Title Helpfn Ctxt)
  (mapcar 'set (list 'Msg 'Style 'Title 'Helpfn 'Ctxt) ArgLst)
    (vla-eval (vlax-get-acad-object)
              (strcat "ThisDrawing.setVariable \"USERI5\" ,CInt((MsgBox(\""
                      Msg "\""
                      (if Style (strcat "," (itoa Style)) "")
                      (if Title (strcat ",\"" Title "\"") "")
                      (if Helpfn (strcat ",\"" Helpfn "\"") "")
                      (if Ctxt (strcat "," (itoa Ctxt)) "")
                      ")))")
    )
    (getvar "useri5")
)
[/php]
还有strconv，比strcase功能要多，如把每个单词的首个字母大写( (conv设为3)
[php]
(defun StrConv(Str conv)
    (vla-eval (vlax-get-acad-object)
              (strcat "ThisDrawing.setVariable \"USERS5\" ,CStr((StrConv(\"" Str "\", " (itoa Conv) ")))")
    )
    (getvar "users5")
)
[/php]

梦断江南

我也来一个：
[php]
;| (X-vbfun typ vbfun) = 运行简单的vb函数- v1.0 b ----------梦断江南.2004.9
参数: typ ＝ 函数返回值的vb类型.
      vbfun = 简单的vb函数.
返回: 设置于 "USERR5"变量中的值.
实例:(x-vbfun 'variant '(rnd)) ;; 出错.显示设置系统变量出错.!!
     (x-vbfun 'double '(rnd))  ;;->0.533424 :取得随机数.ok
     (x-vbfun 'integer '(msgbox("hello，x-vbfun",3,"test"))) ;;-> 6.0 :显示信息框，参数详vb函数参考.ok.
     (x-vbfun 'single '(msgbox("test1",3))) ;;出错.显示设置系统变量出错.!!
要点: typ 必须于 vbfun 返回值类型相一致!!!
参考: http://www.xdcad.net/forum/showthread.php?s=&threadid=259492
|;
(DEFUN X-vbfun (typ vbfun / typlst)
  (setq typlst '(("BOOLEAN" . "CBOOL")("BYTE" . "CBYTE")("CURRENCY" . "CCUR")("DOUBLE" . "CDBL")("DECIMAL" . "CDEC")
               ("INTEGER" . "CINT")("LONG" . "CLNG")("SINGLE" . "CSNG")("STRING" . "CSTR")("VARIANT" . "CVAR")))
  (vla-eval (vlax-get-acad-object)
            (strcat "thisdrawing.setvariable \"USERR5\" ,"
                    (cdr(assoc (strcase (vl-symbol-name typ)) typlst))
                    "("
                    (vl-prin1-to-string vbfun)
                    ")"
            )
  )
  (getvar "USERR5")
)
[/php]
(x-vbfun 'double '(rnd))  ;;->0.533424 :取得随机数.ok
(x-vbfun 'integer '(msgbox("hello，x-vbfun",3,"test"))) ;;-> 6.0 :显示信息框，参数详vb函数参考.ok.
(x-vbfun 'variant '(Shell("CALC.EXE", 1))) ;;调出计算器并返回cad状态.  ok!

雪山飞狐(lzh)

提醒一点，好像都没有想过把User系列变量还原，？
好像用Users1～5要好些吧？
Msgbox用下面的代替，也可以
(vlax-invoke-method (vlax-create-object "WScript.Shell") "Popup" "why" 7 "Answer This Question:" 1)
实际上WScript.Shell的功能也很强大，：）

雪山飞狐(lzh)

发现一个办法，可以不用传递系统变量了
(setq a (vlax-create-Object "ScriptControl"))
(vlax-put-property a "language" "vbs")
(vla-eval a "Rnd()")

梦断江南

但是每次运行都是一样的“随机数”？

雪山飞狐(lzh)

前面的
(setq a (vla-GetInterfaceObject (vlax-get-acad-object) "ScriptControl"))
(vlax-put-property a "language" "vbs")
只运行一次

你应该只运行
(vla-eval a "Rnd()")
VB的随机数是“伪随机数”，：）

梦断江南

我vb是门外汉，你能否说说为什么叫“伪随机数”?
最重要的是，怎么让它每次运行结果不一样？

雪山飞狐(lzh)

VB的随机数，也是通过一种算法进行运算的，每一次的数的顺序都一样
你可以把
(setq a (vla-GetInterfaceObject (vlax-get-acad-object) "ScriptControl"))
(vlax-put-property a "language" "vbs")

放在启动时加载
调用时运行(vla-eval a "Rnd()")即可

例，在Acad.lsp文件里加入
(setq Tls-VBScript (vlax-create-Object "ScriptControl"))
(vlax-put-property Tls-VBScript "language" "vbs")

(defun Rnd() (vla-eval Tls-VBScript "Rnd()"))

梦断江南

嗯，的确可以了：）
另外，"wscript.shell" 已经有实例。那么"wscript" 对象如何取得？
如果用 (setq a (vla-GetInterfaceObject (vlax-get-acad-object) "ScriptControl"))
(vla-eval a "Rnd()")可以，但是(vla-eval a "Randomize") 却又不行了，why？