[求助]：调用autolisp的问题

gxynd

编写完一个autolisp(其中含有(c:cal))之后，将其拷贝到cad，键入命令，却老是发现"错误: 参数太多"字样,键入“cal”回车，按ESC，再重新键入上边新编制的命令，发现运行正常，如何克服这个问题，是什么原因造成的呢？望兄台相告。

blackspot

检查实参数量，但你说按完ESC后还能运行正常？
顺便说一句，尽量不要用autocad保留变量名（函数名，命令名等）作为自定义函数名

gxynd

我的意思是说要想运行自己编制的autolisp程序，首先要键入cal命令才行，不然程序不予运行，就会出现上述错误，所以还请兄台能够理解不知是不是我的程序问题，现书写如下，望指教

(defun c:hh()
  (setq Ls (getreal "Ls = "))
  (setq R (getreal "R = "))
  (setq c (* Ls R))
  (setq i -1)
  (setq L 1)
  (while (< i Ls)
    (setq i (c:cal "i+L"))
    (setq x (c:cal "i-i^5/(40*c*c)"))
    (setq y (c:cal "i^3/(6*c)-i^7/(336*c^3)"))
    (setq pt (cons (list x y) pt))   
  )
(setq pt1 (reverse pt))
(setvar "cmdecho" 0)
(setvar "osmode" 0)
  (apply 'command (cons ".pline" pt1))
(setq pt1 nil pt nil)
  (command)
  (princ)
)

打开cad，将以上粘贴到cad命令行后，运行hh，就会出现以上错误，而键入cal>>回车>>ESC，再键入hh就可以运行了，如何解决这个问题呢？望回！

LUCAS

(defun C:HH ()
  (arxload "geomcal.arx" nil)
  ;;(vl-arx-import  "geomcal.arx")
  (setq LS (getreal "Ls = "))
  (setq R (getreal "R = "))
  (setq C (* LS R))
  (setq I -1)
  (setq L 1)
  (while (< I LS)
    (setq I (C:CAL "i+L"))
    (setq X (C:CAL "i-i^5/(40*c*c)"))
    (setq Y (C:CAL "i^3/(6*c)-i^7/(336*c^3)"))
    (setq PT (cons (list X Y) PT))
  )
  (setq PT1 (reverse PT))
  (setvar "cmdecho" 0)
  (setvar "osmode" 0)
  (apply 'command (cons ".pline" PT1))
  (setq        PT1 NIL
        PT  NIL
  )
  (command)
  (princ)
)



將 ObjectARX/ADSRX 函數匯入分離名稱空間的 VLX
(vl-arx-import ['function | "application"])

依預設值，分離名稱空間 VLX 應用程式不從 ObjectARX/ADSRX 應用程式匯入任何函數。使用 vl-arx-import 明確地從 ObjectARX/ADSRX 應用程式匯入函數。

引數

函數

要匯入函數名稱的符號。

application

要匯入函數所屬應用程式名稱字串。

如果沒有指定引數 (或 nil)，vl-arx-import會從目前的文件名稱空間匯入全部函數名稱。

傳回值

未指定。
如果從文件 VLX 執行，這個函數不作任何事並傳回 nil，因為所有 ADS-DEFUN 函數名稱全都自動匯入文件 VLS 應用程式。

範例

要知道 vl-arx-import 如何運作，嘗試下列步驟：

1        將下列程式碼複製到 VLISP 編輯器並儲存檔案：

(vl-doc-export 'testarx)
(defun testarx ()
   (princ "This function tests invoking an ARX app ")
   (vl-arx-import 'c:cal)
   (c:cal)

)

2        使用「製作應用程式」以上述程式碼建立一個 VLX。選取「分離名稱空間應用程式」選項。
3        如果尚未載入 geomcal.arx，請將它載入。
4        載入並執行應用程式。

要確認 vl-arx-import 的影響，在程式碼中vl-arx-import 呼叫列左端處加上註解符號「；」，儲存變更，然後重新建構並執行此應用程式。沒有了 vl-arx-import 呼叫，會找不到 c:cal函數。
在以上的範例中，您可以用下列程式置換 vl-arx-import 呼叫：

(vl-arx-import "geomcal.arx")

這會匯入 geomcal.arx 中全部的函數定義，包括 c:cal。

gxynd

太谢谢了，这个问题困了我好久了，我是一个初自学者，碰到很多问题，真是太谢谢了，以后还请多多关照，多多指教。