[编程申请]：递增复制 非完全数字（有字母或字符）

woaining

已有可以递增复制数字的vlx  
工作中发现如果有可以递增复制带字符或字母的功能将更加实用！
如图  数字间有横线 我想实现复制递增 象图中的064683-00-1
复制成06483-00-2   06483-3   06483-4 ..........

如果原始数据是A1  复制递增后可以是A2 A3  A4............

sdwy19691229

递增复制 非完全数字（有字母或字符）
我觉得是很难完成的，毕竟太多字了。如C648300405 ，D648300405，
C648300505， C648300406，
最好是复制，然后改文字。
快速改文字才是关键！

urljit

最初由 sdwy19691229 发布
[B]递增复制 非完全数字（有字母或字符）
我觉得是很难完成的，毕竟太多字了。如C648300405 ，D648300405，
C648300505， C648300406，
最好是复制，然后改文字。
快速改文字才是关键！ [/B]

我觉得不难，主要是没有时间编程，可以提供编程思路：提示用户选择源文字；处理源文字，取出右侧数字部分，转换为数字；生成新的数字值，转换为字符串，合成字符串；提示用户输入新字符串的位置，放置字符串。如果有必要，可以作对话框，要求用户输入步长，循环个数等信息。

柔柔

AutoCAD自己就能做到

柔柔

再来一个
命令tcount

mmmm

http://www.ikozmos.com/htmls/listquickfill2005.htm

zh_6531394

5 楼主是用的什么命令, "tcount"  不对

乐逍遥

最初由 zh_6531394 发布
[B]5 楼主是用的什么命令, "tcount"  不对 [/B]

CAD2005中，tcount可以用。

256497335

看不懂

小菜

tcount以前都不知道这么好的命令

fools

tcount是express tools里的工具，而且是lisp原代码，是一个很好的例子程序

winabcd

楼上的，我用的是2004，我没找到你讲的lisp源代码，如果你有源代码，能不能传上来给大家共享共享，先谢了！

zh_6531394

"tcount是express tools里的工具，而且是lisp原代码，是一个很好的例子程序"
能传上来吗

fools

express tools里的acetext.lsp
[PHP]
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; TCOUNT  TEXT COUNT
(defun c:tcount ( / ss_sort ss start inc startinc flag flt n)

(acet-error-init
(list (list "cmdecho" 0
             "highlight" (getvar "highlight")
             "limcheck" 0
       );list
       T
);list
);acet-error-init

(setq flt '((-4 . "<OR")
             (0 . "TEXT")
             (0 . "MTEXT")
             (0 . "ATTDEF")
            (-4 . "OR>")
           )
);setq

(if (and (setq ss (ssget flt));setq
         (setq ss (car (acet-ss-filter (list ss
                                             '(("LAYERUNLOCKED") ;Dis-allow locked layers, non-current-space
                                               ("CURRENTUCS")    ;and dis-allow objects not in current ucs
                                              )
                                             T
                                       );list
                       );acet-ss-filter
                  );car
         );setq
    );and
    (progn
     (if (not #bns_tcount_sort)
         (setq #bns_tcount_sort "Select-order")
     );if

     (initget "X Y Select-order")
     (setq ss_sort (getkword (acet-str-format
                               "\nSort selected objects by [X/Y/Select-order] <%1>: "
                               #bns_tcount_sort
                             );acet-str-format
                   );getkword
     );setq
     (if (or (not ss_sort)
             (equal ss_sort "")
         );or
         (setq ss_sort #bns_tcount_sort);setq then
         (setq #bns_tcount_sort ss_sort);setq else
     );if
     (if (not #bns_tcount_start)
         (setq #bns_tcount_start 1)
     );if
     (if (not #bns_tcount_inc)
         (setq #bns_tcount_inc 1)
     );if
     (while (not flag)
      (setq flag T)
      (setq startinc (strcat (itoa (fix #bns_tcount_start)) ","
                             (itoa (fix #bns_tcount_inc))
                     );strcat
            startinc (getstring (acet-str-format
                                 "\nSpecify starting number and increment (Start,increment) <%1>: "
                                 startinc
                                );acet-str-format
                     );getstring
      );setq
      (if (equal startinc "")
          (setq startinc (strcat (itoa (fix #bns_tcount_start)) ","
                                 (itoa (fix #bns_tcount_inc))
                         );strcat
          );setq
      );if
      (setq startinc (acet-str-to-list "," startinc))
      (if (or (not (car startinc))
              (not (numberp (read (car startinc))))
              (and (cadr startinc)
                   (not (numberp (read (cadr startinc))))
              );and
          );or
          (progn
           (princ "\nInvalid input.")
           (setq flag nil)
          );progn then
      );if
      (setq start (atoi (car startinc)));setq
      (if (cadr startinc)
          (setq inc (atoi (cadr startinc)));setq then
          (setq inc 1);setq else
      );if
      (if start
          (setq #bns_tcount_start start)
      );if
      (if (or (not inc)
              (equal inc 0)
          );or
          (setq inc #bns_tcount_inc);setq then
      );if
      (if inc
          (setq #bns_tcount_inc inc)
      );if
     );while
     (bns_get_tcountmode_cmd)
     (setq n (bns_tcount
                 ss                  ;the selection set
                 ss_sort             ;the sort type
                 start               ;the start number
                 inc                 ;the increment
                 #bns_tcount_mode    ;placement mode =overwrite/prefix/suffix/find&replace
                 #bns_tcount_replace ;search string for Find&replace option.
             )
     );setq
     (princ (acet-str-format "\n%1 objects modified." (itoa n)))
     (if ss
         (command "_.select" ss "")
     );if
    );progn then
);if

(acet-error-restore)
);defun c:tcount
[/PHP]

zh_6531394

我运行了"Error: no function definition: ACET-ERROR-INIT"
请问原因