[求助]：请教：vba怎样生成exe文件

200142066

第一天学vba,做了一个小程序,由用户输入两点的坐标,画出直线:
Private Sub CmdClear_Click()
Text1_x.Text = ""
Text1_y.Text = ""
Text1_z.Text = ""
Text2_x.Text = ""
Text2_y.Text = ""
Text2_z.Text = ""

End Sub

Private Sub CmdDraw_Click()
Dim sp(2) As Double, ep(2) As Double
sp(0) = Text1_x.Text: sp(1) = Text1_y.Text: sp(2) = Text1_z.Text
ep(0) = Text2_x.Text: ep(1) = Text2_y.Text: ep(2) = Text2_z.Text
Dim L As AcadLine
Set L = ThisDrawing.ModelSpace.AddLine(sp, ep)    '根据“起点”和“终点”画直线
L.color = acRed
ZoomExtents
End Sub

程序可以运行
但我想让它生成.exe文件,而VBA中没有这个选项,我该怎么做?

h_lon

你不知道vba只是傍大款的小蜜，离开了应用程序，她就什么也做不了？
vba=visual basic for application

mikewolf2k

只能用VB

200142066

但是怎样在VB中运行呢?
我将程序拷到vb中,将接口程序加上,还是不行
请大家帮忙

gcgerkaven

转别人的

转换VBA代码到VB中

更新代码示例以用于VB中，你必须首先引用AutoCAD类型库。在VB中，可从工程菜单中选择引用项弹出引用对话框。从引用对话框中，选择AutoCAD Release 15类型库并按确定。

下一步，在代码示例中使用引用活动文档的用户指定变量替换所有引用的ThisDrawing。要做到这一点，可定义AutoCAD应用程序变量(acadApp)和当前文档变量(acadDoc)。然后，设定应用程序变量到当前AutoCAD应用程序。

如果AutoCAD正在运行，用GetObject方法返回AutoCAD应用程序对象。如果AutoCAD没有运行，则会捕获到一个错误发生(对于本例)，然后清除它。接下来用CreateObject方法试图创建AutoCAD应用程序对象。如果成功，则会启动AutoCAD；如果失败，则会弹出一信息框显示出错的内容。以下代码示例使用了Err的Clear和Description属性。如果你的代码环境不支持这些属性，你需要适当修改示例。

从Visual Basic中连接到AutoCAD

Sub Ch2_ConnectToAcad()
Dim acadApp As AcadApplication
On Error Resume Next

Set acadApp = GetObject(, "AutoCAD.Application")
If Err Then
Err.Clear
Set acadApp = CreateObject("AutoCAD.Application")
If Err Then
MsgBox Err.Description
Exit Sub
End If
End If
MsgBox "现在运行 " + acadApp.Name + _
" 版本号 " + acadApp.Version
End Sub

下一步，设定文档变量到AutoCAD应用程序中的文档对象。文档对象是由应用程序对象的ActiveDocument属性返回的。

Dim acadDoc as AcadDocument
Set acadDoc = acadApp.ActiveDocument

通过以上操作，使acadDoc变量引用当前AutoCAD图形。

注意：当运行多个进程的AutoCAD，GetObject函数将返回Windows运行对象表中AutoCAD的第一个实例。请参考Microsoft Visual Basic文档中关于运行对象表(ROT)和GetObject函数部分以取得更多关于检验GetObject返回进程的内容。

VBA相对于VB对照代码示例

以下代码示例示范了通过VBA和VB创建一条直线：

使用VBA创建一条线

Sub Ch2_AddLineVBA()
' 本例在模型空间中添加一条直线
Dim lineObj As AcadLine
Dim startPoint(0 To 2) As Double
Dim endPoint(0 To 2) As Double

' 为直线定义起点和终点
startPoint(0) = 1
startPoint(1) = 1
startPoint(2) = 0
endPoint(0) = 5
endPoint(1) = 5
endPoint(2) = 0

' 在模型空间中创建该直线
Set lineObj = ThisDrawing. _
ModelSpace.AddLine _
(startPoint, endPoint)

' 缩放以显示新创建的直线
ZoomAll
End Sub

使用VB创建一条直线

Sub Ch2_AddLineVB()
On Error Resume Next

' 连接到AutoCAD应用程序
Dim acadApp As AcadApplication
Set acadApp = GetObject _
(, "AutoCAD.Application")
If Err Then
Err.Clear
Set acadApp = CreateObject _
("AutoCAD.Application")
If Err Then
MsgBox Err.Description
Exit Sub
End If
End If

' 连接到AutoCAD图形
Dim acadDoc As AcadDocument
Set acadDoc = acadApp.ActiveDocument

' 确定直线的两个端点
Dim lineObj As AcadLine
Dim startPoint(0 To 2) As Double
Dim endPoint(0 To 2) As Double
startPoint(0) = 1
startPoint(1) = 1
startPoint(2) = 0
endPoint(0) = 5
endPoint(1) = 5
endPoint(2) = 0
' 在模型空间创建一条直线
Set lineObj = acadDoc.ModelSpace.AddLine _
(startPoint, endPoint)
ZoomAll
End Sub