[求助]：请问波浪线怎么画？

jack7115

请问CAD里波浪线怎么画？有波浪线的线性吗？

06\05版本

请部2楼的：有没有什么方法让它画出来是直的啊，这个命令手一动，线就会不直啊。还有啊，如果说有长度要求，我怎么知道会达到我画的长度啊。

明年2006

2006里就有波浪线的

chnytm

波浪线的线型2004也有啊

JJBMW

2002怎么没有啊。

6666298

用直线怎样传换啊/能说明白的点吗
2楼。。。。。。。。。。。

mr cool

不知道你要的是不是图中所示的. 这是用下面这个LSP做的,这个程序是转本论中的其他会员的贴
很值得学习
(defun c:blx (/ boch pt pt1 pt2 pt3 dist lis ang0 ang)
  (SETQ OLDOS (GETVAR "OSMODE"))
  (if (= bofu nil)
    (setq bofu1 20)
  )
  (if (= bochang nil)
    (setq bochang1 50)
  )
  (if (/= (setq oldcmd (getvar "cmdecho")) 0)
    (setvar "cmdecho" 0)
  )
  (prompt "\n请输入波幅<")
  (princ bofu1)
  (if (= (setq bofu (getreal ">:")) nil)
    (setq bofu bofu1)
    (setq bofu1 bofu)
  )
  (prompt "\n请输入波长<")
  (princ bochang1)
  (if (= (setq bochang (getreal ">:")) nil)
    (setq bochang bochang1)
    (setq bochang1 bochang)
  )
  (initget "Yes No")
  (setq id (getkword "\n是否重新计算波长？Yes [No]:"))
  (if (= id nil)
    (setq id "No")
  )
  (if (setq pt1 (getpoint "\n开始画波浪线(回车退出):"))
    (progn
      (while (setq pt2 (getpoint pt1 "\n下一点(回车退出):"))
        (setq dist (distance pt1 pt2))
        (setq ang0 (angle pt1 pt2))
        (setq n (fix (/ dist bochang)))
        (while (= n 0)
          (prompt "\n该段长度比波长小，请重新输入:")
          (setq pt2 (getpoint pt1 "\n下一点(回车退出):"))
          (if (/= pt2 nil)
            (progn
              (setq dist (distance pt1 pt2))
              (setq ang0 (angle pt1 pt2))
              (setq n (fix (/ dist bochang)))
            )
            (setq n nil)
          )
        )
        (if (/= pt2 nil)
          (progn
            (if        (= id "No")
              (setq boch (/ bochang 4))
              (setq boch (/ dist (* n 4)))             
            )
            (setq dist (sqrt (+ (* boch boch) (* bofu bofu))))
            (setq lis (list (atan bofu boch)
                            (- 0 (atan bofu boch))
                            (- 0 (atan bofu boch))
                            (atan bofu boch)
                      )
            )
            (setq pt3 pt1)
            (IF        (< (- OLDOS 16384) 0)
              (SETVAR "OSMODE" (+ OLDOS 16384))
            )
            (command "spline" pt1)
            (repeat n
              (foreach ang lis
                (setq pt (polar pt3 (+ ang0 ang) dist))
                (setq pt3 pt)
                (command pt)
              )
            )
            (command "" "" "")
            (setq pt1 pt)
            (SETVAR "OSMODE" OLDOS)
          )
        )
      )
    )
  )
  (SETVAR "OSMODE" OLDOS)
  (setvar "cmdecho" OLDCMD)
)

jack7115

谢谢楼上的，不错，会自己做了

xyp1964

这个不错！呵呵……
http://www.xdcad.net/forum/showthread.php?s=&threadid=287063

若风

看过高手的方法，,才知道自己的水平是多么菜鸟！

3603131977

通过在线型中加载上波浪线型即可,如果看不出来的话,就调整线型显示比例,然后```````

6666298

你那那个程序怎样用的我用了画不出波浪线
能清楚点吗。。运行左是这个提示，应该怎样输入数据。