（完成）[编程申请]：括号删除，如（M2]20）变成M2]20

lengliqun · 发表于 2005-9-3 12:50:57

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

对以“（”开头，以“）”结尾的字符串，若括号中的第一个字母为M，则将括号删除，如（M2]20）变成M2]20;（M2]22）变成M2]22;（M2]14）变成M2]14，余类推。
（cad2002 默认全选）谢谢。
*-*c *-*c *-*c *-*c *-*c *-*c *-*c *-*c *-*c *-*c *-*c

david96007 · 发表于 2005-9-3 13:28:30

试试!
太马虎了!又改了一下!

(defun c:tt (/ ss l n ent str s e)
(PRINC "\n选择需要修改的文本:")
(setq ss (ssget '((0 . "TEXT")))
l (sslength ss)
n 0
)
(while (< n L)
(setq ent (entget (ssname ss n))
str (cdr (assoc 1 ent))
ll (strlen str)
s (substr str 1 2)
e (substr STR ll)
N (1+ N)
)
(if (and (= s "(M") (= e ")"))
(progn (setq str (substr str 2 (- ll 2))
ent (subst (cons 1 str) (assoc 1 ent) ent)
)
(entmod ent)
)
()
)
)
(princ)
)

lengliqun · 发表于 2005-9-3 13:42:16

谢谢，可你删多了个字母“M”，只删除括号就可以了。

david96007 · 发表于 2005-9-3 15:03:57

太马虎了!已经改了!

eachy · 发表于 2005-9-3 15:33:52

为了缩小范围，一般这样写

(defun c:tt (/ ss)
(if (progn (princ "\nSelect Texe ...")
(setq
ss (ssget
'((0 . "text") (1 . "(M##]##),(M#]#),(M##]#),(M#]##)"))
)
)
)
(progn
.
.
.
)
)
)

如果处理所有含括号的这样写

(ssget '((0 . "text") (1 . "(*)")))

复制代码

lengliqun · 发表于 2005-9-3 15:41:01

可以用了，谢谢。

lengliqun · 发表于 2005-9-3 17:28:25

实际使用中又有要求，1、对以“（”开头，以“）”结尾的字符串，若括号中的第一个字母为M，则将括号删除，如（M2]20）变成M2]20;（M2]22）变成M2]22;（M2]14）变成M2]14，余类推(上面程序已达到要求)；2、对不以“（”开头但含“（M*]*）”的字符串，则变“（”为“＋”，且删其“）”，如XXX（M2]20）变成XXX＋M2]20，KKK（M2]22）变成KKK＋M2]22，余类推。
（cad2002 默认全选）谢谢。

david96007 · 发表于 2005-9-3 20:00:26

谢谢斑竹的指点！！！

(defun c:tt (/ ss l n ent str s e pos)
(PRINC "\n选择需要修改的文本:")
(setq ss (ssget '((0 . "TEXT") (1 . "*(M*)")))
l (sslength ss)
n 0
)
(while (< n L)
(setq ent (entget (ssname ss n))
str (cdr (assoc 1 ent))
ll (strlen str)
s (substr str 1 2)
e (substr STR ll)
N (1+ N)
)
(if (and (= s "(M") (= e ")"))
(progn (setq str (substr str 2 (- ll 2))
ent (subst (cons 1 str) (assoc 1 ent) ent)
)
(entmod ent)
)
(progn (setq pos (vl-string-position (ascii "(") str)
str (strcat (substr str 1 pos)
"+"
(substr str (+ 2 pos) (- ll pos 2))
)
ent (subst (cons 1 str) (assoc 1 ent) ent)
)
(entmod ent)
)
)
)
(princ)
)

(defun c:tt (/ ss l n ent str s e pos) 
  (PRINC "\n选择需要修改的文本:") 
  (setq        ss (ssget '((0 . "TEXT") (1 . "*(M*)"))) 
        l  (sslength ss) 
        n  0 
  ) 
  (while (< n L) 
    (setq ent (entget (ssname ss n)) 
          str (cdr (assoc 1 ent)) 
          ll  (strlen str) 
          s   (substr str 1 2) 
          e   (substr STR ll) 
          N   (1+ N) 
    ) 
    (if        (and (= s "(M") (= e ")")) 
      (progn (setq str (substr str 2 (- ll 2)) 
                   ent (subst (cons 1 str) (assoc 1 ent) ent) 
             ) 
             (entmod ent) 
      ) 
      (progn (setq pos (vl-string-position (ascii "(") str) 
                   str (strcat (substr str 1 pos) 
                               "+" 
                               (substr str (+ 2 pos) (- ll pos 2)) 
                       ) 
                   ent (subst (cons 1 str) (assoc 1 ent) ent) 
             ) 
             (entmod ent) 
      ) 
    ) 
  ) 
  (princ) 
)

梦断江南 · 发表于 2005-9-4 02:00:13

(defun c:tt( / ss i e ent str a)
(PRINC "\n选择需要修改的文本:")
(setq ss (ssget '((0 . "TEXT")(1 . "*(M*)")))
i -1)
(while (setq e (ssname ss (setq i(1+ i))))
(setq ent (entget e)
str (cdr(assoc 1 ent))
a (if (wcmatch str "(M*)") "" "+")
str (vl-string-subst a "("(vl-string-subst "" ")" str))
)
(entmod (subst (cons 1 str)(assoc 1 ent)ent))
)(princ)
)

lengliqun · 发表于 2005-9-5 12:23:31

8楼9楼CAD2002测试可用，谢谢。

账号		自动登录	找回密码
密码			立即注册

（完成）[编程申请]：括号删除，如（M2]20）变成M2]20

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

相关帖子