[求助]：如何用entmod函数在已知的多段线后面追加一个圆弧

tgh56

编程中要求用户点出圆弧的中点和终点,圆弧的起点为已知多段线的最后一个点

eachy

画个arc然后Pedit不简单？

yshf

;请试用以下程序
(defun c:cc()
   (setq db (entget (car (entsel "\n请选择多段线(LWPOLYLINE):")))
         pm (getpoint "\n圆弧的中点:")
         pe (getpoint "\n圆弧的终点:")
         db (reverse (member (assoc 10 (reverse db)) (reverse db)))
         n  (cdr (assoc 90 db))
         pn (cdr (last db))
         pmid (mapcar '* '(0.5 0.5) (mapcar '+ pn pe))
         gxb (/ (distance pm pmid) (/ (distance pn pe) 2.0))
         ang (+ (* (car pn) (cadr pm))
                (* (car pm) (cadr pe))
                (* (car pe) (cadr pn))
                (* -1.0 (car pm) (cadr pn))
                (* -1.0 (car pe) (cadr pm))
                (* -1.0 (car pn) (cadr pe))
             )
   )
   (if (< ang 0.0) (setq gxb (* -1.0 gxb)))
   (setq db (subst (cons 90 (1+ n)) (assoc 90 db) db)
         db (append db (list '(40 . 0.0) '(41 . 0.0)
                              (cons 42 gxb) (cons 10 pe)
                              '(210 0.0 0.0 1.0)
                       )
            )
   )
   (entmod db)         
)

tgh56

谢3楼的兄弟！！
你写的正是我想要的！！