[求助]：找多义线形心

baobin_yu

我有一个找多义线程序，但有时不能用，要找多义线炸开再重新连接才可以，不知道为什么，请各位大侠指教。
(defun c:zxx (/ se rg f xxx xxy xxx1 xxy1 xxx2 xxy2 cep)
  (setvar "CMDECHO" 0)
  (setvar "FILEDIA" 0)
  (setvar "LUPREC" 8)
  (setq se (entsel "\n 请选取欲求形心的多义线："))
  (command "copy" se "" "0,0" "0,0")
  (command "region" se "")
  (setq rg (entget (entlast)))
  (command "massprop" "l" "" "y" "f:/ZZX.mpr")
  (command "erase" "l" "")
  (setq f (open "f:/ZZX.mpr" "r"))
  (read-line f)
  (read-line f)
  (read-line f)
  (read-line f)
  (read-line f)
  (read-line f)
  (read-line f)
  (setq xxx (read-line f))
  (setq xxy (read-line f))
  (close f)
  (setq xxx1 (substr xxx 25 20))
  (setq xxy1 (substr xxy 25 20))
  (setq xxx2 (atof xxx1))
  (setq xxy2 (atof xxy1))
  (setq cep (list xxx2 xxy2 0))
  (entmake (list (cons 0 "point") (cons 8 "temp") (cons 10 cep)))
  (setvar "FILEDIA" 1)
  (setvar "LUPREC" 0)
  (vl-file-delete "f:/ZZX.mpr")
)

yuer0103

我也正想知道如何得到一多义线构成的多边形的重心呢，我等着有人给你好的解答，在下也沾沾光了

xyz2004

将多义线原位复制一个 用region命令或vba 方法生成一个region 获取它的实体名ename, 用下面的函数可获得重心,然后将ename删除即可,这段代码不用偶编了吧?
(setq pt (Get_Cen_pt ename))

(defun Get_Cen_pt (ename / acad-obj acad-doc acad-msp vlname pt)
  (VL-LOAD-COM)
  (setq acad-obj (vlax-get-acad-object))
  (setq acad-doc (vla-get-activedocument acad-obj))
  (setq acad-msp (vla-get-modelspace acad-doc))
  (setq vlname (vlax-ename->vla-object ename))
  (setq pt (vlax-get vlname "centroid"))
  )

baobin_yu

多谢

WHGF

To xyz2004  
为什么要“将多义线原位复制一个.....”，原因何在？

yuer0103

致三楼楼主，为什么要用region把多义线原位复制一个呢，可不可以不用region而直接用几何方法求出？？？？

xyz2004

我所说的复制一个，用完后删除掉是为了不影响原图。我那个找形心程序是有一回做异型柱独立基础，需要找形心，我不想把画好的异型柱都变成region 所以复制一个找到形心后删掉。
    至于说是否可以直接求出形心，当然可以，搜一下论坛好像以前有类似的程序。这也涉及到lisp编程的特殊性，有些要求可以用图形几何的算法求出，也可以用cad的命令功能实现；前者更根本，更具通用性，但需要花费精力去学习；后者相对比较简单，容易掌握，但知其然不知其所以然；这就看你编程的目的和精力了。
像我是搞结构专业的，编程只是为了更方便的画图，所以没有太深入去研究第一种，怎样方便怎样编。所以我觉得先用最方便的方法
编完用上，有时间和兴趣再多学些知识。

WHGF

程序没有试通，问一下象马蹄铁形状的封闭区通求出形心吗？

xyz2004

我把我用的完整程序贴出来 只要是封闭的 能成功生成region实体的图形就可 不一定非得是多义线 马蹄形也可以

(defun c:zxx (/ ename pt ss etype old-os old-la
              )
  (setvar "cmdecho" 0)
  (setq old-os (getvar "osmode")
        old-la (getvar "clayer"))
  (setvar "osmode" 0)
  (while
    (progn
      (setq ss (ssget))
      (/= ss nil)
      );end while if
    (command "undo" "be")
    (command "copy" ss "" '(0 0) "@")
    (command "region" ss "")
    (setq ename (entlast))
    (setq etype (cdr (assoc 0 (entget ename))))
    (if (= etype "REGION")
      (progn
        (setq pt (Get_Cen_pt ename))
        (if (= (tblsearch "layer" "defpoints") nil)
          (command "-layer" "n" "defpoints" ""))
        (setvar "clayer" "defpoints")
        (command "line" pt "@500,0" "")
        (command "line" pt "@0,500" "")
        (entdel ename)
        (command "undo" "e")
        );end if YES
      (progn
        (alert "未成功生成Region实体,请检查")
        (command "undo" "e" "u")
        );end if NO
      );end if
    );end while
  (setvar "osmode" old-os)
  (setvar "clayer" old-la)
  (princ)
  )
(defun Get_Cen_pt (ename / acad-obj acad-doc acad-msp vlname pt)
  (VL-LOAD-COM)
  (setq acad-obj (vlax-get-acad-object))
  (setq acad-doc (vla-get-activedocument acad-obj))
  (setq acad-msp (vla-get-modelspace acad-doc))
  (setq vlname (vlax-ename->vla-object ename))
  (setq pt (vlax-get vlname "centroid"))
  )
;;

xyp1964

试试签名栏下的“中心线”程序。

yuer0103

我查过了，好像没有找到用几何方法直接求出重心的程序。请问是否可请哪位高手帮帮忙，解决解决一下？？？？

xyz2004

我记得平面薄板的重心是在高数中二重积分中讲的吧 你去查一下积分算法看能否实现 只是我奇怪为什么非要数学解呢？ cad的region 功能很不错 由线 弧 曲线 组成的封闭图形都可以生成region  除非你要在其他程序中用 在cad中用region求重心很方便呀 像求面积也是如此 直线多边形还好说 如果加上曲线 及 凹多边形 求起来非常讨厌 生成region 或polyline  得到面积属性就行了 非常简单

xyp1964

vla-get-centroid：取得面域或实体的面积或质量的中点。

ss1025

这个命令我很常用,不过给排水中的立管都是块,没办法用region来生成命域。

xyp1964

最初由 ss1025 发布
[B]这个命令我很常用,不过给排水中的立管都是块,没办法用region来生成命域。 [/B]

2. [FONT=courier new];;;建立面域
   
3. (command "-boundary" "a" "o" "r" "" (getpoint) "") [/FONT]

[FONT=courier new];;;建立面域<br /> (command "-boundary" "a" "o" "r" "" (getpoint) "") [/FONT]