[求助]：图块后加属性可以办到吗？谢谢。

xiaochongcn

如何将图形中已有的没有定义属性的图块，给它们全部加上某一属性值，并且把属性也显示出来。

一般来说属性值是在定义图块的时候一起定义的。但如果当时没有定义属性，而后来需要加上怎么办？目的是让图形中已有的图块都能自动加上属性。

谢谢赐教！

柔柔

最初由 xiaochongcn 发布
[B]目的是让图形中已有的图块都能自动加上属性[/B]

想想看，有实用价值吗？图块加上了属性，已经插入的各个块的属性值不还是要一个一个修改吗？

xiaochongcn

各不相同当然没价值了。
但是当属性值都一样或者大部分都一样的时候了，就有实用价值了。大不了我可以手动修改一小部分属性嘛！
比如一个小区都是5F的楼，这样把5F作为属性值不就很好了吗。况且镜像的时候，属性值还是正常显示。

大家认为有办法吗？
我用在位编辑块加上属性或者炸开块，重新附上属性再同名做块更新都不行。新插入的块正常，但是原有的块则不显示属性。

原地踏步

这是我过去编的一个程序，将无属性的块改为有属性的块，可能对你有点用。具体设置属性用另外的程序，或者将此程序稍做修改，我想比较简单，就不贴了。
;;***************************** ADDATT.LSP *****************************
;;
;;  For AutoCAD R14
;;
;;  本程序为没有属性的图块增加属性.
;;  Invisible : T   Value : ""
;;  default tag : DN
;;
;;======================= The Main Function ============================
;;
(defun c:addatt (/ cde clp ccl omd blp olderr ss ent att opt
                   filst tag blknam ltp lay pt lay scl clr n)
  (setq cde (getvar "cmdecho")
        omd (getvar "osmode")
        clp (getvar "celtype")
        ccl (getvar "cecolor")
        blp (getvar "blipmode")
  )
;;
;; Internal error handler
;;
(defun aa_err (s)
  (if (/= s "Function cancelled")
    (princ (strcat "\nError: " s))
  )
  (setq ss nil)
  (setvar "osmode" omd)
  (setvar "celtype" clp)
  (setvar "cecolor" ccl)
  (setvar "blipmode" blp)
  (command "_.UNDO" "_END")
  (setvar "cmdecho" cde)
  (setq *error* olderr)
  (princ)
)
;;
  (setq olderr *error*  *error* aa_err)
  (setvar "cmdecho" 0)
  (command "_.UNDO" "_GROUP")
  (setvar "osmode" 0)
  (setvar "blipmode" 0)
  (setvar "celtype" "BYLAYER")
  (setvar "cecolor" "BYLAYER")
  (setq tag (getstring "\nTag <DN>: "))
  (if (= tag "") (setq tag "DN"))
  (setq ent (car (entsel "\nPick a block: ")))
  (while ent
    (setq att (entget ent))
    (if (= (ai_val 0 att) "INSERT")
      (progn
        (initget "Select All")
        (setq opt (getkword "\nSelect/<All>: ")
              blknam (ai_val 2 att)
              filst (list
                      '(-4 . "<AND")
                        '(0 . "INSERT")
                        (cons 2 blknam)
                        '(-4 . "<NOT") '(66 . 1) '(-4 . "NOT>")
                      '(-4 . "AND>")
                    )
              n 0
        )
        (if (= opt "Select")
          (setq ss (ssget filst))
          (setq ss (ssget "X" filst))
        )
        (if ss
          (repeat (sslength ss)
            (setq ent (ssname ss n)
                  att (entget ent)
                  att (append att '((66 . 1)))
                  ltp (ai_val 6 att)
                  lay (ai_val 8 att)
                  pt (ai_val 10 att)
                  scl (ai_val 41 att)
                  clr (ai_val 62 att)
                  n (1+ n)
            )
            (entdel ent)
            (entmake att)
            (setq att (list '(0 . "ATTRIB") '(1 . "")
                            (cons 2 tag) '(8 . "0")
                            (cons 10 pt) (cons 40 (* 0.2 scl))
                            '(70 . 1)
                      )
            )
            (entmake att)
            (setq att (list '(0 . "SEQEND") (cons 8 lay)))
            (if ltp (setq att (append att (list (cons 6 ltp)))))
            (if clr (setq att (append att (list (cons 62 clr)))))
            (entmake att)
          )
          (prompt "\nAll blocks have already attribute definitions .")
        )
      )
      (prompt "\nNo block selected.")
    )
    (if ss
      (princ (strcat "\n" (itoa (sslength ss))
             " attribute definition(s) added.")
      )
    )
    (setq ent (car (entsel "\nPick a block: ")))
  )
  (setq ss nil)
  (setvar "osmode" omd)
  (setvar "celtype" clp)
  (setvar "cecolor" ccl)
  (setvar "blipmode" blp)
  (command "_.UNDO" "_END")
  (setvar "cmdecho" cde)
  (setq *error* olderr)
  (princ)
)
;;
(defun ai_val (v attr)
  (cdr (assoc v attr))
)
;;======================================================================
(princ)

kk1874

楼上的我有用啊，教师要求我们加属性，不知道怎么弄呢，呵呵

xiaochongcn

加载程序后提示：
错误: 输入的点对中含有多余的 cdrs

民工

最初由 xiaochongcn 发布
[B]我用在位编辑块加上属性或者炸开块，重新附上属性再同名做块更新都不行。新插入的块正常，但是原有的块则不显示属性。[/B]

你已经做对了一半了：照你的方法，炸开一个块，增加属性，重新做同名块，这是正确的。
你差了一步：同步属性， _AttSync 命令

看看下面的帖子，2楼的“艺高”长老的演示
http://www.xdcad.net/forum/showthread.php?threadid=125677

原地踏步

系统出毛病了，而且怎么也改不过来。
filst 定义的时候出错。

xiaochongcn

谢谢民工！
也谢谢原地踏步。