[求助]：我写的批量瘦身工具

丹佛

大家看看问题出在那里？
(defun c:pu(/ wj n n1 wj1 wj2);
(vl-load-com)
(setq wj (vl-directory-files "c:/pu" "*.dwg" 1))
(setq n (length wj))
(setvar "filedia" 0)
(repeat n
(setq n1 0)
(setq wj1 (nth n1 wj))
(setq wj2 (strcat "c:/pu/" wj1))
(command "open" wj1)
(repeat 3
(command "-purge" "A" "" "n"))
(setq n1 (+1 n1))
)
(command "closeall" )
(setvar "filedia" 1)
)

xyp1964

(command "open" wj1) 似乎无法运行！

丹佛

请问版主，这个地方该如何写呢？告诉我吧，我想了很久都不行。

wwwdh

论坛里有好多例子，;;一个VLISP的批量处理范例
转一个给你
;;从这个范例可以了解VLISP批量处理图档
;;虽然速度慢了点,但非常实用
;;By LUCAS(龙龙仔)
;;从文件移除未使用之具名参考                                 
;;                                                           
;;虽配合Expresstools__(acetutil.arx)                        
;;为加度程序执行,程序将设定系统变量ACADLSPASDOC              
;;即<只载入 acad.lsp 至 AutoCAD 执行期所开启的第一个图面>   
;;当然程序结束后,会还原系统变量ACADLSPASDOC
;;                 
;;Usage: (PURGEALL <循环次数>)                                                            
;;Usage: (PURGEALL 5)                                       

(arxload "acetutil.arx" NIL)
(vl-load-com)
(defun PURGEALL        (TIMES / HOLDECHO APP DWGNAME PREFIX_DWG NN QQ HOLDLSP
                 WW)
  (setq HOLDECHO (getvar "cmdecho"))
  (setvar "cmdecho" 0)
  (setq        PREFIX_DWG
         (strcat
           (strcase (acet-ui-pickdir
                      "选择目录"
                      (vl-string-right-trim "\\" (getvar "dwgprefix"))
                      "移除未使用之具名参考"
                    )
           )
           "\\"
         )
  )
  (setq HOLDLSP (getvar "ACADLSPASDOC"))
  (setvar "acadlspasdoc" 0)
  (setq QQ (vl-directory-files PREFIX_DWG "*.DWG"))
  (setq NN 0)
  (if (/= QQ NIL)
    (progn
      (setq APP (vlax-get-acad-object))
      (repeat (length QQ)
        (setq DWGNAME (strcase (strcat PREFIX_DWG (nth NN QQ))))
        (setq WW (vla-open (vla-get-documents APP) DWGNAME))
        (repeat TIMES (vla-purgeall WW))
        (vla-save WW)
        (prompt (strcat "\n" DWGNAME " !!!"))
        (vla-close WW :vlax-false)
        (setq NN (1+ NN))
      )
      (vlax-release-object WW)
      (vlax-release-object APP)
    )
    (prompt "\n所选目录中未有任何图档!!!")
  )
  (setvar "acadlspasdoc" HOLDLSP)
  (setvar "cmdecho" HOLDECHO)
  (princ)
)
(princ)

丹佛

收下了，谢谢，研究一下。