[LISP函数]：常用几何函数:点p 在p1 p2 p3确定的平面上的投影~

fsxm

常用几何函数:
点p 在p1 p2 p3确定的平面上的投影~
[php]
;;;预备子函数1   点在直线的投影：
(defun prj-p->p1p2 (p p1 p2 / l1 k1 k2 k)
  (setq        l1 (mapcar '- p2 p1)
        k1 (apply '+ (mapcar '* (mapcar '- p p1) l1))
        k2 (apply '+ (mapcar '* l1 l1))
        k  (/ k1 k2)
  )
  (mapcar '+ (mapcar '* (list k k k) l1) p1)
)
;;;预备子函数2   两向量的叉积：
(defun V1xV2 (v1 v2)
  (list        (-
          (* (cadr v1) (caddr v2))
          (* (cadr v2) (caddr v1))
        )
        (-
          (* (caddr v1) (car v2))
          (* (caddr v2) (car v1))
        )
        (-
          (* (car v1) (cadr v2))
          (* (car v2) (cadr v1))
        )
  )
)
;;;主函数 点在平面上的投影：
(defun prj-p->p1p2p3 (p p1 p2 p3 / pp tmp-p v1 v2 vxv)
  (setq        v1    (mapcar '- p2 p1)
        v2    (mapcar '- p3 p1)
        vxv   (v1xv2 v1 v2)
        tmp-p (mapcar '+ p1 vxv)
        pp    (prj-p->p1p2 p p1 tmp-p)
  )
  (mapcar '+ p1 (mapcar '- p pp))
)
[/php]

sujia

vl-cmdf "ucs" "3"  p1 p2 p3
(setq p0 (trans p 0 1)
(setq p0  (append (reverse (cdr (reverse p0))) '(0)))
(setq p0 (trans p0 1 0))
vl-cmdf "ucs" w

fsxm

楼主的方法很简明很好！~不过（vl-cmdf "ucs" "3" p1 p2 p3）如果我给的点是WCS 中的呢？
这样做要区分给定的点是WCS还是UCS
================================================
为了方便在作为子孙程序调用习惯于不用command了所以给了个纯几何的算法~！
几何算法给出的点是WCS算出来的也是WCS的点
给出的点是UCS算出来的也是UCS的点