[求助]：请问用ENTSEL选择对象时如何设置过滤.

oyxx_1023 · 发表于 2006-10-30 19:52:09

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

比如只让选多义线.

qjcpj · 发表于 2006-10-30 23:28:40

好像办不到吧！
要select之后才能filter，问题是已“选”了...

舟自横 · 发表于 2006-10-31 13:53:51

可以,用grread 重寫entsel可以設置過濾功能,此功能在論壇中好象有，可以到函數下載中去找找看。。
明經通道好象我也有見過的..

橄榄滋味 · 发表于 2006-10-31 14:11:51

因为entsel是单选函数，所以可以用while控制，如果不是多义线则重新选择

lazybug · 发表于 2006-10-31 16:44:13

;带提示和过滤表的entsel

(defun c:test()
(setq en (xentsel "\n请选择一个圆:" '((0 . "circle"))))
)
;No.1 选择类型不附继续选择，为空则退出
(defun xentsel(txt plist / ss sn en)
;(setq txt "\n请选择一个圆:")
;(setq plist '((0 . "circle")))
(setq ss (ssget "x" plist))
(setq sn 0)
(while (zerop sn)
(setq en (entsel (strcat "\n" txt)))
(if (not en) (vl-exit-with-error ""))
(if (ssmemb (car en) ss) (setq sn 1))
)
en
)
;No.2 直到选择到为止
(defun xentsel (txt plist / ss sn en)
;(setq txt "\n请选择一个圆:")
;(setq plist '((0 . "circle")))
(setq ss (ssget "x" plist))
(while (not (and (setq en (entsel (strcat "\n" txt)))
(ssmemb (car en) ss)
)
)
)
en
)
;No.3 这个是明经上的改编而来(直到选择到为止)
(defun xentsel (txt plist)
(while (not (and (setq en (entsel txt))
(not (command "_select" (car en) ""))
(sssetfirst nil nil)
(ssget "p" plist)
)
)
)
en
)
;No.4 明经无痕大作
(defun xentsel (msg fil)
(while (not (and (setq el (entsel msg)) (ssget (cadr el) fil)))
)
el
)

(defun c:test() 
    (setq en (xentsel "\n请选择一个圆:" '((0 . "circle")))) 
) 
;No.1 选择类型不附继续选择，为空则退出 
(defun xentsel(txt plist / ss sn en) 
    ;(setq txt "\n请选择一个圆:") 
    ;(setq plist '((0 . "circle"))) 
    (setq ss (ssget "x" plist)) 
    (setq sn 0) 
    (while (zerop sn) 
        (setq en (entsel (strcat "\n" txt))) 
        (if (not en) (vl-exit-with-error "")) 
        (if (ssmemb (car en) ss) (setq sn 1)) 
    ) 
    en 
) 
;No.2 直到选择到为止 
(defun xentsel (txt plist / ss sn en) 
    ;(setq txt "\n请选择一个圆:") 
    ;(setq plist '((0 . "circle"))) 
    (setq ss (ssget "x" plist)) 
    (while (not        (and (setq en (entsel (strcat "\n" txt))) 
                     (ssmemb (car en) ss) 
                ) 
           ) 
    ) 
    en 
) 
;No.3 这个是明经上的改编而来(直到选择到为止) 
(defun xentsel (txt plist) 
    (while (not        (and (setq en (entsel txt)) 
                     (not (command "_select" (car en) "")) 
                     (sssetfirst nil nil) 
                     (ssget "p" plist) 
                ) 
           ) 
    ) 
    en 
) 
;No.4 明经无痕大作 
(defun xentsel (msg fil) 
    (while (not (and (setq el (entsel msg)) (ssget (cadr el) fil))) 
    ) 
    el 
)

Dallas_whu · 发表于 2006-10-31 17:32:35

给你个更好的吧，陌生人的大作！
[php]
;;;=============================================================================
;;返回值: NIL 或者 (实体名 . 点位)点对表.
;;功能: 1.带提示和过滤表的ENTSEL;
;;    2.循环直到选中有效实体或选择退出为止;
;;    3.返回的点对表中的点位为实体上的点;
;;    4.支持关键字串。
;;实例: (XENTSEL "\n选择直线或圆/UNDO/OPTION/EXIT" "UNDO OPTION EXIT" '((0 . "*LINE,CIRCLE,ARC")))
(DEFUN XENTSEL (MSG KEYWORD FILTER_LIST / $S0 $S01)
  (INITGET KEYWORD)
  (SETQ $S0 (ENTSEL MSG))
  (COND
((AND (= $S0 NIL) (= (GETVAR "ERRNO") 52)) NIL) ;回车结束，返回NIL
((= $S0 NIL) (XENTSEL MSG KEYWORD FILTER_LIST)) ;空选重复
((= (TYPE $S0) 'STR) $S0) ;返回关键字
((= (TYPE $S0) 'LIST) ;返回实体与点表，与ENTSEL相同
   (IF FILTER_LIST ;存在特征关联表
   (IF (AND (SETQ $S01 (SSGET (CADR $S0) FILTER_LIST))
(SSMEMB (CAR $S0) $S01)
   )
   $S0 ;真，返回实体与点表
   (XENTSEL MSG KEYWORD FILTER_LIST) ;假，循环拾取
   )
   $S0
   )
)
(T (XENTSEL MSG KEYWORD FILTER_LIST)) ;其它拾取及输入情况，循环拾取
  )
)
[/php]

lazybug · 发表于 2006-11-1 16:07:09

更好？？
好的标准是什么！

我认为，无痕的那个是最厉害的。

雨箭风刀 · 发表于 2006-11-1 18:19:06

“无痕的那个是最厉害的"
一山还比一山高，没有最厉害的：）

橄榄滋味 · 发表于 2006-11-2 12:23:00

最简单最实用的就是最厉害的，支持无痕

账号		自动登录	找回密码
密码			立即注册

[求助] [求助]：请问用ENTSEL选择对象时如何设置过滤.

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

相关帖子