[LISP程序]：ACAD2002和ACAD2004中VLSP的主要区别是什么呢？

chlh_jd

ACAD2002和ACAD2004中VLSP的主要区别是什么呢？
为什么有些LSP在2002测试正常，在2004测试不正常呢？
我有个将粗PL线转换成封闭PL线的程序，就遇到这样的问题，各位大侠帮忙看下，谢谢！
;;;-------------------------------------------------------------------------------------;;;
(defun c:ptsl (/ ss i sslen el ent kuandu dia el1 el2 ent1 ent2)
  (svos)(undo-begin)
  (setq ss (ssget '((0 . "LWPOLYLINE") (-4 . ">") (40 . 180))))
  (setq i 0)
  (setq sslen (sslength ss))
  (while (<= i (1- sslen))
    (setq el (ssname ss i))
    (setq ent (entget el))
    (setq kuandu (cdr(assoc 40 ent)))
    (setq dia (/ kuandu 2 ))
    (setq el1 (vla-offset (vlax-ename->vla-object el) dia))
    (setq el1
         (vlax-vla-object->ename
           (vlax-safearray-get-element
             (vlax-variant-value el1)
             0)
           )
        )
    (setq ent1 (entget el1))
    (setq ent1 (subst (cons 8 "WALL")(assoc 8 ent1) ent1))
    (entmod ent1)
    (PWProcess el1 0)
   
    (setq el2 (vla-offset (vlax-ename->vla-object el) (* -1 dia)))
    (setq el2
         (vlax-vla-object->ename
           (vlax-safearray-get-element
             (vlax-variant-value el2)
             0)
           )
        )
    (setq ent2 (entget el2))
    (setq ent2 (subst (cons 8 "WALL")(assoc 8 ent2) ent2))
    (entmod ent2)
    (PWProcess el2 0)
    (setq ptlist1(endpt el1))
    (setq ptlist2(endpt el2))
    (command "line" (car ptlist1) (car ptlist2) "")
    (setq el3 (entlast))
    (command "line" (cadr ptlist1) (cadr ptlist2) "")
    (setq el4 (entlast))
    (command "pedit" el1 "j" el2 el3 el4 "" "")
    (entdel el)
    (setq i (1+ i))
    )  
  (clos)(undo-end)
  (princ "\n高山流水建筑图结构处理程序，命令PTSL!")
  )


;;;返回多段线第n子段的端点坐标,从零开始.
;;;[语法]
;;;(coodsofsegbynum obj n)
;;;[参数]
;;;obj:图元名
;;;n:代表子段位置的整数
;;;[返回值]
;;;坐标列表.
;;(coods-of-seg-by-num (entlast) 1)
(defun coods-of-seg-by-num (ename n)
  (setq obj (vlax-ename->vla-object ename))
  (vlax-safearray->list
              (vlax-variant-value
                (vla-get-coordinate obj n)))
)




;;;---------------------------------------------------------------------;;;
(defun svos()                                                    ;;;保存原来的设定
  (setq oldosm (getvar "OSMODE")                ;捕捉设定
        oldoth (getvar "ORTHOMODE")                ;正交设定
        oldlye (getvar "CLAYER")                ;当前层
        oldclr (getvar "CECOLOR")                ;当前颜色
        plnwid (getvar "PLINEWID")                ;线宽设定
        oldltp (getvar "CELTYPE")                ;保存当前线形
  )
)        ;;;end svos()
;;;---------------------------------------------------------------------;;;
(defun clos()                                             ;;;恢复原来的设定
  (setvar "OSMODE" oldosm)
  (setvar "ORTHOMODE" oldoth)
  ;(command "LAYER" "SET" oldlye "")
  (setvar "CECOLOR" oldclr)
  (setvar "PLINEWID" plnwid)
  (setvar "CELTYPE" oldltp)
  (prin1)
)
;;;---------------------------------------------------------------------;;;
(defun undo-begin    (/ undo_control old_cmdecho)                 ;;;UNDO开始
  (setq undo_flag 0)
  (setq undo_control (getvar "undoctl"))
  (if (and (= 1 (logand 1 undo_control))
      (/= 2 (logand 2 undo_control))
      (/= 8 (logand 8 undo_control))
      )
    (progn
      (setq old_cmdecho (getvar "cmdecho"))
      (setvar "cmdecho" 0)
      (command "_.undo" "_begin")
      (setvar "cmdecho" old_cmdecho)
      (setq undo_flag 1)
    )
  )
)
;;;---------------------------------------------------------------------;;;
(defun undo-end (/ old_cmdecho)                                 ;;;UNDO结束
  (if (eq 1 undo_flag)
    (progn
      (setq old_cmdecho (getvar "cmdecho"))
      (setvar "cmdecho" 0)
      (command "_.undo" "_end")
      (setvar "cmdecho" old_cmdecho)
      (setq undo_flag 0)
    )
  )
)
;;;---------------------------------------------------------------------;;;
(defun PWProcess  (entname width / edent entname cp r endent_layer)
  (setvar "blipmode" 0)
  (setvar "plinewid" width)
  ;;(command "layer" "LOCK" "hatch" "")
  (setq edent (entget entname))
  (cond        ;;"PLINE"
        ((or (= "LWPOLYLINE" (cdr (assoc 0 edent)))
             (= "POLYLINE" (cdr (assoc 0 edent))))
         (command "pedit" entname "W" width "" ))
        ;;"LINE" "ARC"
        ((or (= "ARC" (cdr (assoc 0 edent)))
             (= "LINE" (cdr (assoc 0 edent))))
         (command "pedit" entname "" "W" width ""))
        ;;"CIRCLE"
        ((= "CIRCLE" (cdr (assoc 0 edent)))
         (setq cp (cdr (assoc 10 edent))) ;center point
         (setq r (cdr (assoc 40 edent))) ;radius
         (entdel entname)                ;delete old "CIRCLE"
         (setq edent_layer (cdr (assoc 8 edent)))
         (command "layer" "s" edent_layer "")
         (command "_.donut"
                  (* 2.0 (- r (/ width 2)))
                  (* 2.0 (+ r (/ width 2)))
                  cp
                  "")))
  (command "layer" "UNLOCK" "hatch" "")
  (command "setvar" "blipmode" 1)
  (command "redraw")
  ); end PWProcess



;|取得曲线的起点，终点.  -----------------------------陌生人.2004
支持arc,spline,pline,lwpline,el,line.
测试: (endpt (car(entsel))) 点取任意曲线，返回-> ((20931.6 2906.28 0.0) (28571.5 1410.14 0.0))
|;
(defun endpt (e)
  (setq eobj (vlax-ename->vla-object e)
pts  (vlax-curve-getstartpoint eobj)
pte  (vlax-curve-getendpoint eobj)
  )
  (cons pts (list pte))
)