[下载]：属性与文本批量互转！

carrot1983

1.TAG2TXT属性转文本　
[php]
;; TAG2TXT属性转文本　
(defun C:TAG2TXT ()
   (setq sset (ssget '((0 . "ATTDEF"))))
   (setq num (sslength sset) itm 0)
   (while (< itm num)
     (setq hnd (ssname sset itm))
     (setq ent (entget hnd))
     (setq new '((0 . "TEXT")))
     (setq new (append new (list (cons 1 (cdr (assoc 2 ent))))))
     (setq dolst (list 7 8 10 11 39 40 41 50 51 62 71 72 73))
     (foreach grp dolst
       (setq addto (assoc grp ent))
       (if (/= addto nil)
         (setq new (append new (list (assoc grp ent))))
       )
     )
     (entdel hnd)
     (entmake new)
     (setq itm (1+ itm))
   )
   (princ)
)
[/php]

2.TXT2TAG文本转属性
[php]
;; TXT2TAG文本转属性　
(defun C:TXT2TAG (/ sset num itm hnd ent new dolst grp addto)
  (setq sset (ssget '((0 . "TEXT"))))
  (setq        num (sslength sset)
        itm 0
  )
  (while (< itm num)
    (setq hnd (ssname sset itm))
    (setq ent (entget hnd))
    (setq new '((0 . "ATTDEF")))
    (setq new (append new
                      (list (cons 1 (cdr (assoc 1 ent)))
                            (cons 2 (cdr (assoc 1 ent)))
                            (cons 3 (cdr (assoc 1 ent)))
                            (cons 70 0)
                      )
              )
    )
    (setq dolst (list 7 8 10 11 39 40 41 50 51 62 71 72 73))
    (foreach grp dolst
      (setq addto (assoc grp ent))
      (if (/= addto nil)
        (setq new (append new (list (assoc grp ent))))
      )
    )
    (entdel hnd)
    (entmake new)
    (setq itm (1+ itm))
  )
  (princ)
)

[/php]

marcoyuwen

“TXT2TAG文本转属性”程序中：
1. 如果被编辑的文本图元的文本内容含有小写字母则会自动转为大写；
2. 如果被编辑的文本图元的文本内容含有空格，则会与程序的初衷不符，会丢失。

huyong

最初由 marcoyuwen 发布
[B]“TXT2TAG文本转属性”程序中：
1. 如果被编辑的文本图元的文本内容含有小写字母则会自动转为大写；
2. 如果被编辑的文本图元的文本内容含有空格，则会与程序的初衷不符，会丢失。 [/B]

不错，谢谢了。但应该保留小写才好是。

carrot1983

谢谢二楼的提醒！
首先，抱歉。
其次，第一个程序是MJTD上面的！
      第二个当然是我根据上面的想法做的修改。
最后，希望哪位把二个程序修正完整一下！感谢！
第二个程序感觉没什么意义！用下面这个吧！
[php]
;;把text转为属性图块
;;By LUCAS
(defun C:C_DEF (/ HOLDECHO HOLDBLIP HOLDREQ SS SSS N A AA A1 A73 HH
                LST_210        LST_10
               )  (defun DXF (A1 A2 /)
    (setq ENT (cdr (assoc A1 A2)))
  )  (defun GETATT        (E ATTNAME / N ATT E1 EN EN1 RSLT)
    (setq EN (entget E)
          E1 E
    )
    (if        (and (= (DXF 0 EN) "INSERT")
             (= (DXF 66 EN) 1)
        )
      (progn
        (setq E1  (entnext E1)
              ATT (strcase ATTNAME)
        )
        (while (and E1
                    (setq EN1 (entget E1))
                    (= (DXF 0 EN1) "ATTRIB")
               )
          (setq RSLT (append RSLT (list (DXF -1 EN1))))
          (setq E1 (entnext E1))
        )
      )
    )
    (setq N 0)
    (repeat (length RSLT)
      (entmod (subst (nth N LST_210)
                     (assoc 210 (entget (nth N RSLT)))
                     (entget (nth N RSLT))
              )
      )
      (entmod (subst (nth N LST_10)
                     (assoc 10 (entget (nth N RSLT)))
                     (entget (nth N RSLT))
              )
      )
      (setq N (1+ N))
    )
    (entupd (entlast))
  )  (command "_.undo" "_group")
  (setq HOLDECHO (getvar "cmdecho"))
  (setq HOLDBLIP (getvar "blipmode"))
  (setq HOLDREQ (getvar "attreq"))
  (setvar "cmdecho" 0)
  (setvar "blipmode" 0)
  (while (or (= SSS NIL) (= SS NIL))
    (setq SSS (ssget))
    (setq SS (ssget "P" '((0 . "TEXT"))))
  )
  (command "_.UCS" "")
  (setq N 0)
  (setq HH (ssadd))
  (repeat (sslength SS)
    (setq A (ssname SS N))
    (setq LST_210 (append LST_210 (list (assoc 210 (entget A)))))
    (setq LST_10 (append LST_10 (list (assoc 10 (entget A)))))
    (setq AA (member '(100 . "AcDbEntity") (entget A)))
    (setq A73 (cdr (assoc 73 AA)))
    (setq A1 (cdr (assoc 1 AA)))
    (entmake (append '((0 . "ATTDEF"))
                     (reverse (cddr (reverse AA)))
                     '((100 . "AcDbAttributeDefinition")
                       (70 . 8)
                       ;;(73 . 0)
                      )
                     (list (cons 74 A73)
                           (cons 3 A1)
                           (cons 2 A1)
                     )
             )
    )
    (ssadd (entlast) HH)
    (setq N (1+ N))
  )
  (command "_.erase" SS "")
  (setq A (rtos (* (getvar "CDATE") 1E8)))
  (command "_.BLOCK" A "0,0" HH SSS "")
  (setvar "attreq" 0)
  (command "_.INSERT" A "0,0" "" "" "")
  (setvar "attreq" HOLDREQ)
  (GETATT (entlast) A)                        ;处理text对象不在X-Y平面
  (command "_.UCS" "P")
  (setvar "blipmode" HOLDBLIP)
  (setvar "cmdecho" HOLDECHO)
  (command "_.undo" "_end")
  (princ)
)
(prompt "\nType C_DEF")
(princ)
[/php]

qq1254582201

找了很久了
终于找到你！！！！
感谢