[求助]：为什么单步运行取点全部正确，画出来却不一样？

zhengbinlover · 发表于 2008-5-8 06:12:27

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

程序要求提示输入两圆心，两半径，自动生成切线
如图

我调试了好久，实在不知道我的代码出错在什么地方了
我把后面取点aaa,bbb,ccc,ddd的代码一条一条贴到CAD中执行，获取的点都是正确的，可是整个运行就乱画。求大虾帮忙
如果有另外的简便方法的话，请帮帮忙解答

(DEFUN C:99()
;(/ c1 r1 c2 r2 x y xy m n ang j2 pa pb)
  (setq c1 (getpoint "请指定圆1的圆心"))
  (setq R1 (getdist c1 "请指定圆1的半径"))
  (command "circle" c1 R1)
  (setq c2 (getpoint "请指定圆2的圆心"))
  (setq R2 (getdist c2 "请指定圆2的半径"))
  (command "circle" c2 R2)
  (command "line" c1 c2 "")

  (setq xx (abs (- (car c1) (car c2))))
  (setq yy (abs (- (cadr c1) (cadr c2))))
  (setq xy (sqrt (+ (* xx xx) (* yy yy))))

  (setq mm (- R2 R1))
  (setq nn (sqrt (- (* xy xy) (* (- R2 R1) (- R2 R1)))))

  (setq j1 (atan (/ mm nn)))
  (setq j2 (atan (/ yy xx)))
  (setq aaa (polar c1 (+ j1 j2 (* 90 (/ 3.1415926 180))) r1))
  (setq bbb (polar c1 (- (+ j2 (* 270 (/ 3.1415926 180))) j1) r1))
  (setq ccc (polar c2 (+ j1 j2 (* 90 (/ 3.1415926 180))) r2))
  (setq ddd (polar c2 (- (+ j2 (* 270 (/ 3.1415926 180))) j1) r2))

  (command "line" aaa ccc "")
  (command "line" bbb ddd "")

(princ))

xyp1964 · 发表于 2008-5-8 07:53:40

[FONT=courier new](DEFUN C:99 (/ c1 r1 c2 r2 ang p1 p2 p3 p4)
(setq c1 (getpoint "\n请指定圆1的圆心: ")
R1 (getdist c1 "\n请指定圆1的半径: ")
)
(command "circle" "non" c1 R1)
(setq c2 (getpoint "\n请指定圆2的圆心: ")
R2 (getdist c2 "\n请指定圆2的半径: ")
)
(command "circle" "non" c2 R2)
(command "line" "non" c1 "non" c2 "")
(setq ang (angle c1 c2)
p1 (polar c1 (+ ang (* pi 0.5)) r1)
p2 (polar c1 (- ang (* pi 0.5)) r1)
p3 (polar c2 (+ ang (* pi 0.5)) r2)
p4 (polar c2 (- ang (* pi 0.5)) r2)
)
(command "line" "tan" p1 "tan" p3 "")
(command "line" "tan" p2 "tan" p4 "")
(princ)
)[/FONT]

zml84 · 发表于 2008-5-8 22:28:47

<HR SIZE=5><PRE>(defun C:TT (/ C1 R1 C2 R2 ANG DIST PT1 PT2 PT3 PT4)
(if (and (setq C1 (getpoint "\n请指定圆1的圆心: "))
 (setq R1 (getdist C1 "\n请指定圆1的半径: "))
 (setq C2 (getpoint "\n请指定圆2的圆心: "))
 (setq R2 (getdist C2 "\n请指定圆2的半径: "))
)
(progn
 (command "_.circle" "non" C1 R1)
 (command "_.circle" "non" C2 R2)
 (command "line" "non" C1 "non" C2 "")
 (setq ANG (angle C1 C2)
 DIST (distance C1 C2)
 ANG1 (atan
 (- R1 R2)
 (sqrt (- (* DIST DIST) (* (- R1 R2) (- R1 R2)))
 )
 )
 )
 (setq PT1 (polar C1 (- ANG (* pi 1.5) ANG1) R1)
 PT2 (polar C2 (- ANG (* pi 1.5) ANG1) R2)
 PT3 (polar C1 (+ ANG (* pi 1.5) ANG1) R1)
 PT4 (polar C2 (+ ANG (* pi 1.5) ANG1) R2)
 )
 (command "_.line" "non" PT1 "non" PT2 "")
 (command "_.line" "non" PT3 "non" PT4 "")
)
)
(princ)
)
</PRE>

linhui12 · 发表于 2008-5-8 22:35:07

楼主的程序其实是可行的,只要在
"(command "line" aaa ccc "")"前加一句" (setvar "osmode" 0)"关掉对象捕捉就行了.

账号		自动登录	找回密码
密码			立即注册

[求助] [求助]：为什么单步运行取点全部正确，画出来却不一样？

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

相关帖子