[求助]：帮忙搞定它（轴网LISP）

tanle2020

求助各位大哥，帮忙搞定这个程序，此程序缺少resfnt这个函数，小弟不才还请各位大哥帮帮忙

LISP代码：

(defun ax_edit (l1     bottom_list top_list    left_list
  right_list  /  dimlist     comlist
  repno     dimen why     str_pos
  hangle     vangle temp     i
  p1     p2  do_diment   show_type
  do_dimens   do_editem do_delitem  defaults
  save_list   what_next check_in    del_list
  do_repnos   do_repnot do_vangle   ins_item
  show_list   show_l do_typesel  rm_item
  do_hangle   sin_id do_reset    do_additem
  item     do_sum do_single   do_save
  do_key
        )
  (defun rm_item (thelist rm_pos / str)
    (repeat rm_pos
      (setq str     (cons (car thelist) str)
     thelist (cdr thelist)
      )
    )
    (append (reverse str) (cdr thelist))
  )
  (defun ins_item (thelist ins_pos item / str)
    (if (/= 0 ins_pos)
      (repeat (1- ins_pos)
(setq str     (cons (car thelist) str)
       thelist (cdr thelist)
)
      )
    )
    (append (reverse str) (list item) thelist)
  )
  (defun save_list ()
    (cond ((= show_type 0) (setq top_list dimlist) (del_list))
   ((= show_type 1) (setq bottom_list dimlist) (del_list))
   ((= show_type 2) (setq left_list dimlist) (del_list))
   ((= show_type 3) (setq right_list dimlist) (del_list))
    )
  )
  (defun show_l (dimkeyl / i n str c tf)
    (setq str (apply 'strcat
       (mapcar '(lambda (s)
    (if (= "" s)
      s
      (strcat s " ")
    )
         )
        dimlist
       )
       )
    )
    (if (< (strlen str) 132)
      (if dimkeyl
(progn (setq n      (1+ (strlen dimkeyl))
       dimlist nil
       str     ""
       i      0
       tf      T
        )
        (repeat n
   (setq i (1+ i)
         c (substr dimkeyl i 1)
   )
   (if (or (= " " c) (= "" c) (= "," c) (= ";" c))
     (progn (setq tf T)
     (if (/= "" str)
       (setq dimlist (cons str dimlist)
      str   ""
       )
     )
     )
     (cond ((= "." c) (setq tf nil))
    ((and tf (or (<= "0" c "9") (= "*" c)))
     (setq str (strcat str c))
    )
     )
   )
        )
        (setq dimlist (reverse (cons "" dimlist)))
)
(set_tile "key_l" str)
      )
    )
    (start_list "dim_list")
    (mapcar 'add_list dimlist)
    (end_list)
  )
  (defun do_key (v)
    (show_l v)
    (do_sum dimlist show_type)
    (set_tile "dim_list" (itoa str_pos))
  )
  (defun show_list ()
    (cond ((= show_type 0) (setq dimlist top_list))
   ((= show_type 1) (setq dimlist bottom_list))
   ((= show_type 2) (setq dimlist left_list))
   ((= show_type 3) (setq dimlist right_list))
    )
    (show_l nil)
    (set_tile "dim_list" (itoa str_pos))
  )
  (defun do_sum (l tp / x)
    (setq x (apply '+ (resolve l)))
    (if (not sin_id)
      (setq x (max x
     (apply '+
     (resolve (cond ((= 0 tp) bottom_list)
      ((= 1 tp) top_list)
      ((= 2 tp) right_list)
      ((= 3 tp) left_list)
       )
     )
     )
       )
      )
    )
    (set_tile (if (< tp 2)
  "kai_t"
  "jin_t"
       )
       (rtos x 2 0)
    )
  )
  (defun defaults ()
    (if _tfsd
      (progn (setq sin_id T) (do_single) (mode_tile "single" 1))
    )
    (set_tile "hangle_t" hangle)
    (set_tile "vangle_t" vangle)
    (if (>= 4 what_next)
      (progn (setq str_pos 0
     show_type 1
      )
      (setq dimlist bottom_list)
      )
    )
    (show_l nil)
    (start_list "com_list")
    (mapcar 'add_list comlist)
    (end_list)
    (do_sum bottom_list 1)
    (do_sum left_list 2)
    (set_tile "type_sel" "bottom")
    (set_tile "dim_list" "0")
    (mode_tile "cancel" 2)
  )
  (defun check_in (input format)
    (if (distof input 2)
      (if (not (and (/= (substr format 5 4) "转角")
      (<= (atoi (setq input (itoa (atoi input)))) 0)
        )
   )
(progn (rs_error) input)
      )
      (progn (set_tile "error" (strcat "无效的" format "输入"))
      nil
      )
    )
  )
  (defun do_reset ()
    (if (not (new_dialog "confirm" axis_id))
      (exit)
    )
    (action_tile "sure" "(done_dialog 2)")
    (if (= (start_dialog) 2)
      (del_list)
    )
    (set_tile "dim_list" "0")
    (do_sum dimlist show_type)
  )
  (defun do_repnot ()
    (if (setq temp (check_in temp "重复数"))
      (progn (setq repno temp) (set_tile "rep_no_s" repno))
    )
    (set_tile "rep_no_t" repno)
  )
  (defun do_repnos () (set_tile "rep_no_t" repno))
  (defun do_diment ()
    (if (setq temp (check_in temp "尺寸参数"))
      (progn (setq dimen temp) (set_tile "dimen_s" dimen))
    )
    (set_tile "dimen_t" dimen)
  )
  (defun do_dimens ()
    (if (= 3 why)
      (progn (setq dimen (itoa (* (/ (+ 150 (atoi dimen)) 300) 300)))
      (set_tile "dimen_s" dimen)
      )
    )
    (set_tile "dimen_t" dimen)
  )
  (defun do_typesel (which)
    (save_list)
    (cond ((= which "top")
    (setq show_type 0)
    (if (equal '("") top_list)
      (setq top_list bottom_list)
    )
   )
   ((= which "bottom")
    (setq show_type 1)
    (if (equal '("") bottom_list)
      (setq bottom_list top_list)
    )
   )
   ((= which "left")
    (setq show_type 2)
    (if (equal '("") left_list)
      (setq left_list right_list)
    )
   )
   ((= which "right")
    (setq show_type 3)
    (if (equal '("") right_list)
      (setq right_list left_list)
    )
   )
    )
    (show_list)
  )
  (defun do_delitem ()
    (if (not (equal '("") dimlist))
      (progn (setq str_pos (atoi (get_tile "dim_list")))
      (setq dimlist (rm_item dimlist
        (- str_pos
           (if (= "" (nth str_pos dimlist))
      1
      0
           )
        )
      )
      )
      (show_l nil)
      (set_tile "dim_list"
         (itoa (if (= str_pos (length dimlist))
          (1- str_pos)
          str_pos
        )
         )
      )
      (do_sum dimlist show_type)
      )
    )
  )
  (defun do_editem (/ l_item tf)
    (if (/= ""
     (setq str_pos (atoi (get_tile "dim_list"))
    item   (nth str_pos dimlist)
     )
)
      (progn (setq l_item (strlen item)
     i   1
      )
      (while (< i l_item)
        (if (= "*" (substr item i 1))
   (setq repno (substr item 1 (1- i))
         dimen (substr item (1+ i) (- l_item i))
         i     l_item
         tf    T
   )
   (setq i (1+ i))
        )
      )
      (if (not tf)
        (setq dimen item
       repno "1"
        )
      )
      (setq dimlist (rm_item dimlist str_pos))
      (show_l nil)
      (set_tile "dim_list" (itoa str_pos))
      (set_tile "rep_no_t" repno)
      (set_tile "rep_no_s" repno)
      (set_tile "dimen_t" dimen)
      (set_tile "dimen_s" dimen)
      (do_sum dimlist show_type)
      (mode_tile "ed_item" 1)
      )
    )
  )
  (defun do_addcom (n / x)
    (rs_error)
    (setq str_pos (1+ (atoi (get_tile "dim_list")))
   item   (nth (atoi n) comlist)
   dimlist (ins_item dimlist str_pos item)
   x   (length dimlist)
    )
    (show_l nil)
    (cond ((/= x str_pos) (set_tile "dim_list" (itoa str_pos)))
   ((and (= (1- x) str_pos) (/= 1 x))
    (set_tile "dim_list" (itoa (1- str_pos)))
   )
    )
    (do_sum dimlist show_type)
    (mode_tile "ed_item" 0)
  )
  (defun do_additem (/ x)
    (rs_error)
    (setq str_pos (1+ (atoi (get_tile "dim_list"))))
    (if (> (atoi repno) 1)
      (setq item (strcat repno "*" dimen))
      (setq item dimen)
    )
    (setq dimlist (ins_item dimlist str_pos item)
   x   (length dimlist)
    )
    (show_l nil)
    (cond ((/= x str_pos) (set_tile "dim_list" (itoa str_pos)))
   ((and (= (1- x) str_pos) (/= 1 x))
    (set_tile "dim_list" (itoa (1- str_pos)))
   )
    )
    (do_sum dimlist show_type)
    (mode_tile "ed_item" 0)
  )
  (defun do_single (/ tf)
    (setq tf (if sin_id
        1
        0
      )
    )
    (mode_tile "type_sel" tf)
    (mode_tile "double" tf)
    (mode_tile (if (> show_type 1)
   "kai_jian"
   "jin_shen"
        )
        tf
    )
    (do_sum dimlist show_type)
  )
  (defun do_hangle ()
    (if (Check_in temp "横轴转角")
      (setq hangle temp)
      (set_tile "hangle_t" hangle)
    )
  )
  (defun do_vangle ()
    (if (Check_in temp "纵轴转角")
      (setq vangle temp)
      (set_tile "vangle_t" vangle)
    )
  )
  (defun del_list ()
    (setq dimlist '("")
   str_pos 0
    )
    (show_l nil)
  )
  (defun do_save ()
    (save_list)
    (cond ((and sin_id
  (not (cdr (cond ((= show_type 0) top_list)
    ((= show_type 1) bottom_list)
    ((= show_type 2) left_list)
    ((= show_type 3) right_list)
     )
       )
  )
    )
    (set_tile "error" "未定义单向轴网!")
   )
   ((not (or sin_id (cdr bottom_list) (cdr top_list)))
    (set_tile "error" "上下开间均无定义!")
    (show_list)
   )
   ((not (or sin_id (cdr left_list) (cdr right_list)))
    (set_tile "error" "左右进深均无定义!")
    (show_list)
   )
   ((>= (atof hangle) (atof vangle))
    (set_tile "error" "横轴转角应小于纵轴转角!")
    (show_list)
   )
   (T
    (setq top_list    (reverse (cdr (reverse top_list)))
   bottom_list (reverse (cdr (reverse bottom_list)))
   left_list   (reverse (cdr (reverse left_list)))
   right_list  (reverse (cdr (reverse right_list)))
   l1      (list hangle vangle)
    )
    (if (not bottom_list)
      (setq bottom_list top_list)
    )
    (if (not left_list)
      (setq left_list right_list)
    )
    (done_dialog 2)
   )
    )
  )
  (setq hangle     (car l1)
vangle     (cadr l1)
repno     "1"
dimen     "3300"
top_list    (append top_list '(""))
bottom_list (append bottom_list '(""))
left_list   (append left_list '(""))
right_list  (append right_list '(""))
comlist     '("1800" "2100"   "2400"    "2700"    "3000"
        "3300" "3600"   "3900"    "4200"    "4500"
        "4800" "5100"   "5400"    "5700"    "6000"
        "6600" "7500"   "9000"
       )
  )
  
  (if (and (not axis_id)(<(setq axis_id(load_dialog "axis.dcl"))0))(exit))
  (setq what_next 4)
  (while (< 2 what_next)
    (if (not (new_dialog "axis" axis_id))
      (exit)
    )
    (if (= 4 what_next)
      (progn (mode_tile "sel_objs" 1) (mode_tile "area_t" 1))
    )
    (defaults)
    (action_tile "rep_no_t" "(setq temp $value)(do_repnot)")
    (action_tile "rep_no_s" "(setq repno $value)(do_repnos)")
    (action_tile "dimen_t" "(setq temp $value)(do_diment)")
    (action_tile
      "dimen_s"
      "(setq dimen $value why $reason)(do_dimens)"
    )
    (action_tile "key_l" "(do_key $value)")
    (action_tile "type_sel" "(do_typesel $value)")
    (action_tile
      "single"
      "(setq sin_id(= $value \"1\"))(do_single)"
    )
    (action_tile "del_item" "(do_delitem)")
    (action_tile "ed_item" "(do_editem)")
    (action_tile "add_item" "(do_additem)")
    (action_tile "reset" "(do_reset)")
    (action_tile "dim_list" "(setq str_pos(atoi $value))")
    (action_tile
      "com_list"
      "(if(= 1 $reason)(do_addcom $value))"
    )
    (action_tile "hangle_t" "(setq temp $value)(do_hangle)")
    (action_tile "hangle_t1" "(done_dialog 5)")
    (action_tile "vangle_t" "(setq temp $value)(do_vangle)")
    (action_tile "vangle_t1" "(done_dialog 6)")
    (action_tile "accept" "(do_save)")
    (action_tile "help" "(do_help \"desaxis\")")
    (setq what_next (start_dialog))
    (cond
      ((= 2 what_next)
       (list (if sin_id
        show_type
      )
      l1
      top_list
      bottom_list
      left_list
      right_list
       )
      )
      ((= 5 what_next)
       (if
  (and
    (setq
      p1 (getinters "\n请点取横轴转角的第一点 <退出>: " "轴线")
    )
    (setq p2 (getinters "\n再点取横轴转角的第二点 <退出>: "
          "轴线"
          p1
      )
    )
    (Check_in (setq temp (angtos (angle p1 p2) 0 2)) "横轴转角")
  )
   (setq hangle temp)
       )
      )
      ((= 6 what_next)
       (if
  (and
    (setq
      p1 (getinters "\n请点取纵轴转角的第一点 <退出>: " "轴线")
    )
    (setq p2 (getinters "\n再点取纵轴转角的第二点 <退出>: "
          "轴线"
          p1
      )
    )
    (Check_in (setq temp (angtos (angle p1 p2) 0 2)) "纵轴转角")
  )
   (setq vangle temp)
       )
      )
    )
  )
)
(defun axi_r (/ fn i n)
  (setvar "limcheck" 0)
  (if (setq fn (open "axis.dat" "r"))
    (progn (setq p0 (read-line fn)
   ll (list (read-line fn)
     (read-line fn)
     (read-line fn)
     (read-line fn)
     (read-line fn)
      )
    )
    (close fn)
    (if (and p0 (listp (setq p0 (read p0))) (mapcar 'and ll))
      (progn (grtext 20 "————")
      (grtext 21 "生成方式")
      (grtext 22 "————")
      (grtext 23 "生成数据")
      (grtext 24 "修改数据")
      (initget "1 2")
      (setq ll (mapcar '(lambda (x)
     (if x
       (read x)
     )
          )
         ll
        )
     i  (getkword "\n请选择/ 1-生成新数据/ 2-修改已有数据/ <1>: ")
      )
      (setq n 20)
      (repeat 5 (grtext n "        ") (setq n (1+ n)))
      )
    )
    )
  )
  (if (not i)
    (setq i "1")
  )
  (if (= i "1")
    (setq p0 (list 9000. 9000.)
   ll (list '("0" "90") nil nil nil nil)
    )
  )
)
(defun axi_w (/ fn)
  (if (setq fn (open "axis.dat" "w"))
    (progn (prin1 p0 fn)
    (print (car ll) fn)
    (print (caddr ll) fn)
    (print (if (equal (caddr ll) (cadr ll))
      nil
      (cadr ll)
    )
    fn
    )
    (print (cadddr ll) fn)
    (print (if (equal (cadddr ll) (last ll))
      nil
      (last ll)
    )
    fn
    )
    (close fn)
    )
  )
)
(defun axi_1 (lx1 lx2 xa xb xmx ax ax1 / q1 q2 d d2 x1 x2 xx tf)
  (cond ((not lx2) (setq lx2 lx1))
((not lx1) (setq lx1 lx2))
  )
  (setq d  1000.
d2 (/ d 2)
x1 0
x2 0
xx 0
  )
  (while (or (< xx xmx) (and (= xx xmx) (/= x1 x2)))
    (setq tf (> x1 x2)
   xx (if tf
        x2
        x1
      )
   p1 (polar p0 ax1 xx)
   q1 (polar p1
      ax
      (- xa
         (if tf
    d2
    d
         )
      )
      )
   q2 (polar p1
      ax
      (+ xb
         (if (< x1 x2)
    d2
    d
         )
      )
      )
    )
    (getcxy1 q1)
    (getcxy1 q2)
    (command ".line" q1 q2 "")
    (setq tf (<= x1 x2))
    (if (>= x1 x2)
      (setq x2 (if lx2
    (+ x2 (car lx2))
    xmx
  )
     lx2 (cdr lx2)
      )
    )
    (if tf
      (setq x1 (if lx1
    (+ x1 (car lx1))
    xmx
  )
     lx1 (cdr lx1)
      )
    )
  )
)
(defun resolve (l / l1 n i)
  (foreach x (reverse l)
    (setq i (atoi x)
   n (strlen (itoa i))
    )
    (if (> (strlen x) n)
      (setq x (substr x (+ 2 n)))
      (setq i 1)
    )
    (setq x (atof x))
    (repeat i (setq l1 (cons x l1)))
  )
  l1
)
(defun c:QQ (/    tf   p0  p1   ll   a axy  ax   ax1  ay
    ay1  sina cosa lx1  lx2  ly1 ly2  x0   xa   xb
    y0   ya   yb  lzmw xmin xmax ymin ymax c0   tfo
   )
  (axi_r)
  (if (setq ll (apply 'ax_edit ll))
    (progn
      (setq c0 1000.
     tf (car ll)
     p1 (getpoint (strcat (if tf
       "\n请点取单向轴网插入点 <"
       "\n输入轴线网左下角点 <"
     )
     (rtos (car p0) 2 0)
     ","
     (rtos (cadr p0) 2 0)
     ">: "
    )
        )
     p0 (if p1
   p1
   p0
        )
     ll (cdr ll)
      )
      (axi_w)
      (resfnt)
      ;(begin "轴线")
      (if tf
(if (and (setq
     ax (getangle
   p0
   "\n再点取单向轴网的生成方向或输入方向角 <退出>: "
        )
   )
   (setq p1 (getpoint p0 "\n给出轴线结束点 <退出>: "))
     )
   (progn (setq ll (resolve (nth tf (cdr ll)))
         ya (p_l p1 p0 (polar p0 ax 1e3))
   )
   (axi_1 ll
   nil
   0
   (abs ya)
   (apply '+ ll)
   ((if (> ya 0)
      -
      +
    )
     ax
     _pi2
   )
   ax
   )
   )
)
(progn (mapcar 'set '(axy lx1 lx2 ly1 ly2) ll)
        (setq ax   (angtof (car axy) 0)
       ax1  (+ ax _pi2)
       ay   (angtof (cadr axy) 0)
       ay1  (- ay _pi2)
       lx1  (resolve lx1)
       lx2  (resolve lx2)
       ly1  (resolve ly1)
       ly2  (resolve ly2)
       x0   (max (apply '+ lx1) (apply '+ lx2))
       y0   (max (apply '+ ly1) (apply '+ ly2))
       a   (+ ax _pi2 (- ay))
       sina (sin a)
       cosa (cos a)
       xa   (if (< sina 0)
       (/ (* x0 sina) cosa)
       0
     )
       xb   (if (< sina 0)
       (/ y0 cosa)
       (/ (+ y0 (* x0 sina)) cosa)
     )
       ya   (if (< sina 0)
       (/ (* y0 sina) cosa)
       0
     )
       yb   (if (< sina 0)
       (/ x0 cosa)
       (/ (+ x0 (* y0 sina)) cosa)
     )
        )
        (axi_1 lx2 lx1 xa xb x0 ay ay1)
        (axi_1 ly1 ly2 ya yb y0 ax ax1)
)
      )
      (zoome)
      (end)
    )
  )
)


DCL代码：

axis: dialog {
  label = "轴网数据编辑";
  : row {
    : column {
      : row {
        : boxed_radio_column {
          label = "类型选择";
          key = "type_sel";
          : radio_button {
            label = "上开间T";
            key = "top";
            mnemonic = "T";
          }
          : radio_button {
            label = "下开间B";
            key = "bottom";
            mnemonic = "B";
          }
          : radio_button {
            label = "左进深L";
            key = "left";
            mnemonic = "L";
          }
          : radio_button {
            label = "右进深I";
            key = "right";
            mnemonic = "I";
          }
        }
        : boxed_column {
          label = "数据编辑";
          : edit_box {
            key = "rep_no_t";
            label = "重复数P:";
            mnemonic = "P";
            fixed_width = true;
            edit_width = 2;
            edit_limit = 2;
            value=1;
          }
          : slider {
            key = "rep_no_s";
            min_value = 1;
            max_value = 30;
            small_increment = 1;
            big_increment = 1;
          }
          : edit_box {
            key = "dimen_t";
            label = "尺寸M:";
            mnemonic = "M";
            fixed_width = true;
            edit_width = 5;
            edit_limit = 5;
            value=3300;
          }
          : slider {
            key = "dimen_s";
            value = 3300;
            min_value = 300;
            max_value = 18000;
            small_increment = 50;
            big_increment = 300;
          }
        } // column
      } //  row
      : edit_box {
        key = "key_l";
        label = "键入K:";
        mnemonic = "K";
      }
      : row {
        : boxed_column {
          label = "双向轴网转角" ;
          key = "double" ;
          : row {
            : button {
              key = "hangle_t1";
              label = "横转角X<";
              mnemonic = "X";
            }
            : edit_box {
              key = "hangle_t";
              fixed_width = true;
              edit_width = 4;
              edit_limit = 4;
              value = 0;
            }
          }
          : row {
            : button {
              key = "vangle_t1";
              label = "纵转角Y<";
              mnemonic = "Y";
            }
            : edit_box {
              key = "vangle_t";
              fixed_width = true;
              edit_width = 4;
              edit_limit = 4;
              value=90;
            }
          }
        }
        : boxed_column {
          label = "总尺寸" ;
          : row {
            key = "kai_jian";
            : text {
              label = "开间:";
            }
            : text {
              key = "kai_t";
              width = 6;
            }
          }
          : row {
            key = "jin_shen";
            : text {
              label = "进深:";
            }
            : text {
              key = "jin_t";
              width = 6;
            }
          }
        }
      }
    }
    : column {
      : row {
        : list_box {
          label = "开间/进深";
          key = "dim_list";
          width = 11;
          height = 9;
        }
        : list_box {
          label = "常用值";
          key = "com_list";
          allow_accept = false;
          width = 7;
          height = 9;
        }
      }
      : row {
        : button {
          label = "加入A";
          key = "add_item";
          mnemonic = "A";
        }
        : button {
          label = "删除D";
          key = "del_item" ;
          mnemonic = "D";
        }
      }
      : row {
        : button {
          label = "修改E";
          key = "ed_item";
          mnemonic = "E";
        }
        : button {
          label = "全清U";
          key = "reset";
          mnemonic = "U";
        }
      }
    }
  }
  : row {
    : toggle {
      key = "single";
      label = "单向轴网S";
      mnemonic = "S";
      value = 0;
    }
    ok_cancel;
  }
  errtile;
}
// ---------------END-------------------------
//  Warning for confirming "开间/进深列表" deletion.
// -------------------------------------------
confirm: dialog {
  label = "注 意";
  : text { label = "真要清除列表内容吗?";}
  key = "confirm";
  spacer_1;
  : row {
    fixed_width = true;
    aligment = centered;
    : button {
      label = "OK";
      mnemonic = "O";
      key = "sure";
      width = 8;
    }
    : spacer { width = 2;}
    : default_button {
      label = "Cancel";
      key = "no";
      width = 8;
    }
  }
}

aeo

轴网有必要吗
直接offset就可以

ljttjl

http://ljttjl.ys168.com  20090309轴线自动编序号球并标注尺寸程序