求助lisp程序批量解决改变图层管理器内图层颜色

李旭洋

newer 发表于 2018-3-28 23:31
把图层名是 1,2,3的图层设置RGB颜色。你要的和这个不一样。

我把所有层对照按这个写也就可以了

dnbcgrass

;试用以下程序，未优化
(defun c:gtcys()
    (setq tcyslb '(((35 31 32) (33 26 23))       ;((原来颜色号R1 G1 B1) (新颜色号R1 G1 B1))
                   ((225 244 253) (240 247 252))
                   ((185 124 15) (173 130 18))
                   ((0 174 239) (0 155 219))
                   ((237 28 36) (191 10 19))
                   ((0 166 81) (0 144 69))
                   ((239 91 161) (202 104 160))
                   ((253 185 19) (233 188 0))
                   ; ...
                  )
    )

    (setq acCmColo (vla-getinterfaceobject
                      (vlax-get-acad-object)
                      (strcat "AutoCAD.AcCmColor." (substr (getvar "ACADVER") 1 2))
                  )
    )
  
    (vlax-for Layer (vla-get-Layers (vla-get-ActiveDocument (vlax-get-acad-object)))
        (setq Truecolor (vlax-get-property Layer "TrueColor"))
        (setq ysb (list (vlax-get Truecolor "Red")
                        (vlax-get Truecolor "Green")
                        (vlax-get Truecolor "Blue")
                  )
        )
        (foreach tcys tcyslb
             (if (equal ysb (car tcys))
                 (progn
                     (setq newysb (cadr tcys))
                     (vlax-invoke acCmColo "SetRGB" (car newysb) (cadr newysb) (last newysb))
                     (vlax-put Layer "Truecolor" acCmColo)
                 )
             )
        )
   )
   (princ)  
)

李旭洋

dnbcgrass 发表于 2018-3-29 15:32
;试用以下程序，未优化
(defun c:gtcys()
    (setq tcyslb '(((35 31 32) (33 26 23))       ;((原来颜 ...

多谢大神，很给力，已经实现了，太棒了，谢谢您