测定并标注Satwe、Yjk框架柱计算配筋图中b、h边位置

dyjwyqz5221

Satwe、Yjk（盈建科）结构计算软件的计算配筋图中，框架柱外框线是有方向的。
功能：准确测定并标注矩形框架柱边框的b边、h边，顶点位置（0~3），这是判定配筋是否满足的重要依据。
使用范围：仅适应于矩形框架柱
这两款计算软件框架柱计算配筋平面图（转cad后）中，框架柱的特点：
1、闭合顶点数均为4。
2、均为逆时针方向。
3、点表的起始点不同。
为此设计了本程序，以方便识别配筋值是属于哪个边的。
框架柱的方向与初始输入的框架柱方向一致，尤其对于斜向柱、转90度的柱，判断非常困难。

分享给结构设计人员，望大家多提宝贵意见，以便改进。

[Actionscript3] 纯文本查看 复制代码

(defun c:chk-kzbh(/ ss)
	;;;为调整标注文字方向用
	(defun get::pts(pts)
		(if (not (equal (car (car pts)) (car (cadr pts)) 1e-3))
			(vl-sort pts
				'(lambda(a b)
					(< (car a) (car b))
				)
			)
			(vl-sort pts
				'(lambda(a b)
					(< (cadr a) (cadr b))
				)
			)
		);;;if
	);;;defun
	(defun _pross(ss)
		(xdrx_begin)
        	(xdrx_sysvar_push '("osmode" 0 "cmdecho" 0 "Pickstyle" 0));;;捕捉和命令关闭
		(xdrx_runtime t)
		(mapcar
			'(lambda(x / pts-e pt-mid pts pts1 area1 str pt-mid-b pt-mid-h ang-b ang-h m pts-b pts-h)
				(setq pts-e (xdrx_entity_getstretchpoint x)
					pt-mid (xdrx_getpropertyvalue x "centroid")
					pts (xdrx-curve-offset1 x 150.);;;外扩150mm后的点表
					pts (reverse (cdr (reverse pts)));;;去掉最后一个点（与起点重合）
					pts1 (XD::List:SnakePair pts)
					area1 (xdrx_points_area pts);;;面积,有正、负之分
				);;;setq
				(if (equal (car pts-e) (last pts-e))
					(setq pts-e (reverse (cdr (reverse pts-e))))
				);;;if
				(if (minusp area1)
					(setq str "顺时针");;;顺时针为负值
					(setq str "逆时针");;;逆时针为正值
				);;;if
				(cond
					((= #abc# "Satwe")
						(setq pt-mid-b (apply 'xdrx_line_midp (cadr pts1))
							pt-mid-h (apply 'xdrx_line_midp (car pts1))
							pts-b (get::pts (cadr pts1))
							pts-h (get::pts (car pts1))
						);;;setq
					);;;cond1
					(t
						(setq pt-mid-b (apply 'xdrx_line_midp (car pts1))
							pt-mid-h (apply 'xdrx_line_midp (cadr pts1))
							pts-b (get::pts (car pts1))
							pts-h (get::pts (cadr pts1))
						);;;setq
					);;;cond2
				);;;cond
				(setq ang-b (apply 'angle pts-b)
					ang-h (apply 'angle pts-h)
				);;;setq
				(setq m -1)
				(mapcar
					'(lambda(y)
						(xdrx_setPropertyValue 
							(XD::Text:Make 
								(list y) 
								(xdrx_prompt (setq m (1+ m)) t) 
								"yqz-style" 
								150. 
								0.70 
								0. 
								"MC"
							) 
							"layer" "yqz-bh" "color" 1
						)
					);;;lmabda
					pts-e
				);;;mapcar
				(xdrx_setPropertyValue 
					(XD::Text:Make 
						(list pt-mid-b) 
						(strcat "b边，" str) 
						"yqz-style" 
						150. 
						0.70 
						ang-b 
						"MC"
					) 
					"layer" "yqz-bh" "color" 4
				)
				(xdrx_setPropertyValue 
					(XD::Text:Make 
						(list pt-mid-h) 
						(strcat "h边，" str)
						"yqz-style" 
						150.
						0.70 
						ang-h 
						"MC"
					) 
					"layer" "yqz-bh" "color" 4
				)
			);;;lambda
			(xdrx_pickset->ents ss)
		);;;mapcar
		(xdrx_prompt "\n用时 "(xdrx_runtime)" 秒")
		(xdrx_sysvar_pop)
        	(xdrx_end)
        	(princ)
	);;;while
	(if (not #abc#)
		(setq #abc# "Yjk(盈建科)")
	);;;if
	(if (and (setq #abc# (xdrx_ui_combolist "类型" "选择类型" '("Satwe" "Yjk(盈建科)") #abc#))
		(member #abc# '("Satwe" "Yjk(盈建科)"))
	    );;;and
		(while (setq ss (xdrx-ssget "\n框选多段线<退出>：" ":L" '((0 . "LWPOLYLINE")(90 . 4)(-4 . "&=")(70 . 1))))
			(_pross ss)
		);;;while
		(setq #abc# "Yjk(盈建科)")
	);;;if
	(princ)
);;;defun

LXH刚开始

又有新插件可以学习了，谢谢!

tzfcn

这个插件很实用，特别在建筑与结构图的审图中非常实用。

kyky1002

很有用的插件，多谢分享

dyjwyqz5221

欢迎关注，我正在与pkpm软件编制人员咨询，框架柱计算配筋与框架柱的准确位置关系，这样在变形缝处也能准确取到其b、h向及Gx、Gy的值了，计算配筋与实配钢筋面积的校核程序就会更加完善了。

XDSoft

调整文字正确方向显示，试用下函数
(xd::text:adjust e)

dyjwyqz5221

XDSoft 发表于 2020-6-19 15:27
调整文字正确方向显示，试用下函数
(xd::text:adjust e)

谢谢指导！

既然青春留不住

wangcunshi

这个适用场景是怎么样的呢？没有看明白呢？

pxt2015

[点表] [函数发布] 对点表，根据其中存在的一个点PT为起点，逆时针重新排列
根据以上函数，柱轮廓点表距离文字G*最近点为起点，逆时针排序返回lst=(p1 p2 p3 p4)，再根据关键点(p1和p4中点，p1和p2中点，p2，p1)，柱轮廓偏移一定距离后点集cp，遍历文字选择集ssget "cp"，就能将b边，h边柱计算配筋，角部计算配筋，箍筋，柱编号分组，列表。返回("KZ*" Asb Ash Ascor Asg 截面尺寸)，然后可以根据柱编号归并最大配筋，把归并后的柱配筋画出来
当然圆形柱子也可以，区分一下顶点的数量，CP点表计算稍不同。以上思路没考虑异性柱和剪力墙的配筋归并。

pxt2015

在这里学到很多-帮助CHM文件没有的xdrx函数